【01】SAP ABAP性能优化 - 如何减少DB的访问次数？

在《【开篇】SAP ABAP性能优化 - 在哪些方面进行优化？》中介绍了在ABAP程序运行时，访问不同位置数据的时间消耗。毫无疑问，ABAP程序在访问DB进行相关的操作时，访问数据的速度是最慢的，那么如何尽可能地减少DB的访问次数呢？

方法1：尽量使用内表进行数据库的批量操作

这个原则很好理解，例如，要向数据库中插入100条数据，那么可以通过内表批量操作。

* -- Bad -- *
LOOP AT lt_sflight INTO ls_sflight.
   INSERT INTO sflight VALUES ls_sflight.
ENDLOOP.

* -- Good-- *
INSERT INTO sflight FROM TABLE lt_sflight .

方法2：使用Join进行在DB层级进行数据的处理

如果通过JOIN能够完成数据的处理，则尽可能减少在ABAP的AS进行处理。

* -- Bad -- *
SELECT carrid connid fldate 
   FROM sflight INTO (xcarrid, xconnid, xfldate) 
   WHERE planetype = '727-200'.
        SELECT bookid FROM sbook INTO ybookid
         WHERE carrid = xcarrid
	   		AND connid = xconnid
			AND fldate = xfldate.
			WRITE: / xcarrid, xconnid, ybookid.
		ENDSELECT.
ENDSELECT.

* -- Good-- *
SELECT f~carrid f~connid b~bookid
    INTO (xcarrid, xconnid, ybookid) 
    FROM sflight AS f
    INNER JOIN sbook AS b
        ON f~carrid = b~carrid 
        AND f~connid = b~connid 
        AND f~fldate = b~fldate
   WHERE planetype = '727-200'.
   WRITE: / xcarrid, xconnid, ybookid.
ENDSELECT.

方法3：将常用的INNER JOIN创建成DDIC的JOIN VIEW

通过这种方式，在ABAP程序中，可以直接使用VIEW来读取数据多个表的JOIN数据集。

方法4：使用子查询

当需要对同一张表进行多次访问时，可以考虑使用子查询的方式，减少DB的访问次数。

* 举例：确定哪一天的航班预定出座位最多的？

* 方式1：双层select。首先选择出预定最多的航班信息，再确定具体的日期。
DATA: ls_sflight TYPE sflight,
      lv_max     TYPE i.
SELECT carrid connid MAX( seatsocc )
  FROM sflight
  INTO (ls_sflight-carrid, ls_sflight-connid, lv_max)
  GROUP BY carrid connid.

  SELECT fldate FROM sflight
    INTO ls_sflight-fldate
    WHERE carrid = ls_sflight-carrid
      AND connid = ls_sflight-connid
      AND seatsocc = lv_max.
    WRITE: / ls_sflight-carrid, ls_sflight-connid, ls_sflight-fldate.
  ENDSELECT.

ENDSELECT.

* 方式2：使用子查询。单层SELECT直接选择出航班信息和日期信息，将最大的座位数在子查询中确定。
SELECT carrid connid fldate
  FROM sflight AS f
  INTO (ls_sflight-carrid, ls_sflight-connid, ls_sflight-fldate)
  WHERE seatsocc IN ( SELECT MAX( seatsocc )
                        FROM sflight
                       WHERE carrid = f~carrid
                         AND connid = f~connid ).
  WRITE: / ls_sflight-carrid, ls_sflight-connid, ls_sflight-fldate.
ENDSELECT.