汇编语言——输入无符号、有符号的十进制数，存入BX，以十进制、十六进制输出

已于 2024-04-20 15:59:42 修改
阅读量636 收藏 4
点赞数 4
分类专栏： 学习笔记 文章标签： 笔记 汇编 学习
于 2024-04-20 15:18:57 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/m0_62122789/article/details/137999697
版权

文章目录

输入无符号的十进制数，存入BX

指令重点：

mul判断溢出

如果8位*8位=8位，无溢出，CF=OF=0；

如果8位*8位=16位，结果的高8位全为0，无溢出，CF=OF=0，

否则CF=OF=1。

算法核心：

bx*10+输入的字符

当bx*10大于65535，溢出；

当bx*10+输入的字符大于65535，溢出。

在这里插入图片描述
在这里插入图片描述

data segment
	string db 0dh,0ah,"overflow!",'$'
data ends
stack segment stack
	dw 100 dup (?)
	top label word
stack ends
code segment
	assume cs:code,ds:data,ss:stack
main proc far
	mov ax,data
	mov ds,ax
	mov ax,stack
	mov ss,ax
	lea sp,top
	
	mov bx,0			;bx清零
	mov si,10			;si为乘数/除数
	mov cx,0			;统计输入合法字符的个数

L1:		
	mov ah,7			;7号功能输入，不回显
	int 21h
	
	cmp al,0dh			;输入回车，以10进制显示输出bx
	je print
	cmp al,30h			;输入字符小于30h，重新输入
	jb L1
	cmp al,39h			;输入字符大于39h，重新输入
	ja L1
	
	mov dl,al			;合法字符，回显
	mov ah,2
	int 21h
	
	inc cx				;合法字符+1
	
	and dx,0fh			;屏蔽高12位，只留下低4位0-9
	mov ax,dx			
	
	xchg ax,bx			;交换ax，bx(因为mul默认在ax)
	mul si				;结果在(dx,ax)
	
	;判断溢出
	;乘法指令的CF和OF
	;如果8位*8位=8位，无溢出
	;如果8位*8位=16位，结果的高8位全为0，则CF=OF=0，否则CF=OF=1
	jc overflow			
	
	add bx,ax			;如果ax*10刚好等于65535，加上bx可能会溢出
	jc overflow
	jmp L1

;以10进制显示输出bx
print:
	cmp cx,0			;输入的合法字符为0，即一开始就敲了回车，直接退出
	je exit				
	
	;回车和换行
	mov dl,0dh
	mov ah,2
	int 21h
	
	mov dl,0ah
	mov ah,2
	int 21h
	
	mov cx,0			;统计余数个数
	mov ax,bx			;被除数(bx,ax)
	mov dx,0
L2:
	div si
	push dx				;余数进栈
	inc cx				;余数个数+1
	
	cmp ax,0			;商为0，跳转到L3
	je L3
	
	mov dx,0			;dx清零作为新的被除数
	jmp L2

L3:	
	pop dx
	add dl,30h			;转换成数字字符
	mov ah,2
	int 21h
	loop L3
	
	cmp cx,0			;跳过下面的overflow
	jmp exit

;溢出在屏幕上显示"overflow!"
overflow:	
	lea dx,string
	mov ah,9
	int 21h

exit:
	mov ah,4ch
	int 21h
main endp
code ends
	end main

输入带符号的十进制数，存入BX

输入的第一位可能是’+‘、’-'、数字，其他位都是数字。

实现的核心思想是：

输入的符号和数字分开，用一个寄存器记录输入的符号，bp=0为正数，bp=1为负数；

其他数字以无符号数的形式输入，范围为0-65535，判断溢出的方法跟上一题一样；

输完数字敲回车的时候，再去判断有符号数的溢出：

如果bp=1，即bx是负数，对bx求补，根据符号位判断溢出，bx求补的符号位为1，则无溢出；bx求补的符号位为0，则溢出；

如果bp=0，即bx是正数，根据符号位判断溢出，bx的符号位为0，则无溢出；bx的符号位为1，则溢出。

补充
求负数的二进制：对应正数的补码
最高位为1：负数
最高位为0：正数

在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述

