【染色】三维扫描

 三维扫描

源程序名            scan.???（pas, c, cpp） 可执行文件名        scan.exe 输入文件名          scan.in 输出文件名          scan.out

【问题描述】

    工业和医学上经常要用到一种诊断技术——核磁共振成像(Magnetic Resonance Imagers)。利用该技术可以对三维物体(例如大脑)进行扫描。扫描的结果用一个三维的数组来保存，数组的每一个元素表示空间的一个像素。数组的元素是0~255的整数，表示该像素的灰度。例如0表示该像素是黑色的，255表示该像素是白色的。

被扫描的物体往往是由若干个部件组合而成的。例如临床医学要对病变的器官进行检查，而器官是由一些不同的组织构成的。在实际问题中，同一个部件内部的色彩变化相对连续，而不同的部件的交界处色彩往往有突变。下图是一个简化的植物细胞的例子。

从细胞的平面图来看，该细胞大致是由四个“部件”构成的，细胞壁、细胞核、液泡和细胞质。为了方便起见，我们对部件的概念做如下的规定：

（1）如果一个像素属于某部件，则或者该像素至少与该部件的一个像素相邻，或者该像素单独组成一个部件。(说明：每一个像素与前后、左右、上下的6个像素相邻)

（2）同一个部件内部，相邻两个像素的灰度差不超过正整数M。M决定了程序识别部件的灵敏度。

       请你编一个程序，对于给定的物体，判断该物体是由几个部件组成的。

【输入】

    第一行是三个正整数L，W．H(L，W，H≤50)，表示物体的长、宽、高。

    第二行是一个整数M(0≤M≤255)，表示识别部件的灵敏度。

接下来是L×W×H个O~255的非负整数，按照空间坐标从小到大的顺序依次给出每个像素的灰度。

说明：对于空间两点P1(x1, y1, z1)和P2(x2, y2, z2)，P1<P2当切仅当

（x1<x2）或者（x1=x2且y1<y2）或者（x1=x2且y1=y2且z1<z2）s

【输出】

       一个整数N，表示一共识别出几个部件。

【样例】

       scan.in                                scan.out

       2 2 2                                   2

       0

       1 1 1 1 2 2 2 2

=================================

裸的染色，若是深度遍历染色就会爆栈.2个点.

下是深度遍历代码

------------------------------------------------------------

dfs

const
  dx:array[1..6]of longint=(1,-1,0,0,0,0);
  dy:array[1..6]of longint=(0,0,-1,1,0,0);
  dz:array[1..6]of longint=(0,0,0,0,1,-1);
var
  cell:array[0..50,0..50,0..50]of integer;
  f:array[-2..52,-2..52,-2..52]of boolean;
  l,w,h,m:longint;
  
procedure init;
begin
  assign(input,'scan.in');
  assign(output,'scan.out');
  reset(input); rewrite(output);
end;

procedure terminate;
begin
  close(input); close(output);
  halt;
end;

procedure dfs(x,y,z:longint);
var
  i:longint;
  x_,y_,z_:longint;
begin
  f[x,y,z]:=false;
  for i:=1 to 6 do
    begin
      x_:=x+dx[i];
      y_:=y+dy[i];
      z_:=z+dz[i];
      if f[x_,y_,z_] and (abs(cell[x_,y_,z_]-cell[x,y,z])<=m)
        then dfs(x_,y_,z_);
    end;
end;

procedure main;
var
  i,j,k,ans:longint;
begin
  readln(l,w,h);
  readln(m);
  fillchar(f,sizeof(f),false);
  for i:=1 to l do
    for j:=1 to w do
      for k:=1 to h do
        begin
          read(cell[i,j,k]);
          f[i,j,k]:=true;
        end;

  ans:=0;
  for i:=1 to l do
    for j:=1 to w do
      for k:=1 to h do
        if f[i,j,k] then
          begin
            inc(ans);
            dfs(i,j,k);
          end;
          
  writeln(ans);
end;

begin
  init;
  main;
  terminate;
end.

-------------------------------------

下是宽度遍历代码

注意的地方，这个阶段的状态一定是上一阶段而来的..

------------------------

bfs

type
  re=record
       x,y,z:longint;
     end;
const
  dx:array[1..6]of longint=(1,-1,0,0,0,0);
  dy:array[1..6]of longint=(0,0,-1,1,0,0);
  dz:array[1..6]of longint=(0,0,0,0,1,-1);
var
  cell:array[0..50,0..50,0..50]of integer;
  f:array[-2..52,-2..52,-2..52]of boolean;
  h_:array[0..125000]of re;
  l,w,h,m:longint;

procedure init;
begin
  assign(input,'scan.in');
  assign(output,'scan.out');
  reset(input); rewrite(output);
end;

procedure terminate;
begin
  close(input); close(output);
  halt;
end;

procedure bfs(x,y,z:longint);
var
  i:longint;
  l,r:longint;
  x_,y_,z_:longint;
begin
  l:=0; r:=1;
  h_[1].x:=x; h_[1].y:=y; h_[1].z:=z;
  repeat
    inc(l);
    for i:=1 to 6 do
      begin
        x_:=h_[l].x+dx[i];
        y_:=h_[l].y+dy[i];
        z_:=h_[l].z+dz[i];
        if f[x_,y_,z_] and (abs(cell[x_,y_,z_]-cell[h_[l].x,h_[l].y,h_[l].z])<=m) then   //一定要注意是上一阶段而来的..
          begin
            inc(r);
            h_[r].x:=x_;
            h_[r].y:=y_;
            h_[r].z:=z_;
            f[x_,y_,z_]:=false;
          end;
      end;
  until l>=r;
end;

procedure main;
var
  i,j,k,ans:longint;
begin
  readln(l,w,h);
  readln(m);
  fillchar(f,sizeof(f),false);
  for i:=1 to l do
    for j:=1 to w do
      for k:=1 to h do
        begin
          read(cell[i,j,k]);
          f[i,j,k]:=true;
        end;

  ans:=0;
  for i:=1 to l do
    for j:=1 to w do
      for k:=1 to h do
        if f[i,j,k] then
          begin
            inc(ans);
            f[i,j,k]:=false;
            bfs(i,j,k);
          end;

  writeln(ans);
end;

begin
  init;
  main;
  terminate;
end.