【SPFA的应用】最优贸易

【NOIP09】最优贸易

问题编号:520  

题目描述

C 国有n 个大城市和m 条道路，每条道路连接这n 个城市中的某两个城市。任意两个城市之间最多只有一条道路直接相连。这m 条道路中有一部分为单向通行的道路，一部分为双向通行的道路，双向通行的道路在统计条数时也计为1 条。
C 国幅员辽阔，各地的资源分布情况各不相同，这就导致了同一种商品在不同城市的价格不一定相同。但是，同一种商品在同一个城市的买入价和卖出价始终是相同的。
商人阿龙来到 C 国旅游。当他得知同一种商品在不同城市的价格可能会不同这一信息之后，便决定在旅游的同时，利用商品在不同城市中的差价赚回一点旅费。设C 国n 个城市的标号从1~ n，阿龙决定从1 号城市出发，并最终在n 号城市结束自己的旅行。在旅游的过程中，任何城市可以重复经过多次，但不要求经过所有n 个城市。阿龙通过这样的贸易方式赚取旅费：他会选择一个经过的城市买入他最喜欢的商品——水晶球，并在之后经过的另
一个城市卖出这个水晶球，用赚取的差价当做旅费。由于阿龙主要是来C 国旅游，他决定这个贸易只进行最多一次，当然，在赚不到差价的情况下他就无需进行贸易。
假设 C 国有5 个大城市，城市的编号和道路连接情况如下图，单向箭头表示这条道路为单向通行，双向箭头表示这条道路为双向通行。

假设 1~n 号城市的水晶球价格分别为4，3，5，6，1。
阿龙可以选择如下一条线路：1->2->3->5，并在2 号城市以3 的价格买入水晶球，在3号城市以5 的价格卖出水晶球，赚取的旅费数为2。
阿龙也可以选择如下一条线路 1->4->5->4->5，并在第1 次到达5 号城市时以1 的价格买入水晶球，在第2 次到达4 号城市时以6 的价格卖出水晶球，赚取的旅费数为5。
现在给出 n 个城市的水晶球价格，m 条道路的信息（每条道路所连接的两个城市的编号以及该条道路的通行情况）。请你告诉阿龙，他最多能赚取多少旅费。

输入格式

第一行包含 2 个正整数n 和m，中间用一个空格隔开，分别表示城市的数目和道路的
数目。
第二行 n 个正整数，每两个整数之间用一个空格隔开，按标号顺序分别表示这n 个城
市的商品价格。
接下来 m 行，每行有3 个正整数，x，y，z，每两个整数之间用一个空格隔开。如果z=1，表示这条道路是城市x 到城市y 之间的单向道路；如果z=2，表示这条道路为城市x 和城市y 之间的双向道路。
【数据范围】
输入数据保证 1 号城市可以到达n 号城市。
对于 10%的数据，1≤n≤6。
对于 30%的数据，1≤n≤100。
对于 50%的数据，不存在一条旅游路线，可以从一个城市出发，再回到这个城市。
对于 100%的数据，1≤n≤100000，1≤m≤500000，1≤x，y≤n，1≤z≤2，1≤各城市
水晶球价格≤100。

输出格式

共1 行，包含1 个整数，表示最多能赚取的旅费。如果没有进行贸易，则输出0。

样例输入

 5 5
4 3 5 6 1
1 2 1
1 4 1
2 3 2
3 5 1
4 5 2

样例输出

5

=========================

两次SPFA就可以了

================

type
  pnode=^node;
  node=record
         x:longint;
         next:pnode;
       end;
var
  n,m:longint;
  a,b,c:array[1..500000]of longint;
  w_i:array[1..100000]of longint;
  map:array[1..100000]of pnode;
  buy,sell:array[1..100000]of longint;
  h:array[1..200000]of longint;
  f_bo:array[1..200000]of boolean;
procedure init;
begin
  assign(input,'rq520.in');
  assign(output,'rq520.out');
  reset(input); rewrite(output);
end;

procedure terminate;
begin
  close(input); close(output);
  halt;
end;

procedure insert(x,y:longint);
var
  p:pnode;
begin
  new(p);
  p^.x:=y;
  p^.next:=map[x];
  map[x]:=p;
end;

procedure spfa1;
var
  l,r:longint;
  x:longint;
  p:pnode;
  i:longint;
  min:longint;
begin
  fillchar(buy,sizeof(buy),$7);
  fillchar(f_bo,sizeof(f_bo),true);
  buy[1]:=w_i[1];
  l:=0; r:=1;
  h[1]:=1;
  f_bo[1]:=false;
  repeat
    inc(l);
    x:=h[l];
    p:=map[x];
    while p<>nil do
      begin
        if buy[x]<buy[p^.x] then
          begin
            min:=buy[x];
            if buy[x]>w_i[p^.x] then
              min:=w_i[p^.x];
            buy[p^.x]:=min;
            if f_bo[p^.x] then
            begin
              f_bo[p^.x]:=false;
              inc(r);
              h[r]:=p^.x;
            end;
          end;
        p:=p^.next;
      end;
    f_bo[x]:=true;
  until l>=r;
end;

procedure spfa2;
var
  l,r:longint;
  x:longint;
  p:pnode;
  i:longint;
  max:longint;
begin
  fillchar(sell,sizeof(sell),0);
  fillchar(f_bo,sizeof(f_bo),true);
  sell[n]:=w_i[n];
  l:=0; r:=1;
  h[1]:=n;
  f_bo[n]:=false;
  repeat
    inc(l);
    x:=h[l];
    p:=map[x];
    while p<>nil do
      begin
        if sell[x]>sell[p^.x] then
          begin
            max:=sell[x];
            if max<w_i[p^.x] then max:=w_i[p^.x];
            sell[p^.x]:=max;
            if f_bo[p^.x] then
              begin
                f_bo[p^.x]:=false;
                inc(r);
                h[r]:=p^.x;
              end;
          end;
        p:=p^.next;
      end;
    f_bo[x]:=true;
  until l>=r;
end;

procedure main;
var
  i:longint;
  x,y,z:longint;
  ans:longint;
begin
  readln(n,m);
  for i:=1 to n do
    begin
      read(w_i[i]); map[i]:=nil;
    end;
    
  for i:=1 to m do
    begin
      readln(x,y,z);
      insert(x,y);
      if z=2 then insert(y,x);
      a[i]:=x;  b[i]:=y;  c[i]:=z;
    end;
  spfa1;
  
  for i:=1 to n do map[i]:=nil;
  for i:=1 to m do
    begin
      insert(b[i],a[i]);
      if c[i]=2 then insert(a[i],b[i]);
    end;
  spfa2;
  ans:=0;
  
  for i:=1 to n do
    if sell[i]-buy[i]>ans then ans:=sell[i]-buy[i];
    
  writeln(ans);
end;

begin
  init;
  main;
  terminate;
end.