2021-09-14

WINDOWS环境下DELPHI调用JAVA类的方法

前言

因为地方医保政策，导致需要链接国家医保接口，国家医保使用了SM2和SM4的加密方式。而且也只提供了JAVA的DEMO，导致DELPHI无从下手。一开始想从SM2和SM4加密下手，找了很多资料，也只有寥寥的几篇文章是针对SM3和SM4的。所以就想到了是否可以用DELPHI调用JAVA的类，实现此加解密功能。也是找了很多资料，也非常感谢CSDN的各位大神们留下相关的代码和资料，最终实现。因本人对JAVA一点都不了解，遇到很多的坑，也是资料和代码看不到的，一 一写明 ，避免后续有人需要使用这类方法无从下手。

环境准备

1.下载并安装JDK，我使用的是JDK1.8，各位根据需要下载安装
2. 配置JDK的环境变量（JAVA_HOME，CLASSPATH，path）一个都不能少，不知道如何配置的可以自行查找，就不赘述了。
3. 使用了一个开源三方的DelphiJNI，下载地址：DelphiJNI；
4. 准备你要调用的JAVA类的CLASS或JAR文件。文件放置的位置要参照JAVA类的package路径，例如：package com.gj.utils;那就是在应用程序的所在路径下，建立com\gj\utils文件夹路径。
5. 要确定你调用JAVA类和包括调用他方法所对应类的引用三方的类和JAR包（JDK内置的不需要），并一并按照对应的路径放置。

开始代码实现

1. 初始化JVM运行环境

procedure TForm1.Button1Click(Sender: TObject);
var
  Options: array [0 .. 1] of JavaVMOption;
  VM_args: JavaVMInitArgs;
  ErrCode: jint;
begin
  { 创建 Java 虚拟机 }
  FJavaVM := TJavaVM.Create;
  { 配置Java 虚拟机需要加载的CLASS和JAR，CLASS可以到路径，JAR必须要确定文件，
  多路径和JAR加载用;分隔，以下是我调用类所使用的3个JAR文件，必须都要配置好 }
  Options[0].optionString :=
    PAnsiChar(AnsiString('-Djava.class.path=' + ExtractFilePath(ParamStr(0)) +
    'classes;' + ExtractFilePath(ParamStr(0)) +
    'classes\com\gj\cwjs\utils\bcpkix-jdk15on-1.60.jar;' +
    ExtractFilePath(ParamStr(0)) +
    'classes\com\gj\cwjs\utils\bcprov-jdk15on-1.60.jar;' +
    ExtractFilePath(ParamStr(0)) +
    'classes\com\gj\cwjs\utils\hsaf-common-1.0.0-SNAPSHOT.jar'));

  { 设定虚拟机使用的JDK版本}
  VM_args.version := JNI_VERSION_1_8;
  VM_args.Options := @Options;
  { 设置@Options参数数量}
  VM_args.nOptions := 1;
  VM_args.ignoreUnrecognized := true;
  { 这里编译会出内存错误不清楚为什么，但是运行不会，也没有影响！！}
  ErrCode := FJavaVM.LoadVM(VM_args);
  if ErrCode < 0 then
  begin
    MessageBox(Handle, '加载Java VM运行环境配置错误', '创建Java VM', MB_OK OR MB_ICONERROR);
    Halt;
    Exit;
  end;
  { 创建 Java 虚拟机运行环境 }
  FJavaEnv := TJNIEnv.Create(FJavaVM.Env);
  if FJavaEnv = nil then
  begin
    MessageBox(Handle, '创建 Java 虚拟机运行环境错误', '创建 Java 虚拟机运行环境',
      MB_OK OR MB_ICONERROR);
    Exit;
  end
  else
  begin
    ShowMessage('Java 虚拟机运行环境初始成功！！！');
  end;
end;

2. 调用方法

procedure TForm1.btn1Click(Sender: TObject);
var
  jcls: JClass;
  plainString: UTF8String;
  strClass: UTF8String;
  strMetod: UTF8String;
  strSign: UTF8String;
  strArg, strResult: string;
  mid: JNI.JMethodID;
  jclsIns: JObject;
  sj: JNI.JString;
begin
  if Memo1.Text = '' then
    Exit;
  plainString := UTF8Encode(Memo1.Text); 
  { 查询 Java 类名 ，查找的类必须加载使用的全部三方JAR，不然找不到 }
  strClass := 'com/gj/cwjs/utils/BusinessHandleJAR';
  jcls := FJavaEnv.FindClass(strClass);
  if jcls = nil then
  begin
    ShowMessage('未找到或无法加载类！！！请检查CLASS的路径及加载的JAR文件');
    Exit;
  end;
  { 获取BusinessHandle类的构造函数}
  mid := FJavaEnv.GetMethodID(jcls, '<init>', '()V');
  if (mid = nil) then
  begin
    ShowMessage('获取BusinessHandle类的构造函数出错');
    Exit;
  end;
  { 创建类实例}
  try
    jclsIns := FJavaEnv.NewObjectV(jcls, mid, nil);
    if (jclsIns = nil) then
    begin
      ShowMessage('初始化类出错');
      Exit;
    end;
    { Java 函数名称、参数类型、参数 }
    strMetod := 'sign'; // 函数名称
    { 括号内是参数类型，有几个参数写几个，对应适合的类型，括号外是返回值类型，无返回值用V表示}
    strSign := 'String(String,String,String,String)';

    { 执行 Java 函数 中括号是你要传入的参数，我这不是Static函数，所以最后一个参数是FALSE}
    strResult := CallMethod(FJavaEnv, jclsIns, strMetod, strSign,
      [clientid, plainString, siyao, gongyao], false);

    if strResult <> '' then
    begin
      { MessageBox(Handle, PChar(Format('signSm3WithSm2调用返回值: %s', [strResult])),
        'signSm3WithSm2', MB_OK OR MB_ICONINFORMATION); }
      Memo4.Text := strResult;
    end
    else
    begin
      ShowMessage(strResult);
    end;
  finally
    jclsIns := nil;//记得释放
  end;

3.使用后销毁

procedure TForm1.FormDestroy(Sender: TObject);
begin
  if (FJavaEnv <> nil) then
    FreeAndNil(FJavaEnv);
  if (FJavaVM <> nil) then
  begin
    FJavaVM.DestroyJavaVM;
    FreeAndNil(FJavaVM);
  end;
end;

4.效果图，因为我这里有医保的一些私钥和公钥内容，没有办法提供源码，但需要了解的代码已经都放在上边了。

资料调阅基础¹

---

1. Delphi10.3 中通过JNI调用 Java 函数 ↩︎