Mplus—多指标随机截距交叉滞后模型（Multiple Indicator Random Intercept Cross-Lagged Panel Model, MI RI-CLPM）

于 2023-10-11 15:52:27 发布
阅读量834 收藏 4
点赞数
分类专栏： Mplus 随机截距交叉滞后模型 文章标签： 数据分析 经验分享 学习方法 笔记 其他
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/m0_54401011/article/details/133764868
版权

目录

简介

Mplus语法参考

1. ResearchGate-Ellen Hamaker-How to run a multiple indicator RI-CLPM in Mplus

2. ResearchGate-Ellen Hamaker-Mplus files for the MI RI-CLPM

3. Ext. 3: multiple indicator

Mplus语法

1. 形态等值（Configural Invariance）

2. 单位等值（Metric Invariance）或弱等值（Weak Invariance）

3. 尺度等值（Scalar Invariance）或强等值（Strong Invariance）

4. MI RI-CLPM

简介

关于多指标随机截距交叉滞后模型（Multiple Indicator Random Intercept Cross-Lagged Panel Model, MI RI-CLPM），在下面这篇文章的“Extension 3: The multiple indicator RI-CLPM”部分有相应介绍，感兴趣的可以仔细阅读一下。

Mulder, J. D., & Hamaker, E. L. (2021). Three Extensions of the Random Intercept Cross-Lagged Panel Model. Structural Equation Modeling: A Multidisciplinary Journal, 28(4), 638–648. https://doi.org/10.1080/10705511.2020.1784738

1. MI RI-CLPM有两种形式，如下图所示。第二个模型是第一个模型的特殊情况。目前有关RI-CLPM的文献采用的多数为第二个模型。

Top panel shows a model with indicator-specific random intercepts that capture trait-like differences between units, and occasion-specific factors that capture the within-unit dynamics.

Bottom panel shows a model in which there is a latent variable per occasion, which contains a trait-like part that is captured by the higher-order random intercepts, and a state-like part that is used to capture the dynamics over time. 来源：Mulder & Hamaker, 2021

2. 在建立模型之前，首先要进行纵向不变性检验。至少要满足单位等值（Metric Invariance）或弱等值（Weak Invariance）。纵向不变性检验可参见文章：

Mplus—纵向不变性/纵向等值_Kunle~的博客-CSDN博客纵向不变性及在Mplus中的语句https://blog.csdn.net/m0_54401011/article/details/131517229?spm=1001.2014.3001.5501

To allow for a meaningful comparison of factors over time, the factor loadings should be time-invariant, such that there is (at least) weak factorial invariance over time (Meredith, 1993; Millsap, 2011).

如上图所示，所谓MI RI-CLPM，就是将每个潜变量分为个体间水平（Between-person level）和个体内水平（Within-person level）。

Mplus语法参考

1. ResearchGate-Ellen Hamaker-How to run a multiple indicator RI-CLPM in Mplus

网址：https://www.researchgate.net/publication/328095575_How_to_run_a_multiple_indicator_RI-CLPM_in_Mplus

2. ResearchGate-Ellen Hamaker-Mplus files for the MI RI-CLPM

网址：https://www.researchgate.net/publication/328095732_Mplus_files_for_the_MI_RI-CLPM

3. Ext. 3: multiple indicator

网址：https://jeroendmulder.github.io/RI-CLPM/mplus.html#Ext_3:_multiple_indicator

Mplus语法

1. 形态等值（Configural Invariance）

TITLE: Multiple indicator RI-CLPM 4 waves with 3 indicators for each variable at each wave (24 observed variables) Fitting a model without constraints;

DATA: FILE = MIRICLPM.dat; ! 数据来源

VARIABLE: NAMES ARE x11 x12 x13 x21 x22 x23

                                         x31 x32 x33 x41 x42 x43

                                         y11 y12 y13 y21 y22 y23

                                         y31 y32 y33 y41 y42 y43; ! 变量名称

MODEL:

! Factor models for x at 4 waves 创建潜变量

FX1 BY x11-x13;

FX2 BY x21-x23;

FX3 BY x31-x33;

FX4 BY x41-x43;

! Factor models for y at 4 waves 创建潜变量

FY1 BY y11-y13;

FY2 BY y21-y23;

FY3 BY y31-y33;

FY4 BY y41-y43;

OUTPUT: TECH1;

2. 单位等值（Metric Invariance）或弱等值（Weak Invariance）

TITLE: Multiple indicator RI-CLPM 4 waves with 3 indicators for each variable at each wave (24 observed variables) Fitting a model with constraints on the factor loadings over time (weak factorial invariance);

DATA: FILE = MIRICLPM.dat;

VARIABLE: NAMES ARE x11 x12 x13 x21 x22 x23

                                         x31 x32 x33 x41 x42 x43

                                         y11 y12 y13 y21 y22 y23

                                         y31 y32 y33 y41 y42 y43;

MODEL:

! Factor models for x at 4 waves 加设因子负荷等值，通过相同的数字设定负荷等值

FX1 BY x11-x13 (L1-L3);