data segment
	string db 0dh,0ah,"overflow!",'$'
data ends
stack segment stack
	dw 100 dup (?)
	top label word
stack ends
code segment
	assume cs:code,ds:data,ss:stack
main proc far
	mov ax,data
	mov ds,ax
	mov ax,stack
	mov ss,ax
	lea sp,top
	
	mov bx,0
	mov cx,0				;统计合法的数字字符个数
	mov si,10
	mov bp,0				;符号位默认为0(正数)

	mov ah,7				;输入第一个字符
	int 21h
	
	cmp al,0dh				;输入回车，退出
	je exit
	
	cmp al,'-'				;判断输入的第一个字符
	jne L1					;不是负号，跳转到L1继续判断
	mov bp,1				;输入负号，更改符号位
	
	mov dl,al				;显示负号
	mov ah,2
	int 21h
	
	jmp L2					;跳转到L2继续输入数字字符
	
L1:	
	cmp al,'+'
	jne L3					;不是正号，跳转到L3继续判断
	mov bp,0				;输入正号，更改符号位
	
	mov dl,al				;显示正号
	mov ah,2
	int 21h
	
	jmp L2					;跳转到L2继续输入数字字符
	
L2:
	mov ah,7
	int 21h
	
	cmp al,0dh				;输入回车，跳转到以10进制显示bx
	je print

L3:	
	cmp al,30h				;小于30h，继续输入
	jb L2
	cmp al,39h				;大于39h，继续输入
	ja L2
	
	mov dl,al				;显示合法的数字字符
	mov ah,2
	int 21h
	inc cx					;合法的数字字符+1
	
	and dx,0fh				;屏蔽dx高12位
	mov ax,dx
	
	xchg ax,bx				;交换ax和bx
	mul si					;ax*10
	
	;数字部分以无符号数输入
	;限制数字部分的输入范围0-65535
	jc overflow
	add bx,ax
	jc overflow
	
	jmp L2					;无溢出，跳转到L2继续输入数字字符
	
print:
	cmp cx,0				;判断合法的数字字符个数，cx为0退出
	je exit
	
	;接下来判断有符号数的溢出
	cmp bp,1				
	je negative				;判断负数的溢出
	
	cmp bp,0
	je positive				;判断正数的溢出

negative:
	neg bx					;bx是负数，求补
	add bx,0				;这条指令会改变psw，接下来判断符号位
	jns overflow			;符号位是0，溢出
	
	neg bx					;为了下面显示bx，要把bx还原
	
	;回车换行
	mov dl,0dh
	mov ah,2
	int 21h
	
	mov dl,0ah
	mov ah,2
	int 21h
	
	mov dl,'-'				;无溢出，显示字符数前加一个'-'
	mov ah,2
	int 21h
	
	jmp L4					;跳转到L4以10进制显示bx

positive:
	add bx,0				;bx是正数
	js overflow				;符号位是1，溢出
	
	;回车换行
	mov dl,0dh
	mov ah,2
	int 21h
	
	mov dl,0ah
	mov ah,2
	int 21h
	
	mov dl,'+'				;无溢出，显示字符数前加一个'+'
	mov ah,2
	int 21h
	
	jmp L4					;跳转到L4以10进制显示bx

L4:		
	mov cx,0				;余数个数
	mov ax,bx				;被除数(dx,ax)
	mov dx,0
	
L5:
	div si
	push dx					;余数进栈
	inc cx					;余数个数+1
	cmp ax,0				;商为0，退出
	je L6
	mov dx,0				;把dx清零作为新的被除数(dx,ax)
	jmp L5
	
L6:
	pop dx
	add dl,30h				;转换成数字字符
	mov ah,2
	int 21h
	loop L6
	cmp cx,0				;为了跳过下面的overflow
	jmp exit
		
overflow:
	lea dx,string
	mov ah,9
	int 21h

exit:
	mov ah,4ch
	int 21h
main endp
code ends
	end main

输入一个有符号的十进制数，以十六进制输出

在这里插入图片描述

在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述
在这里插入图片描述

data segment
	string db 0dh,0ah,"overflow!",'$'
data ends
stack segment stack
	dw 100 dup (?)
	top label word
