王爽汇编语言第3版 实验7寻址方式在结构化数据访问中的应用

方法一

assume cs:codesg,ds:data,es:table,ss:stacksg

stacksg segment
	dw 8 dup (0)
stacksg ends

data segment 
	
	db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
	db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
	db '1993','1994','1995'
	;以上是表示21年的21个字符串,起始地址 DS:0H
	
	dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
	dd 345980,590827,803530,1183000,1843000,2759000,3753000,464900,5937000
	;以上是表示21年公司总收入的21个dword数据,起始地址 DS:54H
	
	dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
	dw 11542,14430,15257,17800
	;以上是表示21年公司雇员人数的21个word型数据 起始地址 DS:A8H
data ends

table segment
	db 21 dup ('year summ ne ?? ')
table ends


codesg segment
	start:	mov ax,data
		mov ds,ax
		mov ax,table
		mov es,ax
	
	;年份
		mov cx,21
		mov bx,0
		mov si,0
	syear : push cx
	        mov cx,4
		mov di,0
		mov al,0
		year:   mov al,[si]
			mov es:[bx].0[di],al
			inc di
			inc si
		loop year	
		add bx,10h
		pop cx
	loop syear
	
	;总收入
		mov cx,21
		mov bx,0
		mov si,0
	ssumn : mov ax,54H[si]	
		mov es:[bx].5,ax
		add si,2
		mov ax,54H[si]	
		mov es:[bx].7,ax
		add si,2	
		add bx,10h	
	loop ssumn
	
	;人数
		mov cx,21
		mov bx,0
		mov si,0
	  sne : 
		mov ax,0A8H[si]	
		mov es:[bx].0ah,ax
		add si,2				
		add bx,10h
	loop sne
	
	
	;求人均收入
		mov cx,21
		mov bx,0
		mov si,0
		mov di,0
	  sdiv : 
		mov ax,54H[di] ;总收入 被除数底16位
		add di,2
		mov dx,54H[di]  ;总收入 被除数高16位
		add di,2
		div word ptr ds:0A8H[si]   ;人数  除数
		add si,2
		mov es:[bx].0dh,ax
		add bx,10h
	loop sdiv
	
		
		mov ax,4c00h
		int 21h
codesg ends
	
end start

		

运行结果