【as3手册小记】用鼠标跟随方法来创建拖动效果

// 此代码使用鼠标跟随
// 技术创建拖放交互组件。
// 圆和正方形是 DisplayObject （例如 MovieClip 或 Sprite
// 实例）。
import flash.display.DisplayObject;
import flash.events.MouseEvent;
var offsetX:Number;
var offsetY:Number;
var draggedObject:DisplayObject;
// 按下鼠标按键时会调用此函数。
function startDragging(event:MouseEvent):void
{
// 记住正在拖动的对象
draggedObject = DisplayObject(event.target);
// 记录按下鼠标按键时光标的位置
// 与按下鼠标按键时拖动的对象的 x, y 坐标
// 之间的差异（偏移量）。
offsetX = event.stageX - draggedObject.x;
offsetY = event.stageY - draggedObject.y;
// 将所选对象移到显示列表的顶部
stage.addChild(draggedObject);
// 通知 Flash Player 开始侦听 mouseMove 事件。
stage.addEventListener(MouseEvent.MOUSE_MOVE, dragObject);
}
// 松开鼠标按键时会调用此函数。
function stopDragging(event:MouseEvent):void
{
// 通知 Flash Player 停止侦听 mouseMove 事件。
stage.removeEventListener(MouseEvent.MOUSE_MOVE, dragObject);
}
// 只要按下鼠标按键，
// 每次移动鼠标时都会调用此函数。
function dragObject(event:MouseEvent):void
{
// 将拖动的对象移到光标的位置，从而保持
// 光标的位置和拖动的对象的位置
// 之间的偏移量。
draggedObject.x = event.stageX - offsetX;
draggedObject.y = event.stageY - offsetY;
// 指示 Flash Player 在此事件后刷新屏幕。
event.updateAfterEvent();
}
circle.addEventListener(MouseEvent.MOUSE_DOWN, startDragging);
circle.addEventListener(MouseEvent.MOUSE_UP, stopDragging);
square.addEventListener(MouseEvent.MOUSE_DOWN, startDragging);
square.addEventListener(MouseEvent.MOUSE_UP, stopDragging);