stack ends
code segment
	assume cs:code,ds:data,ss:stack
main proc far
	mov ax,data
	mov ds,ax
	mov ax,stack
	mov ss,ax
	lea sp,top
	
	mov bx,0
	mov cx,0				;统计合法的数字字符个数
	mov si,10
	mov bp,0				;符号位默认为0(正数)

	mov ah,7				;输入第一个字符
	int 21h
	
	cmp al,0dh				;输入回车，退出
	je exit
	
	cmp al,'-'				;判断输入的第一个字符
	jne L1					;不是负号，跳转到L1继续判断
	mov bp,1				;输入负号，更改符号位
	
	mov dl,al				;显示负号
	mov ah,2
	int 21h
	
	jmp L2					;跳转到L2继续输入数字字符
	
L1:	
	cmp al,'+'
	jne L3					;不是正号，跳转到L3继续判断
	mov bp,0				;输入正号，更改符号位
	
	mov dl,al				;显示正号
	mov ah,2
	int 21h
	
	jmp L2					;跳转到L2继续输入数字字符
	
L2:
	mov ah,7
	int 21h
	
	cmp al,0dh				;输入回车，跳转到以16进制显示bx
	je print

L3:	
	cmp al,30h				;小于30h，继续输入
	jb L2
	cmp al,39h				;大于39h，继续输入
	ja L2
	
	mov dl,al				;显示合法的数字字符
	mov ah,2
	int 21h
	inc cx					;合法的数字字符+1
	
	and dx,0fh				;屏蔽dx高12位
	mov ax,dx
	
	xchg ax,bx				;交换ax和bx
	mul si					;ax*10
	
	;数字部分以无符号数输入
	;限制数字部分的输入范围0-65535
	jc overflow
	add bx,ax
	jc overflow
	
	jmp L2					;无溢出，跳转到L2继续输入数字字符
	
print:
	cmp cx,0				;判断合法的数字字符个数，cx为0退出
	je exit
	
	;接下来判断有符号数的溢出
	cmp bp,1				
	je negative				;判断负数的溢出
	
	cmp bp,0
	je positive				;判断正数的溢出

negative:
	neg bx					;bx是负数，求补
	add bx,0				;这条指令会改变psw，接下来判断符号位
	jns overflow			;符号位是0，溢出	
	jmp L4					;跳转到L4以16进制显示bx

positive:
	add bx,0				;bx是正数
	js overflow				;符号位是1，溢出

L4:		
	mov cx,4
	
	mov dl,0dh
	mov ah,2
	int 21h
	
	mov dl,0ah
	mov ah,2
	int 21h
	
L5:
	push cx
	mov cl,4
	rol bx,cl
	mov dl,bl
	and dl,0fh
	cmp dl,9
	ja L6
	add dl,30h
	jmp L7

L6:
	add dl,37h
L7:	
	mov ah,2
	int 21h
	pop cx
	loop L5
	
	cmp cx,0
	je exit
		
overflow:
	lea dx,string
	mov ah,9
	int 21h

exit:
	mov ah,4ch
	int 21h
main endp
code ends
	end main
