Faster-RCNN_TF代码解读19：bbox.pyx

# --------------------------------------------------------
# Fast R-CNN
# Copyright (c) 2015 Microsoft
# Licensed under The MIT License [see LICENSE for details]
# Written by Sergey Karayev
# --------------------------------------------------------

cimport cython
import numpy as np
cimport numpy as np

DTYPE = np.float
ctypedef np.float_t DTYPE_t
# rpn：region proposal network
# IoU：Intersection-over-Union，交集并集之比
# GT：ground truth，GT boxes (x1, y1, x2, y2, label)，左上的坐标 和 右下的坐标 + label
# im：image
# ROI：region of interest
# bbox：bounding-box
# regression：和one hot的classification其实区别不大，只是target是（可能为0和1以及）其他数字
# anchor：一个box，通过从上一个卷积层的结果 滑动得到很多个，每个要和 GT的box 计算bbox_overlap
# bbox_overlap：貌似就是IoU，源码如下

def bbox_overlaps(
        np.ndarray[DTYPE_t, ndim=2] boxes,
        np.ndarray[DTYPE_t, ndim=2] query_boxes):
    """
    Parameters
    ----------
    boxes: (N, 4) ndarray of float
    query_boxes: (K, 4) ndarray of float
    Returns
    -------
    overlaps: (N, K) ndarray of overlap between boxes and query_boxes
    """
    #记录anchor的个数
    cdef unsigned int N = boxes.shape[0]
    #记录ground-truth的个数
    cdef unsigned int K = query_boxes.shape[0]
    #创建一个全零arrayoverlaps
    cdef np.ndarray[DTYPE_t, ndim=2] overlaps = np.zeros((N, K), dtype=DTYPE)
    cdef DTYPE_t iw, ih, box_area
    cdef DTYPE_t ua
    cdef unsigned int k, n
    for k in range(K):
        box_area = (#query_boxes（GT）的面积
            (query_boxes[k, 2] - query_boxes[k, 0] + 1) *#列数（x）
            (query_boxes[k, 3] - query_boxes[k, 1] + 1)#行数
        )
        #每一个anchor与当前GT比一下
        for n in range(N):
            iw = (#计算重叠部分的宽
                min(boxes[n, 2], query_boxes[k, 2]) -
                max(boxes[n, 0], query_boxes[k, 0]) + 1
            )
            if iw > 0:
                ih = (#计算重叠部分的高
                    min(boxes[n, 3], query_boxes[k, 3]) -
                    max(boxes[n, 1], query_boxes[k, 1]) + 1
                )
                if ih > 0:
                    ua = float(#计算（anchor+GT-重叠）的面积
                        (boxes[n, 2] - boxes[n, 0] + 1) *
                        (boxes[n, 3] - boxes[n, 1] + 1) +
                        box_area - iw * ih
                    )
                    #对应（n，k）元素存入（重叠/（anchor+GT-重叠））面积
                    overlaps[n, k] = iw * ih / ua
    return overlaps