目录
模型简介
潜增长曲线模型/潜增长模型/潜变量增长曲线模型（Latent Growth Curve Models, LGCM）是纵向追踪数据分析中常用的一种模型。
LGCM可以用来探索事物随时间变化发展的过程。
Latent growth curve models were estimated to examine developmental trajectories of impulsivity and sensation seeking (Connolly et al., 2020). Latent growth modeling (LGM) was used to provide information about intra and interindividual differences in the growth trajectories of victimization and alcohol use (Thompson et al., 2008).
LGCM中包含截距（Intercept）因子和斜率（Slope）因子。
截距因子的【均值】描述初始状态，【方差】表示差异程度或离散程度，数值越大，表示个体间初始差异越大。
斜率因子的【均值】表示平均增长率，【方差】表示个体间增长率差异大小，数值越大，表示个体间发展变化轨迹的差异越大。
分类
LGCM可分为无条件潜增长曲线模型（Unconditional LGCM）和有条件潜增长曲线模型（Conditional LGCM）。
无条件潜增长模型：单纯描述某一事物随时间变化的趋势。分为：
-
无条件线性模型
-
无条件自由估计模型
-
无条件非线性模型
有条件潜增长模型在无条件LGCM的基础上，纳入其他变量，考察其他变量对研究变量发展轨迹的影响，即探究不同变量之间的关系。分为：
-
时不变（Time-invariant）协变量LGCM——协变量不随时间变化，例如性别、种族等，一次测量即可获得
-
时变（Time-variant/Time-varying）协变量LGCM——协变量随时间变化，例如年龄，需要多测测量
-
并行/平行发展（Parallel Process）LGCM——考察两个LGCM之间的关系
-
多变量（Multivariate）LGCM
在研究时，我们往往不清楚某一变量是怎样发展变化的，因此，可以先构建无条件潜增长模型，探索这一变量是如何随时间发展变化的，在此基础上，构建有条件潜增长模型，探讨其他变量对这一变量发展变化的影响。
无条件（Unconditional）LGCM
无条件线性LGCM
无条件线性LGCM指变量的发展趋势呈线性。
截距代表变量发展趋势的起始水平，所有的因素负荷固定为1。
斜率代表变量发展趋势的变化速度，根据自己的调查时间，设定线性发展趋势。
例如调查时间为第1个月、第2个月、第3个月、第4个月、第5个月，则可以将因素负荷分别设为0、1、2、3、4。
例如调查时间为第1个月、第2个月、第3个月、第5个月、第6个月，则可以将因素负荷分别设为0、1、2、4、5。
Mplus语句
DATA: FILE IS 123.dat; ! 数据来源
VARIABLE: NAMES ARE Y1 Y2 Y3 Y4 Y5; ! 变量名称，A为变量，后面的数字代表调查次数，A1代表第一次调查时变量A的得分。
MISSING ARE ALL (99); ! 定义缺失值
USEVARIABLES ARE Y1 Y2 Y3 Y4 Y5; ! 此次分析中用到的变量
ANALYSIS: ESTIMATOR=ML; ! 估计方法，可根据数据特点，选择其他方法
MODEL: I S | Y1@0 Y2@1 Y3@2 Y4@3 Y5@4; ! 创建截距因子和斜率因子，线性发展，将斜率因子负荷分别设定为0、1、2、3、4。
OUTPUT: TECH1 TECH4 STAND; ! 输出模型分析结果 ! STAND 要求提供标准化参数统计量及对应的标准误 ! TECH1 提供参数设置和所有自由估计参数开始值等信息 ! TECH4 提供模型中潜变量的均值、协方差和相关系数等信息
PLOT: TYPE IS PLOT3;
SERIES= Y1 Y2 Y3 Y4 Y5(*); ! 绘图，在模型运行结束后通过Plot下拉菜单View plots查看
结果解读
1. 模型拟合情况：根据文献选择拟合指标及标准，以此来判断模型拟合标准。
2. 模型结果：主要关注截距因子和斜率因子的均值和方差，以及二者之间的相关性。
3. 模型图
无条件自由估计LGCM
在设定模型时，可以将第一次和第二次的负荷分别设定为0、1，随后的负荷允许模型根据数据估计以确定变化趋势。
Mplus语句
DATA: FILE IS 123.dat;
VARIABLE: NAMES ARE A1 A2 A3 A4 A5;
MISSING ARE ALL (99);
USEVARIABLES ARE A1 A2 A3 A4 A5;
ANALYSIS: ESTIMATOR=ML;
MODEL: I S | A1@0 A2@1 A3@2 A4 A5;
OUTPUT: TECH1 TECH4 STAND;
PLOT: TYPE IS PLOT3;
SERIES= A1 A2 A3 A4 A5(*);
结果解读
1. 模型拟合情况
2. 模型结果
3. 模型图
无条件非线性LGCM
无条件非线性LGCM在无条件线性LGCM的基础上增加了一个二次项。
Mplus语句
DATA: FILE IS 123.dat;
VARIABLE: NAMES ARE A1 A2 A3 A4 A5;
MISSING ARE ALL (99);
USEVARIABLES ARE A1 A2 A3 A4 A5;
ANALYSIS: ESTIMATOR=ML;
MODEL: I S Q | A1@0 A2@1 A3@2 A4@3 A5@4;
OUTPUT: TECH1 TECH4 STAND;
PLOT: TYPE IS PLOT3;
SERIES= A1 A2 A3 A4 A5(*);
结果解读
1. 模型拟合情况
2. 模型结果
3. 模型图
无条件LGCM的结果报告
研究过程中，我们往往不清楚某一变量的发展变化趋势，因此，我们可以构建不同的无条件模型，比较模型拟合情况，来确定哪种模型更加合适。
例如，下面这篇文章，为了检验孤独感的变化趋势是线性的还是非线性的，分别构建了无条件线性LGCM和无条件非线性LGCM，比较两个模型的拟合情况，发现无条件非线性LGCM模型拟合优于无条件线性LGCM，表明2-5年级儿童孤独感的发展呈曲线变化趋势。
刘俊升, 周颖, 李丹. (2013). 童年中晚期孤独感的发展轨迹:一项潜变量增长模型分析. 心理学报, 45(02), 179-192
下面这两篇文章，同样比较了线性LGCM和非线性LGCM。
杨满云, 郭成, 周仁会, 李振兴. (2017). 人际冒犯受害者宽恕的变化轨迹:一项潜变量增长模型分析. 中国临床心理学杂志, 25(06), 1124-1129
林楠, 赵雯雯, 武丽丽, 张大均, 程刚. (2023). 心理素质与高中新生入学转变期焦虑变化轨迹的关系——基于潜变量增长模型的分析. 心理科学, 46(02), 443-449
下面这篇文章则构建了几种不同的模型。
程亚华, 冯瑶, 李宜逊, 马嘉琪, 沈岚岚, 张文建, 伍新春, 冯秋迪. (2023). 小学儿童口语词汇知识的发展轨迹及其对阅读能力的预测：一个潜变量增长模型. 心理学报, 55(07), 1074-1086.
在对结果进行阐述时，主要针对截距因子和斜率因子的均值和方差，以及截距因子和斜率因子的相关/协方差。
例如：
Thompson, M. P., Sims, L., Kingree, J. B., & Windle, M.. (2008). Longitudinal associations between problem alcohol use and violent victimization in a national sample of adolescents. Journal of Adolescent Health,42(1), 21-27.
The nonsignificance of the latent variables “victimization intercept” (t = .62, p > .05) and “victimization slope” (t = .82, p > .05) indicated that there was not significant variability among the means of females in their initial level of victimization or in their rate of change of victimization.
Keles, S., Idsøe, T., Friborg, O., Sirin, S., & Oppedal, B. (2017). The Longitudinal Relation between Daily Hassles and Depressive Symptoms among Unaccompanied Refugees in Norway. Journal of Abnormal Child Psychology, 45(7), 1413–1427.
The variance estimate of the latent intercepts for depression, acculturation hassles and general hassles were significant, suggesting considerable individual differences in initial status. （对截距方差的描述：初始状态的个体差异）
The mean slope coefficient for depression was not significant, but significantly negative for acculturation and general hassles. That is, the mean level of depression remained unchanged over time, while the mean level of acculturation and general hassles decreased. （对斜率均值的描述：变量水平随时间的变化）
Moreover, the intercepts of all variables were significantly negatively correlated with their linear slope factor. That is, participants with a higher initial level of depression or any type of hassles experienced a stronger decline in the same construct over time than participants with a lower initial status. （对截距和斜率相关的描述：初始状态与变化率的关系）
Höft, L., & Bernholt, S. (2019). Longitudinal couplings between interest and conceptual understanding in secondary school chemistry: An activity-based perspective. International Journal of Science Education, 41(5), 607–627. https://doi.org/10.1080/09500693.2019.1571650
Intercepts and slopes of six dimensions of students’ interest were uncorrelated, indicating that the extent to which students’ interest in science activities decreased was independent from students’ initial interest at Grade 9. （截距和斜率相关的表述）
有条件（Conditional）LGCM
时不变协变量LGCM
时不变协变量LGCM为在无条件模型的基础上，纳入不随时间变化的协变量，例如性别、种族等，探讨这些协变量对研究变量发展轨迹的影响。
例如：下面这篇文章，为了考察孤独感的变化趋势是否存在性别差异，在无条件非线性模型的基础上加入性别，构建条件模型。
刘俊升, 周颖, 李丹. (2013). 童年中晚期孤独感的发展轨迹：一项潜变量增长模型分析. 心理学报, 45(02), 179-192
Mplus语句
以无条件线性LGCM为基础
DATA: FILE IS 123.dat;
VARIABLE: NAMES ARE Y1 Y2 Y3 Y4 Y5 A B;
MISSING ARE ALL (99);
USEVARIABLES ARE Y1 Y2 Y3 Y4 Y5 A B; ! A B为时不变协变量
ANALYSIS: ESTIMATOR=ML;
MODEL: I S | Y1@0 Y2@1 Y3@2 Y4@3 Y5@4;
I S ON A B; ! 时不变协变量—>截距因子和斜率因子
OUTPUT: TECH1 TECH4 STAND;
PLOT: TYPE IS PLOT3;
SERIES= Y1 Y2 Y3 Y4 Y5(*);
结果解读与报告
以下面这篇文章为例，时不变协变量LGCM中，需要报告的内容有：模型拟合情况、时不变协变量与截距因子的关系、时不变协变量与斜率因子的关系。
刘俊升, 周颖, 李丹. (2013). 童年中晚期孤独感的发展轨迹：一项潜变量增长模型分析. 心理学报, 45(02), 179-192
在Mplus的OUTPUT文件中，对应的则是：
1. 模型拟合情况
2. 时不变协变量与截距因子的关系&时不变协变量与斜率因子的关系
时变协变量LGCM
时变协变量LGCM为在无条件模型的基础上，纳入随时间变化的协变量，探讨这些协变量对研究变量发展轨迹的影响。
例如：下面这篇文章，为考察人际冒犯受害者沉思对宽恕变化趋势的影响，在无条件模型的基础上，加入时间变化协变量人际冒犯沉思，构建条件模型。
杨满云, 郭成, 周仁会, 李振兴. (2017). 人际冒犯受害者宽恕的变化轨迹：一项潜变量增长模型分析. 中国临床心理学杂志, 25(06), 1124-1129
例如：下面这篇文章，为考察同伴接纳对儿童孤独感变化趋势的影响，以同伴接纳作为时间变异的协变量（Time Varying Covariates），性别作为时间恒定的协变量（Time Invariant Covariates）构建条件模型。
刘俊升, 周颖, 李丹. (2013). 童年中晚期孤独感的发展轨迹：一项潜变量增长模型分析. 心理学报, 45(02), 179-192
Mplus语句
以无条件线性LGCM为基础
DATA: FILE IS 123.dat;
VARIABLE: NAMES ARE Y1-Y5 A1-A5;
MISSING ARE ALL (99);
USEVARIABLES ARE Y1-Y5 A1-A5; ! A1-A5为时变协变量
ANALYSIS: ESTIMATOR=ML;
MODEL: I S | Y1@0 Y2@1 Y3@2 Y4@3 Y5@4;
Y1 ON A1;
Y2 ON A2;
Y3 ON A3;
Y4 ON A4;
Y5 ON A5;
OUTPUT: TECH1 TECH4 STAND;
PLOT: TYPE IS PLOT3;
SERIES= Y1 Y2 Y3 Y4 Y5(*);
结果解读与报告
以下面这两篇文章为例，时变协变量LGCM中，需要报告的内容有：模型拟合情况、每个时间点上时变协变量与研究变量的关系。
刘俊升, 周颖, 李丹. (2013). 童年中晚期孤独感的发展轨迹：一项潜变量增长模型分析. 心理学报, 45(02), 179-192
杨满云, 郭成, 周仁会, 李振兴. (2017). 人际冒犯受害者宽恕的变化轨迹：一项潜变量增长模型分析. 中国临床心理学杂志, 25(06), 1124-1129
在Mplus的OUTPUT文件中，对应的则是：
1. 模型拟合情况
2. 每个时间点上时变协变量与研究变量的关系
并行/平行发展（Parallel Process）LGCM
并行/平行发展LGCM用于考察两个LGCM之间的关系。
例如，下面这篇文章，通过构建老年自我刻板印象与家人情感卷入的平行增长模型来考察感知到的家人情感卷入对老年自我刻板印象的影响。
徐冉, 张宝山, 林瑶. (2021). 家人情感卷入对老年自我刻板印象的影响：基于潜变量增长模型的分析. 心理学报, 53(11), 1215-1227
Mplus语句
以无条件线性LGCM为基础
DATA: FILE IS 123.dat;
VARIABLE: NAMES ARE Y1-Y5 A1-A5;
MISSING ARE ALL (99);
USEVARIABLES ARE Y1-Y5 A1-A5;
ANALYSIS: ESTIMATOR=ML;
MODEL: I1 S1 | Y1@0 Y2@1 Y3@2 Y4@3 Y5@4;
I2 S2 | A1@0 A2@1 A3@2 A4@3 A5@4;
S1 ON I2; S2 ON I1;
OUTPUT: TECH1 TECH4 STAND;
值得注意的是，MODEL部分并不是固定的，而是根据自己的研究目的和模型，写出相应的语句。
例如，在下面这两篇文章中，模型图对应的MODEL部分同上，即一个变量的截距预测另一个变量的斜率。
MODEL: S1 ON I2;
S2 ON I1;
Thompson, M. P., Sims, L., Kingree, J. B., & Windle, M. (2008). Longitudinal associations between problem alcohol use and violent victimization in a national sample of adolescents. Journal of Adolescent Health, 42(1), 21-27
Noels, K. A., Vargas Lascano, D. I., & Saumure, K. (2019). The development of self-determination across the language course. Studies in Second Language Acquisition, 41(04), 821-851
下面这篇文章，根据研究目的，则为第一个变量的截距预测第二个变量的截距和斜率，第一个变量的斜率预测第二个变量的斜率。
MODEL: S2 ON I1
S1; I2 ON I1;
徐冉, 张宝山, 林瑶. (2021). 家人情感卷入对老年自我刻板印象的影响：基于潜变量增长模型的分析. 心理学报, 53(11), 1215-1227
下面这篇文章则为第一个变量的截距预测第二个变量的截距和斜率，第一个变量的斜率预测第二个变量的截距和斜率。
MODEL: I2 ON I1 S1;
S2 ON I1 S1;
Silver, I. A., D'Amato, C., & Wooldredge, J. (2021). The cycle of reentry and reincarceration: Examining the influence on employment over a period of 18 years. Journal of Criminal Justice, 74, 101812. Redirecting
结果解读与报告
在写作时，一般需要报告以下内容：
1. 模型拟合情况
2. 路径系数及显著性
The negative association between the latent slopes suggested that individuals that experienced an increasing (or decreasing) number of months incarcerated from 2000 to 2016 also experienced a subsequent decline (or increase) in the likelihood of employment from 2001 to 2017 (Silver et al., 2021).
Results indicated that higher initial levels of alcohol use led to a slower average deceleration in victimization and that higher initial levels of victimization led to a slower average acceleration in alcohol use (Thompson et al., 2008).
The intercepts of these two processes covaried significantly with each other—students with higher integrated regulation at the beginning of the semester also reported higher engagement at the beginning of the semester than students with lower initial levels of integrated regulation (Noels et al., 2019). Initial levels of integrated regulation and behavioral engagement did not contribute to changes in one another over time (Noels et al., 2019). There was, however, a significant positive covariance between the slope parameters. Students with greater increases in integrated regulation also showed less decline in engagements across the semester (Noels et al., 2019).
在Mplus中结果输出文件中，对应：
1. 模型拟合情况
2. 路径系数及显著性
多变量（Multivariate）LGCM
当变量有三个时，可以构建中介模型，例如下面这篇文章：
Bravo, A. J., Kelley, M. L., Swinkels, C. M., & Ulmer, C. S. (2018). Work stressors, depressive symptoms and sleep quality among US Navy members: A parallel process latent growth modelling approach across deployment. Journal of Sleep Research, 27(3), e12624. http://doi.org/10.1111/jsr.12624
(Bravo et al., 2018)
Mplus语句
以无条件线性LGCM为基础
DATA: FILE IS 123.dat;
VARIABLE: NAMES ARE Y1-Y5 A1-A5 B1-B5;
MISSING ARE ALL (99);
USEVARIABLES ARE Y1-Y5 A1-A5 B1-B5;
ANALYSIS: ESTIMATOR=ML;
MODEL: I1 S1 | Y1@0 Y2@1 Y3@2 Y4@3 Y5@4;
I2 S2 | A1@0 A2@1 A3@2 A4@3 A5@4;
I3 S3 | B1@0 B2@1 B3@2 B4@3 B5@4;
I2 ON I1;
I3 ON I1;
I3 ON I2;
S2 ON S1;
S3 ON S1;
S3 ON S2;
S2 ON I1;
S3 ON I1;
S3 ON I2;
MODEL INDIRECT: I3 IND I2 I1;
S3 IND I2 I1;
S3 IND S2 I1;
S3 IND S2 S1;
OUTPUT: TECH1 TECH4 STAND;
结果解读与报告
在写作时，一般需要报告以下几方面的内容（具体可参阅拟投稿期刊上相似文章）：
1. 模型拟合情况
2. 路径系数及显著性（直接效应）
3. 中介效应（间接效应）
(Bravo et al., 2018)
在Mplus结果输出文件中对应：
1. 模型拟合情况
2. 路径系数及显著性
3. 中介效应
4. 模型图
Mplus语句查找
可以根据自己使用的变量，来查找对应的Mplus语句。
Mplus User's Guide Examples -- Chapter 6: Growth Modeling and Survival Analysis
希望上述介绍可以帮助到你！也欢迎大家在评论区多多交流分享。
你的关注/点赞 /收藏★/分享，是最大的支持！
3265
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
