SAP BAdI 深度解读

BAdI是SAP在标准程序中，为客户自定义逻辑所预留的接口（属于第三代增强），在技术本质上是一个interface，通过实现类的向上继承，完成用户逻辑的调用。

操作BAdI的事务代码：

• SE18：定义BAdI， 查看BAdI的相关属性。
• SE19: 实现BAdI，查看BAdI的相关实现。

通常所说的BAdI有两种类型, -

• Classic BAdI (其在运行时进行实例化), 也称old BAdI;
• Kernel BAdI (其在编译时便进行实例化), 也称new BAdI; .

Classic BAdI和Kernel BAdI在系统中的定义方式、程序中的调用方式是不同的。

对于Classic BAdI， 其定义是通过SE18 >> Utilities >> Create Classic BAdI来进行的。

Classic BAdI通过CL_EXITHANDLER=>GET_INSTANCE来获取实例，然后通过实例来调用Interface中的方法。示例代码如下：

  " 对于classic BADI, 其应使用CL_EXITHANDLER=>GET_INSTANCE来获得实例
  DATA: lo_custom_adj TYPE REF TO zif_badi_interface_name.
  DATA: lv_imp_exist TYPE c.
  CALL METHOD CL_EXITHANDLER=>GET_INSTANCE
    EXPORTING
      exit_name              = 'OLD_BADI_NAME'  " BAdI name
      null_instance_accepted = ''
    IMPORTING
      act_imp_existing       = lv_imp_exist
    CHANGING
      instance               = lo_custom_adj    " type ref to BAdI's interface
    EXCEPTIONS
      OTHERS                 = 1.
  IF sy-subrc <> 0.
  ENDIF.
  IF lv_imp_exist IS NOT INITIAL.
    lo_custom_adj->badi_method( ).
  ENDIF.

对于Kernel BAdI, 通过Enhancement Spot进行创建，也即，先创建Enhancement Spot，然后在Enhancement Spot内部创建BAdI.

Kernel BAdI通过GET BADI来获取实例，并调用CALL BADI来调用interface中的方法。示例代码如下：

  " Use statement CALL BADI directly (AS 7.0)
  DATA: lo_adj_badi TYPE REF TO zbadi_test_oo_1.
  GET BADI lo_adj_badi.
  IF lo_adj_badi IS BOUND.
    CALL BADI lo_adj_badi->adjust_result
      EXPORTING
        iv_value1 = p_v1
        iv_value2 = p_v2
      CHANGING
        cv_result = lv_result.
  ENDIF.

---

在程序中，查找BAdI的常用方法：

1. 使用事务代码 SE84 ：Repository information system
2. 使用事务代码 SPRO: Customizing Guide, SAP标准发布的BAdI会在相关应用配置点中说明
3. 在程序中搜索关键字CL_EXITHANDLER=>GET_INSTANCE或关键字GET BADI
4. 在程序中搜索BAdI相关的接口名称，其接口的命规范通常为IF_EX_
5. 事务代码CODE_SCANNER, 可指定在特定的package、program中所有相关的字符串

---

在下文中，给出一个创建、实现、使用 Kernel BAdI的详细步骤 -

Step1: SE18 >> 给定enhancement spot的那么，点击Create.

Step2: 给出enhancement sport的描述信息，确定。

Step3: 在enhancement sport内，在左侧点击创建BAdI的图标。

Step4: 给定BAdI name，并定义BAdI的interface，双击interface name可直接创建interface。

Step5: 定义interface的相关属性、方法；在此仅定义一个adjust_result的方法作为示例。

Step6: 激活interface和enhancement spot, BAdI - ZBADI_TEST_OO_1 创建完成。

Step7: 实现BAdI >> SE19 >>给定enhancement spot的那么点击创建实现Create Implementation。

Step8: 输入相关的描述信息。

Step9: 定义相关的BAdI Implementation和相关的实现类 >> 确定。

Step10: 双击实现类的名称，创建实现类。

Step11: 根据业务需求，实现interface中的方法。

Step12: 激活实现类。BAdI实现完成。

Step13: 在local program中，调用并测试BAdI。

PARAMETERS: p_v1 TYPE i DEFAULT 1,
            p_v2 TYPE i DEFAULT 2.

START-OF-SELECTION.

  " before calling BAdI
  DATA: lv_result TYPE i.
  lv_result = p_v1 + p_v2.
  WRITE: 'result is:' , lv_result.

  " Use statement CALL BADI directly (AS 7.0)
  DATA: lo_adj_badi TYPE REF TO zbadi_test_oo_1. " BAdI name
  GET BADI lo_adj_badi.
  IF lo_adj_badi IS BOUND.
    CALL BADI lo_adj_badi->adjust_result
      EXPORTING
        iv_value1 = p_v1
        iv_value2 = p_v2
      CHANGING
        cv_result = lv_result.
    WRITE: / 'After BAdI, the result is:' , lv_result.
  ELSE.
    WRITE: / 'BAdI is not implemented!'.
  ENDIF.

在进入BAdI调整之前result = 3； 经过BAdI中的调整逻辑，其result = 6.