用DOS写一个简单的虚拟WIFI工具，CMD电脑无线WIFI工具，BAT实现WIFI和自动关机

本文链接：https://blog.csdn.net/jaikydota163/article/details/51638678

实现历程

以前在学校时使用笔记本或台式机开wifi一般使用的都是360wifi或猎豹wifi。

这些wifi功能虽然做得比较人性化，但偶尔网络特别慢，网速不能达到带宽正常网速，而且稳定性较差，又有开启关闭速度慢等缺点。

于是便想起了windows自带的虚拟热点，以前使用命令行开启过，再加上自己会点bat命令，于是闲来无事，写了这个bat小工具，给需要的人。

其中网络共享需要手动在windows上设置，如果有网友有直接实现共享的命令供给我改进，可以直接在下面评论或jaikydota@163.com @我的邮箱，感激不尽。

WIFI BAT工具功能图：

使用教程：

打开后输入【1】，按步骤创建虚拟WIFI后，

打开控制面板->网络共享中心->更改适配器设置[或右键桌面右下角网络图标—打开网络和共享中心]，你会发现多了一个网卡“Microsoft Virtual wlan Miniport Adapter，这个就是我们刚才虚拟出来的无线网络适配器，随便改个适配器名称[也可以不改，需要记住新适配器名称]：无线网络连接3。

然后选择你有 Internet网络通信的适配器，可能是本地连接[以太网]，也可能是宽带连接：

如图，WIN7和WIN10分别是这样，有通路的或访问类型为Internet的适配器表示有Internet网接入。

我们就需要把这个适配器的网络共享出去给WIFI使用，这样WIFI也有Internet接入了。

然后右击适配器“ 本地连接 ”（也就是你连入网络的宽带网卡），然后点击属性->共享，勾选“允许其他网络用户通过此计算机的Internet连接还连接”选项，在下拉菜单中选择刚才建立的虚拟网络：无线网络连接3。

自此这个WIFI工具就实现了，其他功能大家可以自己试试，简单易用，只是网络共享部分不能直接用命令行实现，如果有网友有直接实现共享的命令供给我改进，可以直接在下面评论或jaikydota@163.com @我的邮箱，感激不尽。

实现CMD命令：

@echo off
setlocal EnableDelayedExpansion
title 虚拟WIFI工具
::mode con cols=100 lines=30
color 1F
echo. 【虚拟WIFI工具】
echo. PS：右键以管理员身份运行，第一次使用请选择选项[1]，以后直接使用选项[2]打开WIFI即可
echo. @作者:Jaiky 问题反馈：jaikydota@163.com
echo. 使用博文地址："http://blog.csdn.net/jaikydota163/article/details/51638678"
echo. 
echo. 请选择操作:


:MENU_MAIN
echo. --------------------------------WIFI工具主菜单----------------------------------------------
echo. 1. 创建WIFI
echo. 2. 打开WIFI
echo. 3. 关闭WIFI
echo. 4. 重启WIFI
echo. 5. 查看WIFI连接用户
echo. 6. 修改WIFI名称或密码
echo. 7. 卸载WIFI
echo. 8. 设置自动关机计划
echo. 9. 清屏，重置显示
echo. 0. 退出，输入其他任意非数字也可退出
echo. --------------------------------------------------------------------------------------------

