VBA学习(39)：利用VBA+SQL查询Excel工作表数据（基本查询）

引言

在VBA中，我们可以使用SQL语句对Excel工作表数据进行增删改查的操作。其中，查询工作表数据是最经常使用的操作。SQL查询语句可大致分为以下几类：（1）基本查询；（2）条件查询；（3）模糊查询；（4）分组查询；（5）多表查询。

本文搭建了VBA+SQL查询的模板，并汇总了SQL基本查询的实际应用，为后续学习条件查询、分组查询、多表查询等内容打好坚定的基础。

VBA+SQL查询的模板

Excel工作簿路径，工作表的查询区域，读者可根据实际情况选择。本案例的取值如下表所示：

自定义设置参数	本案例取值
Excel工作簿路径	D:\员工数据库.xlsx
工作表1-工资表	[工资表$A3:M65536]
工作表2-员工花名册	[员工花名册$A1:I65536]

[工资表$A3:M65536] 

[员工花名册$A1:I65536]

注：本文的员工花名册、工资表均为虚构数据，如有雷同，纯属巧合。

我们可以打开或新建一个工作簿，在该工作簿的Visual Basic编辑器下，编写VBA代码。运行VBA代码后，会在第一张工作表前插入新工作表，用于存放【SQL查询结果】。

Sub VBA的SQL查询模板()
    Dim conn As Object
    Set conn = CreateObject("ADODB.Connection")
    conn.Open "provider=microsoft.ace.oledb.12.0;extended properties='excel 12.0';data source='D:\员工数据库.xlsx'"

    Dim sql As String
    sql = "select * from [员工花名册$A1:I65536]"
    
    Dim rs As Object
    Set rs = CreateObject("ADODB.Recordset")
    Set rs = conn.Execute(sql)

    ActiveWorkbook.Sheets.Add before:=ActiveWorkbook.Sheets(1)
    ActiveWorkbook.Sheets(1).Name = "SQL查询结果" & Format(Now, "yyyymmddhhmmss")
    
    Dim i As Integer
    For i = 0 To rs.Fields.Count - 1
        ActiveWorkbook.Sheets(1).Cells(1, i + 1) = rs.Fields(i).Name
    Next
    ActiveWorkbook.Sheets(1).Range("a2").CopyFromRecordset rs
    
    rs.Close: Set rs = Nothing
    conn.Close: Set conn = Nothing
End Sub

SQL基本查询的实际应用

以下SQL的基本查询语句，只要将代码第7行的sql语句替换即可。

1、查询全部字段

sql = "select * from [员工花名册$A1:I65536]"

2、查询部分字段

sql = "select 工号,姓名 from [员工花名册$A1:I65536]"

3、查询不重复的记录（distinct关键字）

例：对员工的英文名进行去重查询

sql = "select distinct 英文名 from [员工花名册$A1:I65536]"

4、生成新的字段

例：根据出生日期查询生成出生年份

sql = "select 姓名,year(出生日期) as 出生年份 from [员工花名册$A1:I65536]"

5、用&连接符拼接字段

列：用“-”拼接员工的部门、学历

sql = "select 姓名,部门&'-'&学历 as 部门学历 from [员工花名册$A1:I65536]"

6、升序降序

例：按实发工资对工资表进行升序排列（默认为升序asc，降序desc）

sql = "select * from [工资表$A3:M65536] order by 实发工资"

7、top查询

例：查询年龄top5的员工信息

sql = "select top 5 * from [员工花名册$A1:I65536] order by 年龄"

 

技术交流，软件开发，欢迎微信沟通：