通过ADB来实现脚本来控制手机

ADB

简介

adb的全称为Android Debug Bridge,安卓调试桥,可以通过调试命令来控制手机,诸如开机,关机等按键控制;或者启动,关闭应用;异或进行触摸模拟.

通过学习adb,可以实现简单的脚本控制,最大的特点是不需要root,对于普通手机都可以进行,帮助我们完成一些简单的重复性事件,诸如刷资源,各种app的签到

环境配置

电脑端

将下面3个文件弄到一个文件夹里D:\android\adb,然后将其添加到path,adb环境就配置好了

AdbWinUsbApi.dll
AdbWinApi.dll
adb.exe

然后将这个文件夹添加到path中

cmd中 adb version检查是否添加成功

手机端

开发者选项

开启开发者选项 : 以小米手机为例,先进入开发者设置,miui版本号点5下,更多设置->开发者选项->开启

打开usb调试 : 在开发者选项中,开启usb调试以便于执行adb指令,miui还需要开启usb调试(安全设置)

获取坐标 : 开发者选项中,开启指针位置以便于模拟触摸时获取位置

设备管理

远程调试

基于内网穿透实现远程调试,就可以不用占用那少得可怜的usb口了,下面是统一管理所有设备的命令

开启关闭服务,默认会自动开启,关闭服务可用于断开多个连接的设备
adb start-server
adb kill-server

adb devices 查看设备列表,如果有模拟器一般会自动连接,所以如果想在开模拟器时断开设备就需要获取模拟器ip:port然后断开

实现步骤

先使用内网穿透得到虚拟IP 如100.119.133.92

推荐tailscale或蒲公英

手机通过usb调试设置监听端口adb tcpip 5555

断开手机后,电脑连接 如adb connect 100.119.133.92:5555

调试结束后可以adb disconnect 100.119.133.92:5555 断开连接

远程控制

scrcpy 使用这个软件,在上面远程连接之后就可以进行远程控制,当然也可以直接连usb获得稳定的投屏

手机adb

Local ADB

• 先连接任意一个 Wi-Fi，就算没有接入互联网都可以；
• 然后打开 LADB，将它调整为小窗模式（或分屏模式）——因为无线调试的配对码等信息每次点击都会动态生成，所以才需要小窗模式同时打开本应用和开发者选项；
• 进入开发者选项，开启无线调试，首次使用需要配对设备，将配对码和端口填入本应用即可；
• 开心使用adb

应用管理

常见命令中常见pm和am的缩写

pm package manager

am activity manager

一个package下有多个activity(界面)

查看应用列表

adb shell pm list packages    		查看所有应用
adb shell pm list packages -s		查看系统应用
adb shell pm list packages -3		查看第三方应用
adb shell pm list packages vivo	 	查看带关键词vivo的应用

安装应用

adb install [-r] [-d] [-g] <apk-file>
-r覆盖 -d降级覆盖 -g授予所有运行权限

例如 adb install "D:\android\apk\com.supercell.clashofclans.apk"

卸载应用

adb uninstall [-k] <package-name>
-k 表示卸载应用但保留数据和缓存目录。

例如adb uninstall com.supercell.clashofclans

获取activity和package

由adb shell dumpsys window w | findstr mCurrent

得到 mCurrentFocus=Window{8554b85 u0 com.supercell.clashofclans/com.supercell.titan.GameApp}

然后可以得到

activity : com.supercell.clashofclans/com.supercell.titan.GameApp

package : com.supercell.clashofclans

可以通过下面cmd代码获取

@echo off

setlocal enabledelayedexpansion
rem 先查询window w mCurrent属性，如果为空，则查询window w imeControlTarget属性
for /f "delims=" %%a in ('adb shell dumpsys window w ^| findstr mCurrent') do set activity=%%a 
if "!activity!"=="" (
for /f "delims=" %%a in ('adb shell dumpsys window w ^| findstr imeControlTarget') do set activity=%%a )