echo. 请输入选项数字，回车确认：
set /p num= 
if %num% EQU 1 (
	echo.
	echo. 请输入WIFI名称[名称不能为空]：
	set /p wifiname= 
	echo. 请输入WIFI密码[必须8位字符以上]：
	set /p wifipsd=
	netsh wlan set hostednetwork mode=allow ssid=!wifiname! key=!wifipsd!
	echo. 虚拟WIFI创建成功！
	echo.
	echo. 正在开启WIFI...
	netsh wlan start hostednetwork
	echo. WIFI开启成功...
	goto MENU_MAIN
)
if %num% EQU 2 (
	echo.
	echo. 正在开启WIFI...
	netsh wlan start hostednetwork
	echo. WIFI开启成功...
	goto MENU_MAIN
)
if %num% EQU 3 (
	echo.
	echo. 正在关闭WIFI...
	netsh wlan stop hostednetwork
	echo. WIFI关闭成功...
	goto MENU_MAIN
) 
if %num% EQU 4 (
	echo.
	echo. 正在重启WIFI...
	echo.
	netsh wlan stop hostednetwork
	netsh wlan start hostednetwork
	echo. WIFI重启成功...
	goto MENU_MAIN
)
if %num% EQU 5 (
	echo.
	echo. 查询信息如下：
	netsh wlan show hostednetwork
	echo. 
	echo. 任意键弹出菜单继续....
	pause >NUL 2>NUL
	goto MENU_MAIN
)
if %num% EQU 6 (
	echo.
	echo. 请输入WIFI名称[名称不能为空]：
	set /p wifiname= 
	echo. 请输入WIFI密码[必须8位字符以上]：
	set /p wifipsd=
	netsh wlan set hostednetwork mode=allow ssid=!wifiname! key=!wifipsd!
	echo. 虚拟WIFI修改成功！
	goto MENU_MAIN
)
if %num% EQU 7 (
	echo.
	echo. 正在卸载WIFI...
	netsh wlan set hostednetwork mode=disallow
	echo. WIFI卸载成功！
	goto MENU_MAIN
)
if %num% EQU 8 (
	echo.
	echo. 请选择关机方式，设置定时关机或倒计时关机：
	echo. -----------------------------定时关机菜单------------------------------------------
	echo. 1.倒计时关机，单位[秒]，如600秒，即10分钟后关机，支持所有WINDOWS系统【推荐】
	echo. 2.定时关机，格式[小时:分钟]，如22:30后关机，此方法支持WIN XP,WIN7
	echo. 3.定时关机，格式[小时:分钟]，如22:30后关机，此方法支持WIN7,WIN8,WIN10
	echo. 4.取消选项[1]或[2]的自动关机计划
	echo. 5.取消选择[3]的自动关机计划
	echo. 6.退出本菜单
	echo. -----------------------------------------------------------------------------------
	echo. 请输入选项数字，回车确认：
	set /p sdchoice= 
	if !sdchoice! EQU 1 (
		echo. 请输入倒计时关机秒数：
		set /p sdtime1= 
		shutdown -s -t !sdtime1!
		goto MENU_MAIN
	)
	if !sdchoice! EQU 2 (
		echo. 请输入定时关机时间：
		set /p sdtime3= 
		at !sdtime3! shutdown -s
		echo. 请输入定时关机时间：
		goto MENU_MAIN
	)
	if !sdchoice! EQU 3 (
		echo. 请输入定时关机时间：
		set /p sdtime2= 
		schtasks /Create /SC ONCE /TN "shutdowntask" /TR "shutdown /s" /ST !sdtime2!
		echo. 请输入定时关机时间：
		goto MENU_MAIN
	)
	if !sdchoice! EQU 4 (
		shutdown -a
		echo. 定时关机任务已取消...
		goto MENU_MAIN
	)
	if !sdchoice! EQU 5 (
		schtasks /Delete /TN "shutdowntask" /F
		echo. 定时关机任务已取消...
		goto MENU_MAIN
	)
	if !sdchoice! EQU 6 (
		goto MENU_MAIN
	)
	echo.
	echo. 选择无效，请重新选择:
	goto MENU_SHUTDOWN
)
if %num% EQU 9 (
	CLS
	goto MENU_MAIN
)
if %num% EQU 0 (
	EXIT
)
echo %num%|findstr /be "[0-9]*" >nul && goto MENU_RESELECT || EXIT

:MENU_RESELECT
echo.
echo. 选择无效，请重新选择:
goto MENU_MAIN


pause
::exit

::暂停1秒 ping /n 2 127.1>nul

获取源文件：BAT工具

源文件说明：直接下载使用即可，功能比较简单，最好右键以管理员身份运行。