小白蹦蹦跳跳
关注
专栏目录
8086汇编语言：输入十个数字（可多位），以十进制和十六进制形式输出其最大值及最小值
坤舆湖畔的万某某的博客
12-21 6115
代码详实，注释详细，思路详尽；并对整个程序所能接受数值的极限进行了讨论，对于奇特的输出现象进行了解释！
汇编语言进制转换程序代码
yi_jianzhongqing的博客
02-19 328
自己写的8086汇编语言进制转换程序
汇编语言中十进制转十六进制----（ 6 ）
Iridescent～～
10-22 4474
DATAS SEGMENT ;数据段DATAS定义 CTR DB 0DH,0AH,'$' ;定义变量CTR, 内容为"0d0a$', 就是回车换行和$字符 DATAS ENDS CODES SEGMENT ASSUME CS:CODES,DS:DATAS ;代码段，数据段和栈的声明 START: MOV AX,DATAS MOV DS,...
汇编语言显示十进制数
11-22
可以用汇编语言将输入的字符串转换为十进制数，通过键盘输入，并且显示在屏幕上
汇编语言：键盘输入一个十进制数，分别转换成十六进制数、BCD码，并显示对应结果
m0_51738372的博客
04-14 6397
键盘输入任意位十进制数，分别转换成十六进制数、BCD码，并显示对应结果 输出如下 代码如下： STACK1 SEGMENT STACK DW 256 DUP(?) STACK1 ENDS DDATA SEGMENT MES1 DB 0ah,0dh,'The BCD code of decimal are:$' two db 2;定义two=2 ten dw 10; sixt dw 16; BUF db 10 DB ? DB
汇编十进制输入输出详解，各种进制输入输出
Afololer的博客
06-23 3536
注意: 输入的是ascll码，'0’对应的是30H，减去30在寄存器存的才是0，如果输入不在范围内，不增加到寄存器 获取输入’0’,30H之后的处理 减去30H，如果是A~Z则减去55，因为’A’为41H，即65 每次接收新一位数时，前面的数都应乘相应进制 再加上新一位的数 没有接收到回车时，2、3循环 十六进制输入十进制输出(输入存在bx寄存器) DATAS SEGMENT ;此处输入数据段代码 num db 65,48,48,48,10 crlf db 10,13,'$'
汇编作业——输出一个多位数（堆栈）
qq_45405490的博客
10-04 559
自定义一个数， DATAS SEGMENT ;此处输入数据段代码 DATAS ENDS STACKS SEGMENT ;此处输入堆栈段代码 STACKS ENDS CODES SEGMENT ASSUME CS:CODES,DS:DATAS,SS:STACKS START: MOV AX,DATAS MOV DS,AX ;此处输入代码段代码 MOV AX,1526 MOV BX,0;记录压栈次数 MOV CL,10 L
汇编：有符号10进制输入输出
antRain的博客
10-27 3414
汇编：有符号10进制输入输出输入有符号十进制整数（－128～127）实现readsib显示有符号十进制整数（－128～127）实现dispsib输入有符号十进制整数（－32768～32767）实现readsiw显示有符号十进制整数（－32768～32767）实现dispsiw 输入有符号十进制整数（－128～127） readsib 输入有符号十进制整数（－128～127）出口：AL＝8位数据 ...
汇编语言键盘输入十六进制加法.pdf
11-05
6. 在转换十六进制数为十进制数时，使用了HUAN和ZHUAN两个子程序，分别用于将十六进制数按位存入AX寄存器和将AX寄存器的值除以BX寄存器的值。 7. 在加法操作中，使用了ADC指令来实现十六进制数的加法操作。 8. 在...
实验二 两个多位十进制数相加实验
02-08
实验二“两个多位十进制数相加实验”旨在让学生掌握汇编语言中子程序的编写技巧以及循环程序设计的方法。在这个实验中，学生需要编写一个程序，接收用户通过键盘输入的两个5位十进制数，然后进行相加操作，并在屏幕...
汇编语言之 两个多位十进制数相加
10-12
汇编语言之两个多位十进制数相加 本实验旨在学习数据传送和算术运算指令的用法，并熟悉在 PC 机上建立、汇编、链接、调试和运行 8086 汇编语言程序的过程。 一、实验目的： * 了解数据传送和算术运算指令的用法 *...
对，我想知道如何用汇编语言将十进制数转为十六进制数输出，并想嫩知道详细的代码
04-18
好的，以下是用汇编语言将十进制数转为十六进制数输出的代码： ``` section .data dec_num dw 12345 ;十进制数 hex_num db 6 dup(0) ;存储十六进制数 section .text global _start _start: mov ax, [dec_num] ;将...
汇编语言——输入16位二进制数，存入BX
最新发布
m0_62122789的博客
04-19 306
汇编语言——输入16位二进制数，存入BX。
汇编——print一个十进制数
GreyBtfly的博客
06-01 3685
开发环境:Emu8086 v3.05  小端模式功能及参数表见代码注释 mov ax,156 call showa ret showa: ;显示一个十进制数-------------------------------------proc of show_one 数在ax中16位 ;div 除法： 被除数: 如果除数是8位则被除数为16位, 默认放在AX中, 如果除数是16位, 则被除...
汇编输出十进制数
InnerAc的专栏
11-01 3421
test
汇编语言实现R进制无符号数的输入/输出
weixin_30549657的博客
02-03 376
　　我认为，学习一门计算机编程语言，第一件事是要掌握如何输入和输出；汇编语言也不例外。通过编制“R进制无符号数的输入/输出”程序，能练习汇编语言中的“INT 12H”中断的1、2、9、1AH号功能，ADD/SUB/MUL/DIV等算术运算指令，以及各种跳转指令的运用，这对汇编语言的快速入门有很大帮助。 　　“R进制无符号数的输入/输出”程序将实现这么一个功能：用户输入R进制数（R=2、...
【汇编语言】从键盘输入10个带符号字节数据，将其从小到大排序，并将结果在显示器上以十进制形式显示输出。
weixin_51148634的博客
05-01 5467
通过调用子程序，实现从键盘输入10个带符号字节数据，将其从小到大排序，并将结果在显示器上以十进制形式显示输出。 data segment ary db 10 dup(0) ;用于存放输入数据 count db 10 x db '-' ;x存放'-'，后面用于判断 sfn db 0 ;标识，用于判断是否输入负数 mess1 db 'Input :','$' mess2 db 0ah,0dh,'Output :$';0ah和0dh是换行和回车 data
32位无符号整数以十进制形式打印输出屏幕【微机原理与汇编语言】＜针对大学8086处理器＞
不是一切星星 都仅指示黑暗
01-11 2569
实验内容： 有一个32位的二进制数，将其转换为十进制形式并且输出 实验难点： 我们直到二进制转换为十进制一般采用 除法指令DIV，但DIV指令只适用于二进制数低于或等于16位。因为DIV指令特点是DX存放商、AX存放余数。如果我们用32位的二进制数除以10则理应得到的商可能还是一个32位数，但没有足够空间大下的寄存器储存其中。 实验思路： 总体思路：就是采用减法去代替除法，可以将我们要处理的32位数不断减去10，每当减一个10，商计数器就加1，这样当数减到小于10时我们就可以得到相应最高位。
汇编十进制输出小程序
weixin_45775703的博客
11-08 1803
汇编十进制输出小程序前言一、算法概述二、完整代码 前言 近日学习汇编，发现当想要以十进制形式输出一个寄存器中所存放的数值时，是比较麻烦的，没有一个特别好的方法。因此，我尝试通过子程序的方法，编写一个十进制输出小程序来解决这个问题 一、算法概述 要输出一个十进制数，最有可能想到的就是通过不断用数据除10，然后获取余数来输出这个数据。基于此思想，我尝试通过汇编中div的特性，即当div除以十六位数据时，DX存放余数，AX存放商的性质来获取余数，然后不断往复，直到AX中商为0，同时DX中余数也为0时停止获取，
写出使用16进制有符号数计算的详细过程，不要转化为10进制
06-03
好的，使用16进制有符号数计算的过程如下： 1. 将11H和B4H转换为有符号数，11H代表的是+17，B4H代表的是-76。 2. 将11H加载到AL寄存器中，AL=11H=+17。 3. 将B4H加载到BL寄存器中，BL=B4H=-76。 4. 执行IMUL BL指令，将BL视为有符号数进行乘法运算。 5. 将AL和BL的16进制补码表示相乘，得到的结果为： ``` AL: 0001 0111 BL: 1011 0100 ------------- AX: 1001 0101 0100 1100 ``` 6. 根据AX的16进制补码表示，将其转换为有符号数。因为最高位为1，表示负数，所以需要先将AX的补码取反，然后加1，得到的结果为： ``` 1001 0101 0100 1100 补码 0110 1010 1011 0100 取反 + 1 ------------- 0110 1010 1011 0101 原码 ``` 7. 因此，11H和B4H在汇编语言中进行有符号数乘法的结果为-12D5H（即0110 1010 1011 0101B的16进制表示）。 注意：在汇编语言中使用16进制有符号数进行运算时，需要使用补码表示。因此，在进行乘法运算时，需要将AL和BL的16进制表示转换成16进制补码表示进行运算。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值