jzoj. 1154. 【GDOI2003】购物

Description

　　GDOI商场推出优惠活动，以超低价出售若干种商品。但是，商场为避免过分亏本，规定某些商品不能同时购买，而且每种超低价商品只能买一件。身为顾客的你想获得最大的实惠，也就是争取节省最多的钱。经过仔细研究，发现商场出售的超低价商品中，不存在以下情况： 　　n(n>=3)种商品C1,C2,…..,Cn,其中Ci,Ci+1是不能同时购买的(i=1,2…,n-1)并且C1, Cn也不能同时购买。 　　编程计算可以节省的最大金额数。

Input

　　第一行两个整数K,M(1<=K<=1000).其中K表示超低价商品数。K种商品的编号依次为1,2,…,K。M表示不能同时购买的商品对数.接下来K行，第i行有一个整数Xi表示购买编号为i的商品可以节省的金额(1<=Xi<=100).再接下来M行，每行两个数A ,B,表示A和B不能同时购买，1<=A<=K,1<=B<=K,A<>B

Output

　　仅一个整数，表示能节省的最大金额数。

Sample Input

3 1
1 1 1
1 2

Sample Output

2

分析：
我们把每一对关系连接起来，于是就有了一个图，题目说明了对于任意数据不存在环和连向自己的边，显然是树，但是不一定只有一棵树（注意）。对于每一棵树，我们假设f[x,0]为不选当前节点的最优值，f[x,1]位选当前节点的最优值，y为x的儿子之一,有
f[x,0]=sum(max(f[y,1],f[y,0])) {当前点不选，显然儿子全都可以选择选或不选，肯定选大的啦}
f[x,1]=sum(f[y,0])+a[x] {a[x]为x点的收益，显然选，儿子只能不选，当然要把所有儿子加起来}
答案就是所有树的最大值得和。
Ans=sum(max(f[root,0],f[root,1])) {这就不用解释了吧}

代码：

type
 node=record
  y,next:longint;
 end;

var
 f:array [1..1001,0..1] of longint;
 a,ls:array [1..2001] of longint;
 g:array [1..5001] of node;
 v:array [1..2000] of boolean;
 i,j,ans,n,m,x,y,o:longint;

procedure add(x,y:longint);
 begin
  inc(o);
  g[o].y:=y;
  g[o].next:=ls[x];
  ls[x]:=o;
 end;

function max(x,y:longint):longint;
 begin
  if x>y then exit(x)
         else exit(y);
 end;

procedure dfs(x:longint);
 var t,y:longint;
begin
 t:=ls[x];
 while t>0 do
  begin
   y:=g[t].y;
   if v[y]=false then
    begin
     v[y]:=true;
     dfs(y);
     f[x,0]:=f[x,0]+max(f[y,1],f[y,0]);
     f[x,1]:=f[x,1]+f[y,0];
    end;
   t:=g[t].next;
  end;
 f[x,1]:=f[x,1]+a[x];
end;

begin
 read(n,m);
 for i:=1 to n do
  read(a[i]);
 for i:=1 to m do
  begin
   read(x,y);
   add(x,y);
   add(y,x);
  end;
 fillchar(v,sizeof(v),false);
 for i:=1 to n do
  begin
   if v[i]=false then
    begin
     v[i]:=true;
     fillchar(f,sizeof(f),0);
     dfs(i);
     ans:=ans+max(f[i,1],f[i,0]);
    end;
  end;
 writeln(ans);
end.