FX2 BY x21-x23 (L1-L3);

FX3 BY x31-x33 (L1-L3);

FX4 BY x41-x43 (L1-L3);

FY1 BY y11-y13 (L4-L6);

FY2 BY y21-y23 (L4-L6);

FY3 BY y31-y33 (L4-L6);

FY4 BY y41-y43 (L4-L6);

OUTPUT: TECH1;

3. 尺度等值（Scalar Invariance）或强等值（Strong Invariance）

TITLE: Multiple indicator RI-CLPM 4 waves with 3 indicators for each variable at each wave (24 observed variables) Fitting a model with constraints on the factor loadings and intercepts over time, while freeing latent means from 2=t onward (strong factorial invariance);

DATA: FILE = MIRICLPM.dat;

VARIABLE: NAMES ARE x11 x12 x13 x21 x22 x23

                                         x31 x32 x33 x41 x42 x43

                                         y11 y12 y13 y21 y22 y23

                                         y31 y32 y33 y41 y42 y43;

MODEL:

! Factor models for x at 4 waves ! constrained factor loadings over time 加设因子负荷等值

FX1 BY x11-x13 (L1-L3);

FX2 BY x21-x23 (L1-L3);

FX3 BY x31-x33 (L1-L3);

FX4 BY x41-x43 (L1-L3);

FY1 BY y11-y13 (L4-L6);

FY2 BY y21-y23 (L4-L6);

FY3 BY y31-y33 (L4-L6);

FY4 BY y41-y43 (L4-L6);

! Constrained intercepts over time 加设截距等值

[x11 x12 x13] (i1-i3);

[x21 x22 x23] (i1-i3);

[x31 x32 x33] (i1-i3);

[x41 x42 x43] (i1-i3);

[y11 y12 y13] (i4-i6);

[y21 y22 y23] (i4-i6);

[y31 y32 y33] (i4-i6);

[y41 y42 y43] (i4-i6);

[FX2* FX3* FX4*];

[FY2* FY3* FY4*];

OUTPUT: TECH1;

4. MI RI-CLPM

TITLE: Multiple indicator RI-CLPM 4 waves with 3 indicators for each variable at each wave (24 observed variables) Fitting a model with constraints to ensure strong factorial invariance, with the RI-CLPM at the latent level;

DATA: FILE = MIRICLPM.dat;

VARIABLE: NAMES ARE x11 x12 x13 x21 x22 x23

                                         x31 x32 x33 x41 x42 x43

                                         y11 y12 y13 y21 y22 y23

                                         y31 y32 y33 y41 y42 y43;

MODEL: 

! Factor models for x at 4 waves 创建潜变量

! constrained factor loadings over time 加设因子负荷等值

FX1 BY x11-x13 (L1-L3);

FX2 BY x21-x23 (L1-L3);

FX3 BY x31-x33 (L1-L3);

FX4 BY x41-x43 (L1-L3);

 FY1 BY y11-y13 (L4-L6);

FY2 BY y21-y23 (L4-L6);

FY3 BY y31-y33 (L4-L6);

FY4 BY y41-y43 (L4-L6);

! Constrained intercepts over time 加设截距等值

[x11 x12 x13] (i1-i3);

[x21 x22 x23] (i1-i3);

[x31 x32 x33] (i1-i3);

[x41 x42 x43] (i1-i3);

[y11 y12 y13] (i4-i6);

[y21 y22 y23] (i4-i6);

[y31 y32 y33] (i4-i6);

[y41 y42 y43] (i4-i6);

[FX2* FX3* FX4*];

[FY2* FY3* FY4*];

! Create between factors (random intercepts) 创建个体间变量/随机截距

RIX BY FX1@1 FX2@1 FX3@1 FX4@1;

RIY BY FY1@1 FY2@1 FY3@1 FY4@1;

! Set the residual variances of all FX and FY variables to zero

FX1-FY4@0;

! Create the within part 创建个体内变量

WFX1 BY FX1@1;

WFX2 BY FX2@1;

WFX3 BY FX3@1;

WFX4 BY FX4@1;

WFY1 BY FY1@1;

WFY2 BY FY2@1;

WFY3 BY FY3@1;

WFY4 BY FY4@1;

! Specify the lagged effects between the ! within-person centered latent variables

! 个体内变量之间的滞后效应

WFX2 ON WFY1 WFX1;

WFX3 ON WFY2 WFX2;

WFX4 ON WFY3 WFX3;

WFY2 ON WFY1 WFX1;

WFY3 ON WFY2 WFX2;

WFY4 ON WFY3 WFX3;

! Estimate the correlations within the same wave 同一时间点个体内变量之间的相关

WFX1 WITH WFY1;

WFX2 WITH WFY2;

WFX3 WITH WFY3;

WFX4 WITH WFY4; 

RIX WITH WFX1@0 WFY1@0;

RIY WITH WFX1@0 WFY1@0;

OUTPUT: TECH1 TECH9;

希望上述介绍可以帮助到你！也欢迎大家在评论区多多交流分享。

你的关注/点赞 /收藏★/分享，是最大的支持！

评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值