洛谷 P1156 垃圾陷阱

题目描述

卡门――农夫约翰极其珍视的一条Holsteins奶牛――已经落了到“垃圾井”中。“垃圾井”是农夫们扔垃圾的地方，它的深度为D(2<=D<=100)英尺。

卡门想把垃圾堆起来，等到堆得与井同样高时，她就能逃出井外了。另外，卡门可以通过吃一些垃圾来维持自己的生命。

每个垃圾都可以用来吃或堆放，并且堆放垃圾不用花费卡门的时间。

假设卡门预先知道了每个垃圾扔下的时间t(0< t<=1000)，以及每个垃圾堆放的高度h(1<=h<=25)和吃进该垃圾能维持生命的时间f(1<=f<=30)，要求出卡门最早能逃出井外的时间，假设卡门当前体内有足够持续10小时的能量，如果卡门10小时内没有进食，卡门就将饿死。

输入输出格式

输入格式：
第一行为2个整数，D 和 G (1 <= G <= 100)，G为被投入井的垃圾的数量。

第二到第G+1行每行包括3个整数：T (0 < T <= 1000)，表示垃圾被投进井中的时间；F (1 <= F <= 30)，表示该垃圾能维持卡门生命的时间；和 H (1 <= H <= 25)，该垃圾能垫高的高度。

输出格式：
如果卡门可以爬出陷阱，输出一个整表示最早什么时候可以爬出；否则输出卡门最长可以存活多长时间。

输入输出样例

输入样例#1：
20 4
5 4 9
9 3 2
12 6 10
13 1 1
输出样例#1：
13
说明

[样例说明]

卡门堆放她收到的第一个垃圾：height=9；

卡门吃掉她收到的第二个垃圾，使她的生命从10小时延伸到13小时；

卡门堆放第3个垃圾，height=19；

卡门堆放第4个垃圾，height=20。

分析：设f[i]为高度堆叠到i时，生命最长维持到多久，有
f[i+h]=max(f[i+h],f[i]) {这块垃圾用来堆叠，高度为h}
f[i]=f[i]+m {m为可以延长生命时间，这块垃圾用来吃}

前提条件为f[i]>=t （t为垃圾下落时间，如果生命不能维持到这时，就不能吃或堆叠）

代码：

type
 node=record
  h,t,m:longint;
 end;
var
 n,i,j,d,g:longint;
 a:array [1..101] of node;
 f:array [0..101] of longint;
procedure qsort(l,r:longint);
  var
    i,j,key:longint;
    temp:node;
  begin
    if l>=r then exit;
    i:=l;j:=r;
    key:=a[l+random(r-l+1)].t;
    repeat
      while  (a[i].t<key) do inc(i);
      while  (a[j].t>key) do dec(j);
      if i<=j then
      begin
        temp:=a[i];a[i]:=a[j];a[j]:=temp;
        inc(i);dec(j);
      end;
    until i>j;
    qsort(l,j);
    qsort(i,r);
  end;

begin
 readln(d,g);
 for i:=1 to g do
  read(a[i].t,a[i].m,a[i].h);
 qsort(1,g);
 f[0]:=10; 
 for i:=1 to g do
  begin
   with a[i] do
    begin
     for j:=d downto 0 do
      if f[j]>=t then
      begin
       if j+h>=d then
        begin
         writeln(t);
         exit;
        end;
        if f[j]>f[j+h] then
          f[j+h]:=f[j];
        f[j]:=f[j]+m;
      end;
    end;
  end;
 writeln(f[0]);
end.