泡泡大战 源码

最新推荐文章于 2020-12-12 11:47:34 发布
最新推荐文章于 2020-12-12 11:47:34 发布
阅读量318 收藏
点赞数
分类专栏： qml
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/lvmengzou/article/details/86688020
版权

以下是泡泡大战源码， 运行 效果图如下：

 

import QtQuick 2.2
import QtQuick.Controls 1.2
 
Rectangle {
    width: 360;
    height: 420;
    color: "#E0E0E0";
    id: root;
    focus: true;
 
    Row {
        id: bubbles;
        anchors.top: parent.top;
        anchors.horizontalCenter: parent.horizontalCenter;
        spacing: 2;
        property var diedCount: 0;
 
        Component.onCompleted: {
            var i = 0;
            var qmlStringBegin = "import QtQuick 2.2; Image{width: 30; height:30; property var died: false; source: \"res/bubble_";
 
            for(; i < 8; i++){
                var qmlString = qmlStringBegin + (i+1) + ".png\";}";
                bubbles.children[i] = Qt.createQmlObject(qmlString, bubbles, "DynamicImage");
            }
        }        
 
        function allDie(){
            return diedCount == children.length;
        }
 
        function reset(){
            diedCount = 0;
            var i = 0;
            var bubble;
            for(; i < bubbles.children.length; i++){
                bubble = bubbles.children[i];
                bubble.died = false;
                bubble.source = "res/bubble_" + (i+1) + ".png";
                bubble.opacity = 1.0;
            }
        }                                             
    }
 
    Text {
        id: scoreInfo;
        anchors.horizontalCenter: parent.horizontalCenter;
        anchors.top: bubbles.bottom;
        anchors.topMargin: 4;
        font.pixelSize: 26;
        font.bold: true;
        color: "blue";
    }
 
    Image {
        id: turret;
        width: 50;
        height: 80;
        anchors.bottom: parent.bottom;
        anchors.horizontalCenter: parent.horizontalCenter;
        source: "res/turret.png";
        transformOrigin: Item.Bottom;
    }
 
    Image {
        id: bullet;
        width: 40;
        height: 40;
        source: "res/knife.png";
        z: 2;
        visible: false;
    }
 
    NumberAnimation {
        property var rotateAngle: 0;
 
        function rotate(angle){
            rotateAngle += angle;
            if(running == false){
                rotateTurret();
            } 
        }
 
        function rotateTurret(){
            if(rotateAngle != 0){
                from = turret.rotation;
                to = turret.rotation + rotateAngle;
                if(to > 80 ) to = 80;
                else if(to < -80) to = -80;
                var distance = to - from;
                duration = Math.min( 100 * Math.abs(distance / 3), 800);
                start();
                rotateAngle = 0;
            }
        }
 
        id: animateTurret;
        target: turret;
        property: "rotation";
        onStopped: {
            rotateTurret();
        }
    }
 
    NumberAnimation {
        id: aboutDie;
        property: "opacity";
        duration: 400;
        from: 1.0;
        to: 0;
        onStopped:{
            showDie.start();
        }
    }
 
    NumberAnimation {
        id: showDie;
        property: "opacity";
        duration: 400;
        from: 0;
        to: 0.6;
        property var diedImage;
        onStarted: {
            target.source = diedImage;
        }
        onStopped:{
            root.resetBullet();
            bubbles.diedCount++;
            if(bubbles.allDie() == true){
                passed.showPass(true);
                deadline.stop();
                root.showScore();
            }
        }            
    }
 
    ParallelAnimation {
        id: animateBullet;
        property var fire: 0; // 0 - init; 1 - shotting; 2 - resetting
        property var diedBubble: -1;
 
        function caculateDiedBubble(){
            var crossX = turret.rotation == 0 ? (root.width/2 - bullet.width/2) : (root.width/2 - bullet.width/2) + (15 - (root.height - bullet.height/2))/Math.tan((90 + turret.rotation)*0.017453293);
            var i = 0;
            var bubble;
            for(diedBubble = -1; i < bubbles.children.length; i++){
                bubble = bubbles.children[i];
                if(crossX > bubbles.x + bubble.x && crossX < bubbles.x + bubble.x + bubble.width){
                    if(bubble.died == false) diedBubble = i;
                    break;
                }
            }
        }
 
        NumberAnimation {
            id: animateBulletX;
            target: bullet;
            property: "x";
            duration: 1200;
            easing.type: Easing.OutCubic;
 
        }
        NumberAnimation {
            id: animateBulletY;
            target: bullet;
            property: "y";
            duration: 1200;
            easing.type: Easing.OutCubic;
        }
        onStopped: {
            if(fire == 1){
                if(diedBubble >=0 ){
                    var bubble = bubbles.children[diedBubble];
                    bubble.died = true;
                    showDie.diedImage = "res/frozen_" + (diedBubble+1) + ".png";
                    aboutDie.target = bubble;
                    showDie.target = bubble;
                    aboutDie.start();
                }else{
                    root.resetBullet();
                }
            }else{
                fire = 0;
                bullet.visible = false;
                if( root.requestReset == true ){
                    root.requestReset = false;
                    playGame.enabled = true;
                }
            }
        }
    }
 
    /*
    * y - y1 = tan(90+rotation)*(x - x1)
    */
    function fire(){
        if(playGame.enabled || animateBullet.fire != 0) return;
        bullet.visible = true;
        animateBullet.caculateDiedBubble();
        animateBulletX.duration = 1200;
        animateBulletX.from = bullet.x;
        if(turret.rotation == 0) animateBulletX.to = bullet.x;
        else animateBulletX.to = (root.width/2 - bullet.width/2) - (root.height - bullet.height/2)/Math.tan((90 + turret.rotation)*0.017453293);
        animateBulletY.duration = 1200;
        animateBulletY.from = bullet.y;
        animateBulletY.to = 5;
        animateBullet.start();
        animateBullet.fire = 1;
    }
 
    function resetBullet(){
        if(animateBullet.fire == 1){
            animateBullet.fire = 2;
            animateBulletX.from = bullet.x;
            animateBulletX.to = root.width/2 - bullet.width/2;
            animateBulletX.duration = 500;
            animateBulletY.from = bullet.y;
            animateBulletY.to = root.height - bullet.height/2;
            animateBulletY.duration = 500;
            animateBullet.start();
        }
    }
 
    Text {
        id: leftSeconds;
        anchors.centerIn: parent;
        color: "red";
        font.pixelSize: 20;
    }
 
    Timer {
        id: deadline;
        interval: 1000;
        repeat: true;
        onTriggered: {
            var curDate = new Date();
            var milliSeconds = maxGameTime - (curDate.getTime() - startDate.getTime());
            if(milliSeconds <= 0){
                failed.showFailed(true);
                deadline.stop();
            }else{
                var seconds = Math.round(milliSeconds / 1000);
                if(seconds == 0) seconds = 1;
                leftSeconds.text = "Left Time: " + seconds;
            }
        }
    }
 
    function showScore(){
        var curDate = new Date();
        var seconds = Math.round((curDate.getTime() - startDate.getTime())/1000);
        if(seconds <= 27){
            scoreInfo.text = +seconds + "S! Excellent!";
        }else if(seconds <= 32){
            scoreInfo.text = +seconds + "S! Good!";
        }else if(seconds <= 42){
            scoreInfo.text = + seconds + "S! Yep, pass.";
        }else{
            scoreInfo.text = + seconds + "S! Try again.";
        }
    }
 
    property var startDate;
    property var requestReset: false;
    readonly property var maxGameTime: 70000;
 
    Button {
        id: resetGame;
        text: "Reset";
        anchors.left: parent.left;
        anchors.leftMargin: 4;
        anchors.bottom: parent.bottom;
        anchors.bottomMargin: 4;        
        onClicked: {
            root.requestReset = true;
            bubbles.reset();
            deadline.stop();
            turret.rotation = 0;
            if( animateBullet.fire == 1 ){
                root.resetBullet();
            }else if( animateBullet.fire == 0 ){
                playGame.enabled = true;
                root.requestReset = false;
            }
            failed.showFailed(false);
            passed.showPass(false);
            leftSeconds.text = "";
            scoreInfo.text = "";
        }
    }
 
    Button {
        id: playGame;
        text: "Play";
        anchors.left: parent.left;
        anchors.leftMargin: 4;
        anchors.bottom: resetGame.top;
        anchors.bottomMargin: 4;
 
        onClicked: {
            root.startDate = new Date();
            deadline.restart();
            playGame.enabled = false;
            root.requestReset = false;
            root.resetBulletPos();
        }
    }
 
    Image {
        id: passed;
        visible: false;
        width: 200;
        height: 51;
        x: root.width / 2 - 100;
        source: "res/passed.png";    
        z: 3;
 
        SpringAnimation {
            id: springY;
            target: passed;
            property: "y";
            spring: 3;
            damping: 0.1;
            epsilon: 0.25;
        }                          
 
        function showPass(bShow){
            visible = bShow;
            if(bShow == true){
                springY.from = y;
                springY.to = root.height / 2 - height / 2;
                springY.start();
            }else{
                y = 0;
            }
        }
    }
 
    Image {
        id: failed;
        visible: false;
        width: 180;
        height: 37;
        source: "res/failed.png";
        z: 3;
 
        states: [
            State {
                name: "show";
                AnchorChanges {
                    target: failed;
                    anchors.horizontalCenter: root.horizontalCenter;
                    anchors.verticalCenter: root.verticalCenter;
                }
            },
            State {
                name: "hide";
                AnchorChanges {
                    target: failed;
                    anchors.left: root.left;
                    anchors.top: root.top;
                }
            }
        ]
 
        state: "hide";
 
        transitions: Transition{
            AnchorAnimation{
                duration: 1000;
                easing.type: Easing.OutInCubic;
            }
        }
 
        function showFailed(bShow){
            visible = bShow;   
            state = bShow ? "show" : "hide"; 
        }
    }
 
    Keys.onReturnPressed: fire();
    Keys.onSpacePressed: fire();
 
    Keys.onLeftPressed: animateTurret.rotate(-3);
    Keys.onRightPressed: animateTurret.rotate(3);
 
    function resetBulletPos(){
        bullet.x = root.width / 2 - bullet.width/2;
        bullet.y = root.height - bullet.height /2;    
    }
 
    onHeightChanged: {
        bullet.x = root.width / 2 - bullet.width/2;
    }
    onWidthChanged: {
        bullet.y = root.height - bullet.height /2;
    }
}
哇风
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
泡泡鱼源代码
05-21
适合刚学java的看， 游戏很简单，适合初学者。。
象棋在线对战网页源码源码安装
dogeven的博客
07-24 1890
象棋在线对战网页源码源码安装，初学者可学习机器人AI思路，和游戏搭建结构
python实验报告及源代码-python满分实验报告：红心大战源代码源码程序
weixin_39607937的博客
11-11 408
python满分实验报告：红心大战源代码/python满分实验报告：红心大战源代码/python_红心大战游戏_满分原创作业/python满分实验报告：红心大战源代码/python_红心大战游戏_满分原创作业/python_红心大战游戏_满分原创作业/python满分实验报告：红心大战源代码/python_红心大战游戏_满分原创作业/python_红心大战游戏_满分原创作业/红心大战/python...
python炫酷动画源代码_python_红心大战游戏源代码_满分原创作业
weixin_39789525的博客
12-12 721
【实例简介】python编写红心大战游戏，满分作业，音效动画传牌等效果酷炫。【实例截图】【核心代码】python_红心大战游戏源代码_满分原创作业└── python_红心大战游戏_满分原创作业└── 红心大战├── back.pgm├── bg.gif├── card│ ├── 0.pgm│ ├── 1.pgm│ ├── 10.pgm│ ├── 11.pgm│ ├── 12....
代码 飞机大战源码 代码 飞机大战源码
05-14
代码 飞机大战源码代码 飞机大战源码代码 飞机大战源码代码 飞机大战源码代码 飞机大战源码代码 飞机大战源码代码 飞机大战源码代码 飞机大战源码代码 飞机大战源码代码 飞机大战源码代码 飞机大战源码代码 飞机大战...
Python飞机大战项目源码
09-01
飞机大战游戏主要以太空主题的画面为游戏背景，由玩家通过键盘控制英雄飞机向敌机总部发动进攻，在进攻的过程中既可以让英雄飞机发射子弹或炮弹击毁敌机以赢取分数，也可以拾取道具以增强自己的战斗力，一旦被敌机...
TanKeWar_坦克大战源码_
10-01
可以玩
Unity飞机大战源码，完整工程
09-30
Unity飞机大战源码，完整工程，3D的飞机大战，可以学习，完整工程，无报错，直接可以跑起来的，真实有效。
C++版红心大战源代码
12-27
C++版红心大战源代码
窗口化源码
10-04
窗口化源码 一般游戏 一边看电影 一边聊天
Android代码-自定义泡泡效果源码.zip
08-02
自定义泡泡效果源码.zip
拱猪游戏源码2012929
09-29
拱猪游戏源码 源码描述： 扑克发牌算法 是棋牌游戏中常用的基础算法，也是游戏开发人员需要熟悉的基算法之一。下面介绍一下该算法的一种实现方式。 洗牌和发牌模拟 首先给扑克牌中每张牌设定一个编号，下面算法实现的编号规则如下： 红桃按照从小到大依次为：1-13 方块按照从小到大依次为：14-26 黑桃按照从小到大依次为：27-39 梅花按照从小到大依次为：40-52 小王为53，大王为54 算法实现如下： 首先按照以上编号规则初始化一个包含108个数字的数组每次随机从该数组中抽取一个数字，分配给保存玩家数据的数组
C++ MFC 吹泡泡 源代码
07-07
：要求用鼠标左键随机在客户区任何地方单击，可产生一个圆形的泡泡（泡泡的大小随机产生）；可通过颜色对话框选择不同的颜色，绘出不同颜色的泡泡；可以保存文档，并能打开文档。吹出的泡泡是透明的。
植物大战僵尸源码unity
11-10
植物大战僵尸源码，unity多光卡。
cf泡泡窗口化完美版5.0修正版.rar
09-03
软件介绍: 使用说明：先打开窗口化软件，再运行CF游戏即可窗口化。本版本修复了退出还原全屏模式，在800x600分辨率模式下下窗口化进入游戏出现问题的需要按下F1键。、如果不想使用窗口化想恢复全屏模式，请找到CF游戏文件夹内的Msimg32.dll文件，把它重命名为Msimg32xixi.dll就可以了。
游戏窗口化参考资料.rar
04-24
游戏 窗口化 参考资料 游戏 窗口化 参考资料 Hook COM
CF窗口化源码
07-19
制作CF窗口化的易语言源码绝对的给力.
python星球大战源码下载
最新发布
12-22
Python星球大战源码是一个由python语言编写的开源项目，它是基于经典的星球大战电影系列而开发的一个游戏。玩家可以在游戏中扮演不同的角色，使用光剑和原力与敌人进行战斗，体验星球大战的刺激和激动人心的场景。 ...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值