手撕iOS底层02 -- 分析alloc&init&new

OC对象与指针

    GPerson *p1 = [GPerson alloc];
    GPerson *p2 = [p1 init];
    GPerson *p3 = [p1 init];

    LGPrint(@"%@ - %p - %p", p1, p1, &p1); //<GPerson: 0x6000022f4160> - 0x6000022f4160 - 0x7ffee7a11078
    LGPrint(@"%@ - %p - %p", p2, p2, &p2); //<GPerson: 0x6000022f4160> - 0x6000022f4160 - 0x7ffee7a11070
    LGPrint(@"%@ - %p - %p", p3, p3, &p3); //<GPerson: 0x6000022f4160> - 0x6000022f4160 - 0x7ffee7a11068

三个指针变量指向同一块内存空间，p1 p2 p3是放在栈空间，所以每一个指针变量地址是不同的；

因为是在栈空间分配的，所以栈空间从高到低；

又因为64位设备，指针大小8字节，所以从0x7ffee7a11078依次减去0x8。

%p -- p1是打印对象的地址

%p -- &p1是打印p1在地址空间的地址

---

0x00 准备源码项目

• 从 官网下载 objc4-781源码项目

• 先放上alloc的流程图

0x01 – alloc探索

1. 在main函数中通过alloc方法进入到实现部分，从这里开始，一点一点的往下往深了走进去～😄

+ (id)alloc {
    return _objc_rootAlloc(self);
}

2. 跳到_objc_rootAlloc的实现部分。

// Base class implementation of +alloc. cls is not nil.
// Calls [cls allocWithZone:nil].
id
_objc_rootAlloc(Class cls)
{
    return callAlloc(cls, false/*checkNil*/, true/*allocWithZone*/);
}

3. 跳到callAlloc流程的实现部分， 这时候这里有分支了，经过断点调试，这里走_objc_rootAllocWithZone

在objc-config.h文件里

// Define __OBJC2__ for the benefit of our asm files.
#ifndef __OBJC2__
#   if TARGET_OS_OSX  &&  !TARGET_OS_IOSMAC  &&  __i386__
        // old ABI
#   else
#       define __OBJC2__ 1
#   endif
#endif

// Call [cls alloc] or [cls allocWithZone:nil], with appropriate 
// shortcutting optimizations.
static ALWAYS_INLINE id
callAlloc(Class cls, bool checkNil, bool allocWithZone=false)
{
#if __OBJC2__ // 宏条件判断是否OBJC2版本
    if (slowpath(checkNil && !cls)) return nil;
  	// cls->ISA()->hasCustomAWZ() 这里判断类有没有实现+allocWithZone，没有实现走到到if条件里。
    if (fastpath(!cls->ISA()->hasCustomAWZ())) { 
        return _objc_rootAllocWithZone(cls, nil);
    }
#endif

    // No shortcuts available.
    if (allocWithZone) {
        return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
    }
    return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}

编译器优化

fastpath和slowpath参考

#define fastpath(x) (__builtin_expect(bool(x), 1))

#define slowpath(x) (__builtin_expect(bool(x), 0))

__builtin_expect 是GCC提供给程序员使用，目的是将"分支转移"的信息提供给编译器，这样编译器可以对代码进行优化，以减少指令跳转带来的性能下降

其实代码中的slowpath和fastpath删除后并不影响这段代码功能，slowpath 和fastpath 的添加是告诉编译器if条件语句中是大概率事件还是小概率事件，从而让编译器对代码进行优化；

 if (x)
       return 1;
   else 
       return 30;

由于计算机并非一次只读取一条指令，而是读取多条指令，所以在读取if语句的时候也会把return 1读取，如果x值为0会再次读取return 30, 重读指令相对来说是耗时的。如果x有很大的概率是0，而return 1 这条指令不可避免的会被读取，但实际上几乎没有机会去执行的，造成不必要的指令重读。因此，定义了两个宏，fastpath(x)依然返回x,只是告诉编译器x的值一般不为0，从而编译可以进行优化。同理，slowpath(x)标识x的值很可能为0，编译时可以进行优化。