rem 然后对获得的结果进行处理提取得到activity和package,先去除},然后取空格分隔的最后一部分,即activity,之后再得到package
for /f "delims=}" %%a in ("!activity!") do set activity=%%a 
rem for /f "tokens=3 delims= " %%a in ("!activity!") do set activity=%%a
for %%I in (!activity!) do (set activity=%%I) 
for /f "tokens=1 delims=/" %%a in ("!activity!") do set package=%%a

echo activity  :  !activity!
echo package   :  !package!

endlocal

提取安装包

获取了安装路径后pull到指定目录里并重命名为com.supercell.clashofclans.apk

adb shell pm path com.supercell.clashofclans
adb pull /data/app/com.supercell.clashofclans-HyrIPsbKlOHBjZwM4LnczA==/base.apk D:\android\com.supercell.clashofclans.apk

用cmd实现批量操作

@echo off
rem 获取安装包
set outputpath=D:\android\apk\
set package=com.supercell.clashofclans
for /f "delims=" %%a in ( 'adb shell pm path %package%' ) do set originalString=%%a
for /f "tokens=2 delims=:" %%a in ("%originalString%") do set apkpath=%%a
adb pull %apkpath% %outputpath%%package%.apk

启动和停止应用

rem 启动
adb shell am start -n com.supercell.clashofclans/com.supercell.titan.GameApp>nul
rem 强行停止
adb shell am force-stop com.supercell.clashofclans

行为模拟

按键模拟

按键模拟都是像下面这种格式,不同的按键对应不同的id

rem 模拟主页键
adb shell input keyevent 3

下面是常用id-按键表

id	按键
3	home
4	返回
187	多任务
24	增加音量
25	减小音量
26	电源键
164	静音
220	提高亮度
221	降低亮度

详细的见官网 KeyEvent | Android Developers

触摸模拟

rem 单击 (1200,70)为x,y坐标
adb shell input tap 1200 70

rem 滑动 从(600,700)滑动到(600,900)经历1000ms
adb shell input swipe 600 700 600 900 1000

rem 长按 用滑动实现
adb shell input swipe 100 100 100 100 1000

系统控制

rem 执行关机命令
adb shell reboot -p

rem 执行重启命令
adb shell reboot

rem 进入Recovery
adb reboot recovery

rem 进入Fastboot
adb reboot fastboot

实战

获取当前活动的activity和package

@echo off

setlocal enabledelayedexpansion
rem 先查询window w mCurrent属性
for /f "delims=" %%a in ('adb shell dumpsys window w ^| findstr mCurrent') do set activity=%%a 
if "!activity!"=="" ( REM 如果没有查询到，则查询window w imeControlTarget属性,此处只试了两款手机,其他的可以自己打印出window w再找
for /f "delims=" %%a in ('adb shell dumpsys window w ^| findstr imeControlTarget') do set activity=%%a )

rem 然后对获得的结果进行处理提取得到activity和package,先去除},然后取空格分隔的最后一部分,即activity,之后再得到package
for /f "delims=}" %%a in ("!activity!") do set activity=%%a 
rem 通过循环得到空格的最后一段,因为不同的指令输出的我们所需的信息都在最后
for %%I in (!activity!) do (set activity=%%I)  
for /f "tokens=1 delims=/" %%a in ("!activity!") do set package=%%a

echo activity  :  !activity!
echo package   :  !package!

endlocal

coc辅助刷夜世界资源

坐标需要根据屏幕分辨率自行调整

chcp 65001
@echo off

set m=7
:m
set /a m+=1

adb shell am start -n com.supercell.clashofclans/com.supercell.titan.GameApp > nul
choice /t 12 /d y  >nul

set  /a n = %m% %% 8
if %n% == 0  (
echo 圣水已收集
adb shell input swipe 600 700 600 900 1000
adb shell input tap 1060 80
adb shell input tap 1100 600
adb shell input tap 1200 70
)

rem 皮卡一字滑
adb shell input tap 120 650
adb shell input tap 1035 500
choice /t 5 /d y  >nul

adb shell input tap 360 650
FOR /L %%i in (1,1,2) DO (
adb shell input tap 200 100
adb shell input tap 200 450
adb shell input tap 1200 100
adb shell input tap 1200 450
)

adb shell am force-stop com.supercell.clashofclans
goto m