DO - varying

很多时候我们需要在一个循环或者批量处理很多名称类似的变量，且这些变量名是可序的，即存在数字规律的，比如WORD01,WORD02等等。那么一个很好用的语法可以实现：VARYING 可以使用DO-VARING

DO 39 TIMES VARYING l_value FROM t_list_history_03-zhr_col01 NEXT t_list_history_03-zhr_col02.
      PERFORM sub_set_cell_value USING application l_row l_col l_value.
      l_row = l_row + 1.
    ENDDO.

 

以下是SAP帮助文档

 

DO - varying

Syntax

DO ... VARYING dobj FROM dobj1 NEXT dobj2 [RANGE range].
  [statement_block]
ENDDO.

Effect

: The addition VARYING assigns a new value to a variable dobj for each run of a DO loop. It can be used more than once in a DO statement.

 

dobj1 and dobj2 are the first two data objects in a sequence of data objects that are the same distance apart in the memory. The data types of the data objects dobj, dobj1, and dobj2 must be flat.

 

In Unicode programs, dobj, dobj1, and dobj2 must be compatible. Also in Unicode programs, dobj1 and dobj2 must either be structure components that belong to the same structure, or subareas of the same data object specified by offset/length specifications.

 

In the first completion of the loop, the content of the data object dobj1 is assigned to dobj, and in the second loop, the content of the data object dobj2 is assigned. In the subsequent loops, dobj is assigned the content of the data object that is the same distance in the memory from the previously assigned data object, as dobj2 is from dobj1. There is no type conversion.

 

If the processing block is not exited within the loop, the content of the variable dobj at the end of the loop run is assigned to the previously assigned data object dobj1 or dobj2 without conversion.

 

The addition RANGE determines the memory area that can be processed using the addition VARYING. After RANGE, an elementary data object range of type c, n, or x, or a structure can be specified. The memory area of range must include the ranges of dobj1 and dobj2. In deep structures, the deep components are exceptions to the permitted area. The DO loop must be ended before non-permitted memory areas are accessed, that is, areas outside of range or their deep components. Otherwise this may lead to an untreatable exception.

 

If RANGE is not explicitly specified, the permitted memory area is determined as follows:

 

• In non-Unicode programs and before release 6.10, the permitted memory area of dobj1 extends to the limit of the current data area of the ABAP program. If the RANGE addition is not specified, there is a danger of unintentionally overwriting the memory.
• In Unicode programs, , RANGE can only be omitted if it can be statically determined that dobj1 and dobj2 are components of the same structure. The permitted memory area is then determined from the smallest substructure that contains dobj1 and dobj2.
  
  
  

Note

: Instead of the addition VARYING, the statement ASSIGN should be used in the loop with the addition INCREMENT.

Example

: In the first DO loop, subareas of the data object text are edited using offset/length access. In Unicode programs, the addition RANGE must be specified here. In the second DO loop, the program accesses the components of the data object text. In this case, it is not necessary to specify RANGE. The third DO loop shows how the functions of the second loop can be programmed using the statement ASSIGN INCREMENT.

DATA: BEGIN OF text,
        word1 TYPE c LENGTH 4 VALUE 'AAAA',
        word2 TYPE c LENGTH 4 VALUE 'BBBB',
        word3 TYPE c LENGTH 4 VALUE 'CCCC',
        word4 TYPE c LENGTH 4 VALUE 'DDDD',
      END OF text.

DATA: word  TYPE c LENGTH 4,
      char1 TYPE c LENGTH 1,
      char2 TYPE c LENGTH 1,
      leng TYPE i.

FIELD-SYMBOLS <word> LIKE text-word1.
DATA inc TYPE i.

DESCRIBE FIELD text LENGTH leng IN CHARACTER MODE.
leng = leng / 2.

DO leng TIMES VARYING char1 FROM text(1)
                            NEXT text+2(1) RANGE text
              VARYING char2 FROM text+1(1)
                            NEXT text+3(1) RANGE text.
  WRITE: char1, char2.
  char1 = 'x'.
  char2 = 'y'.
ENDDO.

DO 4 TIMES VARYING word FROM text-word1 NEXT text-word2.
  WRITE / word.
ENDDO.

DO.
  inc = sy-index  - 1.
  ASSIGN text-word1 INCREMENT inc TO <word> RANGE text.
  IF sy-subrc = 0.
    WRITE / <word>.
  ELSE.
    EXIT.
  ENDIF.
ENDDO.

Exceptions

Non-Catchable Exceptions

 

• Cause: Impermissible access to tables, strings, field or object references within the range specified by the RANGE addition.
  Runtime Error: DO_WHILE_VARY_ILLEGAL_ACCESS
• Cause: Access to data outside the range specified by the RANGE addition.
  Runtime Error: DO_WHILE_VARY_NOT_IN_RANGE