• 在日常开发中，通过在Xcode设置Optimization Level的Debug把None设置为fastest, Smallest[-Os];来达到性能优化的目的。

4. 来到_objc_rootAllocWithZone

NEVER_INLINE
id
_objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused)
{
    // allocWithZone under __OBJC2__ ignores the zone parameter
    return _class_createInstanceFromZone(cls, 0, nil,
                                         OBJECT_CONSTRUCT_CALL_BADALLOC);
}

5. 直接来到核心方法_class_createInstanceFromZone

static ALWAYS_INLINE id
_class_createInstanceFromZone(Class cls, size_t extraBytes, void *zone,
                              int construct_flags = OBJECT_CONSTRUCT_NONE,
                              bool cxxConstruct = true,
                              size_t *outAllocatedSize = nil)
{
    ASSERT(cls->isRealized()); // 容错处理

    // Read class's info bits all at once for performance
    bool hasCxxCtor = cxxConstruct && cls->hasCxxCtor(); //判断是否有c++的构造函数
    bool hasCxxDtor = cls->hasCxxDtor(); // 判断是否有c++的析构函数
    bool fast = cls->canAllocNonpointer();
    size_t size;
		// 计算出需要的内存空间大小 从上边调用得知 extraBytes = 0
    size = cls->instanceSize(extraBytes);
    if (outAllocatedSize) *outAllocatedSize = size;

    id obj;
    if (zone) {
        obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
    } else {
      // 向系统申请开辟内存 ，返回内存地址指针
        obj = (id)calloc(1, size);
    }
  	// 容错处理
    if (slowpath(!obj)) {
        if (construct_flags & OBJECT_CONSTRUCT_CALL_BADALLOC) {
            return _objc_callBadAllocHandler(cls);
        }
        return nil;
    }

    if (!zone && fast) {
      // isa绑定 关联到相应的类
        obj->initInstanceIsa(cls, hasCxxDtor);
    } else {
        // Use raw pointer isa on the assumption that they might be
        // doing something weird with the zone or RR.
        obj->initIsa(cls);
    }

    if (fastpath(!hasCxxCtor)) {
        return obj;
    }

    construct_flags |= OBJECT_CONSTRUCT_FREE_ONFAILURE;
    return object_cxxConstructFromClass(obj, cls, construct_flags);
}

三个核心方法:

⚠️NOTE： 后边系列文章着重分析这几个函数的内部实现：

• size = cls->instanceSize(extraBytes);
• obj = (id)calloc(1, size);
• obj->initInstanceIsa(cls, hasCxxDtor);

总结下_class_createInstanceFromZone流程

1 开辟内存 先计算出需要的内存空间大小

2 申请内存 向系统申请开辟内存，返回地址指针

3 isa绑定 关联到相应的类

---

分析第一个关键函数size = cls->instanceSize(extraBytes);

进入到instanceSize方法

    size_t instanceSize(size_t extraBytes) const {
      	// 编译器优化快速计算
        if (fastpath(cache.hasFastInstanceSize(extraBytes))) {
          	// 执行这里
            return cache.fastInstanceSize(extraBytes);
        }

        size_t size = alignedInstanceSize() + extraBytes;
        // CF requires all objects be at least 16 bytes.
        if (size < 16) size = 16;
        return size;
    }

这里调用fastInstanceSize

    size_t fastInstanceSize(size_t extra) const
    {
        ASSERT(hasFastInstanceSize(extra));
				//Gcc的内建函数 __builtin_constant_p 用于判断一个值是否为编译时常数，
        //如果参数EXP 的值是常数，函数返回 1，否则返回 0
        if (__builtin_constant_p(extra) && extra == 0) {
            return _flags & FAST_CACHE_ALLOC_MASK16;
        } else {
          // _flags
            size_t size = _flags & FAST_CACHE_ALLOC_MASK;
            // remove the FAST_CACHE_ALLOC_DELTA16 that was added
            // by setFastInstanceSize
            return align16(size + extra - FAST_CACHE_ALLOC_DELTA16);
        }
    }

