量化软件——赫兹MT5模式搜索的暴力方法 循环优化

概述
考虑到我上一篇文章中的材料，我可以说这只是我在算法中引入的所有函数的肤浅描述。它们不仅涉及EA创建的完全自动化，还涉及诸如结果优化和选择的完全自动化以及随后用于自动交易，或者我稍后将展示的更先进的EA的创建等重要函数。

由于交易终端、通用EA和算法本身的共生关系，您可以完全摆脱手动开发，或者在最坏的情况下，只要您具备必要的计算能力，就可以将可能改进的劳动强度降低一个数量级。在这篇文章中，我将开始描述这些创新最重要的方面。

严格地说，这个函数应该被用作一个离散的辅助函数。然而，它允许我们计算分数为“i”的值。当然，就我们的问题而言，这不太可能对我们有任何有益的好处。

由于我给出了这样的数学，我有义务提供算法实现的示例。我认为，每个人都会对获得更容易适应其系统的现成代码感兴趣。让我们从定义主要变量和方法开始，这些变量和方法将简化必要量的计算：

//+------------------------------------------------------------------+
//| Number of lines in the balance model                             |
//+------------------------------------------------------------------+
#define Lines 11 

//+------------------------------------------------------------------+
//| Initializing variables                                           |
//+------------------------------------------------------------------+
double MaxPercent = 10.0;
double BalanceMidK[,Lines];
double Deviations[Lines];
int Segments;
double K;

//+------------------------------------------------------------------+
//| Method for initializing required variables and arrays            |
//| Parameters: number of segments and initial balance               |
//+------------------------------------------------------------------+
void InitLines(int SegmentsInput, double BalanceInput) 
{
  Segments = SegmentsInput;
  K = BalanceInput / Segments;
  ArrayResize(BalanceMidK,Segments+1);
  ZeroStartBalances();
  ZeroDeviations();
  BuildBalances();
}

//+------------------------------------------------------------------+
//| Resetting variables for incrementing balances                    |
//+------------------------------------------------------------------+
void ZeroStartBalances()
{
  for (int i = 0; i < Lines; i++ ) 
  {
      for (int j = 0; j <= Segments; j++)
      {
          BalanceMidK[j,i] = 0.0;
      }
  }
}

//+------------------------------------------------------------------+
//| Reset deviations                                                 |
//+------------------------------------------------------------------+
void ZeroDeviations()
{
  for (int i = 0; i < Lines; i++)
  {
      Deviations[i] = -1.0;
  }
}
该代码被设计为可重复使用。在下一次计算之后，您可以通过首先调用InitLines方法来计算不同余额曲线的指标。你需要给它回测和交易数量的最终余额，之后你可以开始根据这些数据构建我们的曲线：

//+------------------------------------------------------------------+
//| Constructing all balances                                        |
//+------------------------------------------------------------------+
void BuildBalances()
{
   int N0 = MathFloor(Segments / 2.0) - Segments / 2.0 == 0 ? Segments / 2 : (int)MathFloor(Segments / 2.0);//calculate first required N0
   for (int i = 0; i < Lines; i++)
   {
       if (i==0)//very first and straight line 
       {
           for (int j = 0; j <= Segments; j++)
           {
               BalanceMidK[j,i] = K*j;
           }
       }
       else//build curved lines
       {
           double ThisP = i * (MaxPercent / 10.0);//calculate current line curvature percentage
           double KDelta = ( (ThisP /100.0) * K * Segments) / (MathPow(N0,2)/2.0 );//calculation first auxiliary ratio
           double Psi0 = -KDelta * N0;//calculation second auxiliary ratio
           double KDelta1 = ((ThisP / 100.0) * K * Segments) / (MathPow(Segments-N0, 2) / 2.0);//calculate last auxiliary ratio
           //this completes the calculation of auxiliary ratios for a specific line, it is time to construct it

           for (int j = 0; j <= N0; j++)//construct the first half of the curve 
           {
               BalanceMidK[j,i] = (K + Psi0 + (KDelta * j) / 2.0) * j;
           }
           for (int j = N0; j <= Segments; j++)//construct the second half of the curve 
           {
               BalanceMidK[j,i] = BalanceMidK[i, N0] + (K + (KDelta1 * (j-N0)) / 2.0) * (j-N0);
           }
       }
   }
}
请注意，“Lines”决定了我们的族中将有多少条曲线。凹度从零（直线）逐渐增加到MaxPercent，正如我在相应的图中所示。然后，您可以计算每条曲线的偏差，并选择最小的一条：

//+------------------------------------------------------------------+
//| Calculation of the minimum deviation from all lines              |
//| Parameters: initial balance passed via link                      |
//| Return: minimum deviation                                        |
//+------------------------------------------------------------------+
double CalculateMinDeviation(double &OriginalBalance[])
{
   //define maximum relative deviation for each curve 
   for (int i = 0; i < Lines; i++)
   {
       for (int j = 0; j <= Segments; j++)
       {
          double CurrentDeviation = OriginalBalance[Segments] ? MathAbs(OriginalBalance[j] - BalanceMidK[j, i]) / OriginalBalance[Segments] : -1.0;
          if (CurrentDeviation > Deviations[i])
          {
              Deviations[i] = CurrentDeviation;
          }           
       }
   }
    
   //determine curve with minimum deviation and deviation itself 
   double MinDeviation=0.0;
   for (int i = 0; i < Lines; i++)
   {
       if ( Deviations[i] != -1.0 && MinDeviation == 0.0)
       {
           MinDeviation = Deviations[i];
       }
       else if (Deviations[i] != -1.0 && Deviations[i] < MinDeviation)
       {
           MinDeviation = Deviations[i];
       }
   }
   return MinDeviation;
}
这就是我们应该如何使用它：

OriginalBalance 原始余额数组的定义。
确定其长度SegmentsInput和最终余额BalanceInput，以及调用InitLines方法。
然后，我们通过调用BuildBalances方法来构建曲线。
由于绘制了曲线，我们可以考虑为曲线族改进CalculateMinDeviation标准。
这就完成了标准的计算。我认为曲线族系数（Curve Family Factor）的计算不会造成任何困难。没有必要在这里介绍它。