Android Gradle 插件编写

现在绝大多数的android项目都是使用gradle来构建了,相信大家对gradle已经很熟悉了.像是声明当前module为application, library或者java;又像通过配置android {...}的属性来影响构建或者编译的过程;或者当引入一些需要参与到编译过程的库时,经常需要使用自定义的gradle的插件.那么这些究竟是怎么实现的? 这篇文章就结合gradle配置,插件和Task实现一个简单场景的插件.后面会有文章涉及到复杂的应用场景.

插件实现

  1. 建立一个插件module, 在module下的build.gradle中按照如下配置.先声明groovy插件, 在依赖中引用gradle和groovy的接口库.这样就构建出可以编写gradle插件的环境了.

    apply plugin: 'groovy'
    	
    dependencies {
        compile gradleApi()
        compile localGroovy()
    }
    
    sourceSets {
        main {
            groovy {
                srcDir 'src/main/groovy'
            }
    
            resources {
                srcDir 'src/main/resources'
            }
        }
    }
    
  2. 先建立一个extension对象, 用来在插件中构建并存储gradle 配置block中的属性.这里的属性定义和gradle配置中的要一一对应.这里重写类的toString方法,将各个属性拼装起来.

    public class PatcherExtension {
    
        String sourceApk
    
        boolean ignoreWarning
    
        boolean useSign
    
        PatcherExtension() {
            sourceApk = ''
            ignoreWarning = false
            useSign = true
        }
    
        @Override
        public String toString() {
            """| sourceApk = ${sourceApk}
               | ignoreWarning = ${ignoreWarning}
               | useSign = ${useSign}
            """.stripMargin()
        }
    
  3. 构建一个Task通过继承DefaultTask来实现,在构造方法中设置group(默认为other), 再通过注解@TaskAction来标记该Task执行中触发的入口方法. PatcherTask在执行的时候会调用构建出来的PatcherExtension对象的toString方法,并将其打印出来.

    public class PatcherTask extends DefaultTask {
    
        PatcherTask() {
            super()
            group = 'patcher'
        }
    
        @TaskAction
        public void test() {
            println(project.patcher.toString());
        }
    }
    
  4. 接着通过实现Plugin的接口来创建出一个插件.接受gradle中的配置,构建名为patcher的extension.并且构建出名为patcherTest的PatcherTask对象.

    public class PatcherPlugin implements Plugin<Project> {
        private final String EXTENSION_PATCHER = "patcher"
    
        @Override
        void apply(Project project) {
            project.extensions.create(EXTENSION_PATCHER, PatcherExtension)
            project.tasks.create("patcherTest", PatcherTask)
        }
    }
    
  5. 创建出gradle插件之后还需要声明一下才能被外部使用,声明的方式就是在resources路径下建立META-INF/gradle-plugins/xxx.properties文件,这个xxx就是对外暴露插件的别名,而这个声明文件的内容要映射到真实的plugin实现类.

    implementation-class=cn.jesse.patcher.build.gradle.PatcherPlugin
    

插件引入

到这里插件的各个部分都已经实现完成了,接下来在要引入插件的工程中配置插件.这里采用本地引入的方式, maven的部署后面会有文章统一介绍.

  1. 首先在项目根目录下的build.gradle中以本地的方式引入插件的jar包.

    dependencies {
        classpath fileTree(dir: 'patcher-build/patch-gradle-plugin/build/libs', include: ['*.jar'])
    }
    
  2. 在application的build.gradle中引用插件, 并在插件block中配置前面extension中声明的属性.

    apply plugin: 'patcher'
    
    patcher {
        sourceApk 'test.apk'
        ignoreWarning true
        useSign true
    }
    
  3. sync工程.如果提示插件没有找到的话就先编译一下插件module,生成插件jar包.

    build patcher module

    一切就绪之后就可以在gradle面板中看到插件中构建的patcherTest任务.

    gradle patcherTest

插件执行

直接执行gradle面板中的patcherTest或者在项目根目录下执行./gradlew patcherTest就可以在终端中看到插件根据gradle配置构建出的extension对象,并在task中将其打印出来的结果.不仅如此,task还可以插入到编译task中,根据插入的不同位置可以处理不同编译阶段的中间数据.例如在processManifest之后插入一个修改androidManifest文件内容的任务,就可以达到修改打包apk一些属性的目的.

exec result

源码地址: https://github.com/HiJesse/Android-Patcher

插件module路径 /patcher-build/patch-gradle-plugin

application路径 /sample


转载请注明出处:http://blog.csdn.net/l2show/article/details/53728652

发布了66 篇原创文章 · 获赞 15 · 访问量 78万+
展开阅读全文

没有更多推荐了,返回首页

©️2019 CSDN 皮肤主题: 技术黑板 设计师: CSDN官方博客

分享到微信朋友圈

×

扫一扫,手机浏览