接着调用align16

    // 0010 0111 39 （15+24）
    // 1111 0000 ～
    // 0010 0000
    // 0000 1111 15
// 16字节对齐算法
static inline size_t align16(size_t x) {
    return (x + size_t(15)) & ~size_t(15);
}

align16方法传进来的是24， 然后按执行这个对齐算法， 24+15 = 39 ， 二进制0010 0111 与 15的取反1111 0000 再按位域

得到 0010 0000 转十进制就是 32;

这里也可以先右移 再左移 ，也可以把末尾的置为0

为什么字节对齐？

• 方便CPU读取，提高读取效率 ，因为如果跨字节访问 会影响IO读取效率；典型的以空间换时间；
• 一个对象，缺省第一个属性isa占8个字节，什么属性都没有时，会留8个字节，与其它对象的isa有一定宽度，保证安全，不会地址越界，非法访问到其它对象的内容；
• 举个🌰: 现在实行垃圾分类，就是为了方便回收利用，方便处理废弃 厨房垃圾，跟字节对齐也一样，都是为了方便，效率高；这个方便效率高相对于人来说，而字节对齐是相对于cpu 机器来说是安全高效的；

字节对齐算法中，对齐的主要是对象，在底层的本质是struct objc_object结构体。

结构体中的成员变量在内存中是连续存放的，所以可以对结构体类型强转。

早期的版本是8字节对齐， 现在是按16字节对齐；

内存对齐规则可以看我之前的struct文章对齐规则，因为oc对象编译到底层的表示也是一个struct objc_object结构体;访问链接

0x02 – callAlloc 探索

obj = (**id**)calloc(1, size);

通过这行代码，obj就是会有一个16进制的地址。

在oc中，打印一个对象的地址<Test: 0x000000ff001>;对象名字+指针地址。这里为什么不一样？

1. 主要是开辟的内存地址还没有与传进来的类关联绑定。

0x03 – initInstanceIsa 探索

obj->initInstanceIsa(cls, hasCxxDtor);

接着开始绑定地址与类的关联。 初始化initIsa 指针。

这里打印出俩的obj就是一个对象指针了。

总结alloc流程

• 主要开辟内存，十六字节对齐，大小为十六整数倍。
• 内存三部曲： 计算对象大小 --- > 申请内存地址 ---->类与地址关联

0x04init方法底层实现

+ (id)init {
    return (id)self;
}

- (id)init {
    return _objc_rootInit(self);
}

id
_objc_rootInit(id obj)
{
    // In practice, it will be hard to rely on this function.
    // Many classes do not properly chain -init calls.
    return obj;
}

工厂设计方法， 提供给用户自定义自己的初始化方法的一个入口；使用id强转的原因，因为内存对齐后，可以使用类型强转成我们需要的类型；

0x05 new方法的底层实现

+ (id)new {
    return [callAlloc(self, false/*checkNil*/) init];
}

苹果不建议使用new去初始化对象，如果自定义类里初始化重写了init方法，使用new会走到这个方法；

//重写init
- (instancetype)init
{
    self = [super init];
    if (self) {
        NSLog(@"come here");
    }
    return self;
}

Demo *obj = [Demo new];
//打印输出 come here

如果不重写 init方法， 使用new会走父类的init方法

一般我们自定义的initWithXXX方法， 会掉用super init方法， 会走父类的init方法，初始化的流程走的更完善；

源码下载网站

苹果开源源码汇总

苹果开源项目下载

带你深入了解OC对象创建过程

欢迎大佬留言指正😄，码字不易，觉得好给个赞👍 有任何表达或者理解失误请留言交流；共同进步；

作者：Hello_Kid
链接：https://juejin.cn/post/6888708803114565639