使用FLEX和Actionscript开发FLASH 游戏-碰撞检测(第二页)
GameObject.as
package
{
import flash.display.*;
import flash.events.*;
import flash.geom.*;
/* The base class for all objects in the game */
public class GameObject
{
//object position
public var position:Point=new Point(0,0);
//higher ZOrder objects are rendered on top of lower ones
public var zOrder:int=0;
//the bitmap data to diaplay
public var graphics:GraphicsResource=null;
//true if the object is active in the game
public var inuse:Boolean=false;
public var collisionArea:Rectangle;
public var collisionName:String=CollisionIdentifiers.NONE;
public function get CollisionArea():Rectangle
{
return new Rectangle(position.x,position.y,collisionArea.width,collisionArea.height);
}
public function GameObject()
{
}
public function startupGameObject(graphics:GraphicsResource,position:Poin,z:int=0):void
{
if(!inuse)
{
this.graphics=graphics;
this.zOrder=z;
this.position=position.clone();
this.inuse=true;
GameObjectManager.Instance.addGameObject(this);
setupCollision();
}
}
public function shutdown():void
{
if(inuse)
{
graphics=null
inuse=false;
GameObjectManager.Instance.removeGameObject(this);
}
}
public function copyToBackBuffer(db:BitmapData):void
{
db.copyPixels(graphics.bitmap,graphics.bitmap.rect,position,
graphics.bitmapAlpha,new Point(0,0),true);
}
public function enterFrame(dt:Number):void
{
}
public function mouseDown(event:MouseEvent):void
{
}
public function click(event:MouseEvent):void
{
}
public function mouseUp(event:MouseEvent):void
{
}
public function mouseMove(event:MouseEvent):void
{
}
protected function setupCollision():void
{
collisionArea=graphics.bitmap.rect;
}
public function collision(other:GameObject):void
{
}
}
}
我们增加了两个新的属性:碰撞区(collisionArea)和碰撞名(collisionName)。碰撞区属性代表了上文所述的描述碰撞区的矩形。碰撞名属性是赋给游戏对象用来定义它是哪种对象的名字,至少对于碰撞检测系统而言的种类。例如:被游戏者发出的子弹的碰撞名为“游戏者武器”,而一架敌机的碰撞名则是“敌人”。缺省状态下我们把它设置为“None”,使用CollisionIdentifiers类的NONE属性。
另外我们也增加了三个新的函数:碰撞(collision)、碰撞区域(CollisionArea)和设置碰撞(setupCollision)。碰撞函数是一个空函数,以待被继承类方法所覆盖。设置碰撞函数被用来负责保存碰撞检测系统下的图片的大小。碰撞区域函数返回碰撞区矩形目前在屏幕上的位置。
你可能想问为什么我们还麻烦地设置一个collsionArea属性,它实际上和graphics.bitmap.rect是完全一样的。只是因为后面(在第七章)我们将增加游戏的动画部分。动画类将用自己的转门的逻辑覆盖设置碰撞函数。虽然现在碰撞区域和图片的矩形一样。
CollisionIdentifiers.as
package
{
public class CollisionIdentifiers
{
public static const NONE:String="None";
public static const PLAYER:String="Player";
public static const PLAYERWEAPON:String="PlayerWeapon";
public static const ENEMYWEAPON:String="EnemyWeapon";
public static const ENEMY:String="Enemy";
public static const POWERUP:String="Powerup";
}
}
就像ZOrders类一样,CollisionIdentifiers类被用来保存一些预定义的静态属性;这里就是碰撞名。这么做的目的还是为了促进自文档化。CollisionIdentifiers.PLAYER的意思不言自明,然而字符串“Player”却没有同样的内在含义。
现在让我们看看在GameObjectManager类中做的改变。
<Previous Page| page: 1 2 3 4 5 6 | Next Page>