bzoj1044 木棍分割 二分+贪心&dp优化

对于第一问：

    直接二分+贪心即可。贪心策略：能加进来的加进来，否则就从当前一根起重新再砍一截。

对于第二问：

    (1)简单dp。设f[j][i]表示到第i个点，截取j个木棍且满足要求的方案数。同时，用sum[i]表示到i为止的木棍做长度，则    f[j][i]={f[j-1][k]}(0<=k<i,sum[i]-sum[k]<=ans1)

   (2)空间优化。由于n<=50000, 0<=m<=min(n-1,1000)，空间最大可以达到50000*1000=5*10^7，明显太大。由(1)的转移方程，我们发现f[j]的值只和f[j-1]有关。由此，我们可以用滚动数组将空间优化到O(N)

    (3)时间优化。根据(1)的转移方程，我们发现时间为O(N^2M)，不能承受。我们应至少去掉一个N。观察转移方程，我们发现部分f[j-1][k]的值被反复计算。那么同样运用前缀和的思想，我们可以利用上一个f[j][i]的值，加加减减之后得到当前f[j][i]的值。具体的方法也比较好想，由于我语文不太好，所以就请代码帮我表达了。

      注意到代码中的p数组，实际上这也是多余的，完全可以利用一个变量来计算，这样可以快1/2左右，也比较简单，这里不再叙述了。

P.S：注意常数！

下附AC代码：

const
  mo=10007;
  inf=1000000007;
var
  a,s,p:array[0..51000] of longint;
  f:array[0..1,0..51000] of longint;
  n,m,i,k,r,l,mid,t,ans,ans2,now,last:longint;
function ok(x:longint):boolean;
var
  i,sum,num:longint;
begin
  sum:=0; num:=0;
  for i:=1 to n do
    begin
      if sum+a[i]>x then
        begin
          num:=num+1; sum:=0;
          if num>m then exit(false);
        end;
      sum:=sum+a[i];
    end;
  if sum>0 then num:=num+1;
  if num>m then exit(false) else exit(true);
end;
begin
  readln(n,m); m:=m+1;
  for i:=1 to n do
    begin
      readln(a[i]);
      if a[i]>r then r:=a[i];
      s[i]:=s[i-1]+a[i];
    end;
  l:=inf;
  while r+1<l do
    begin
      mid:=(r+l)>>1;
      if ok(mid) then l:=mid else r:=mid+1;
    end;
  if ok(r) then ans:=r else ans:=l;
  for i:=1 to n do
    if s[i]<=ans then f[0,i]:=1 else break;
  s[0]:=-inf;
  for t:=2 to m do
    begin
      now:=now xor 1; last:=now xor 1;
      for i:=1 to n do
        begin
          f[now,i]:=0; p[i]:=0;
        end;
      k:=n+1;
      for i:=n downto 2 do
        begin
          if k<i then 
             f[now,i]:=(f[now,i]+p[k]-p[i]) mod mo
          else k:=i;
          while (k>1) and (s[i]-s[k-1]<=ans) do
            begin
              k:=k-1;
              f[now,i]:=(f[now,i]+f[last,k]) mod mo;
              p[k]:=(p[k+1]+f[last,k]) mod mo;
            end;
        end;
      ans2:=ans2+f[now,n];
    end;
  writeln(ans,' ',ans2 mod mo);
end.

2015.2.8

by lych