CMake更进三步

更进一步里面介绍了项目里自己常用的技巧，更进二步里面介绍了windows下的技巧，而在windows下GUI开发基本离不开Qt，所以更进三步介绍配置Qt的一些方法。

配置Qt依赖

第一步必然离不开设置Qt的路径，考虑的本地以及构建机环境不一样，这里我比较推荐下面这种形式，我这里的文件结构如下

Project
├─ CMakeLists.txt
├─ QtEnv
│    ├─ linux_serverQtConfig.cmake
│    ├─ linux_localQtConfig.cmake
│    ├─ win_serverQtConfig.cmake
│    └─ win_localQtConfig.cmake
└─ src
       ├─ A
       │    └─ CMakeLists.txt
       ├─ B
       │    ├─ CMakeLists.txt
       │    └─ main.cpp
       └─ common
              └─ version.h.in

最外层的 CMakeLists.txt 里的编写如下：

if(LOCAL_BUILD)
  if(OS_WINDOWS)
    include(QtEnv/win_localQtConfig.cmake)
  elseif(OS_LINUX)
    include(QtEnv/linux_localQtConfig.cmake)
    add_compile_options(-g)
  endif()
else()
  if(OS_WINDOWS)
    include(QtEnv/win_serverQtConfig.cmake)
  elseif(OS_LINUX)
    include(QtEnv/linux_serverQtConfig.cmake)
  endif()
endif()

# 打印一下Qt的地址
message(STATUS "Qt SKD dir: " ${QT_SDK_DIR})

# 设置 Qt 路径
set(CMAKE_PREFIX_PATH ${CMAKE_PREFIX_PATH} ${QT_SDK_DIR})

# 引用 Qt 的模块
find_package(QT NAMES Qt5 COMPONENTS Core Gui Widgets REQUIRED)
find_package(Qt5 COMPONENTS Core Gui Widgets REQUIRED)

这里主要都是更进二步里面的介绍过的一些方式，脚本+自定义参数+跨平台宏定义
结合构建脚本解释一下，本地的构建脚本相对于构建机环境的构建脚本，会额外多一个 LOCAL_BUILD 宏的定义，大致如下

cmake -G "Visual Studio 16" -A Win32 ^
-DCMAKE_GENERATOR_TOOLSET=v142 ^
-DCMAKE_SYSTEM_VERSION=8.1 ^
-B build_win ^
-DLOCAL_BUILD=ON ^
-DBUILD_DEMO=OFF ^
-DTEST_ENV=ON

所以本地 windows 构建，其实用的就是 win_localQtConfig.cmake 文件中配置的 Qt 环境，具体文件内容如下：

set(QT_SDK_DIR 
    "D:/Qt5.15.0/5.15.2/msvc2019"
)

只设置了 Qt 的编译器路径，所以后面还需要在 cmake 里面设置 Qt 的信息

set(CMAKE_PREFIX_PATH ${CMAKE_PREFIX_PATH} ${QT_SDK_DIR})

后续通过 find_package 去查找 Qt 的指定模块就行，我这里是 Qt5，根据实际情况写
模块名称可以自己在Qt编译器路径下的 /lib/cmake 里面看文件夹的名称，文件夹名称去掉 Qt${QT_VERSION_MAJOR}，注意区分大小写
以我前面设置的本地Qt环境为例，就是 "D:/Qt5.15.0/5.15.2/msvc2019/lib/cmake" 路径，该路径下的文件夹名称去掉 Qt5 就是模块名称

链接Qt库

代码用到什么模块，这里链接什么模块，我这里的 ${THREE_LIBS} 是项目中的依赖的其他三方库，可以忽略

target_link_libraries(${PROJECT_NAME}
  PRIVATE
  ${THREE_LIBS}
  Qt5::Core 
  Qt5::Gui 
  Qt5::Widgets 
  Qt5::Svg 
  Qt5::Xml 
  Qt5::WebChannel 
  Qt5::WebEngineWidgets 
  Qt5::WebEngine 
  Qt5::Script
)

moc等处理

因为 Qt 存在 moc，uic，rcc 处理，cmake 里面需要指定开启，但是配置语法很简单

set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTORCC ON)

windeployqt打包

windows下qt实际上提供了 windeployqt.exe 来进行依赖环境的打包，所以这里我们先找到可执行程序的位置，然后结合前面说的的 add_custom_command 执行命令的方法，直接进行Qt环境的打包

if(OS_WINDOWS)
set(DEPLOYQT_EXECUTABLE ${QT_SDK_DIR}/bin/windeployqt.exe)
message(STATUS "windeployqt dir: " ${DEPLOYQT_EXECUTABLE})
endif()

if(OS_WINDOWS)
add_custom_command(TARGET ${PROJECT_NAME}
  POST_BUILD
  COMMAND ${DEPLOYQT_EXECUTABLE}
    --no-translations
    --no-compiler-runtime
    --release
    $<TARGET_FILE:${PROJECT_NAME}>
)
endif()

为什么不提 linux 下的打包，虽然目前也有开源的项目 linuxdeployqt 打包，它本质还是类似用 ldd 查看库的链接关系，然后拷贝依赖，但是毕竟官方没有出打包工具

知道原理，其实可以更简单的写个脚本就可以了，但是涉及到 qml 这一块，我不了解，我自己的项目也没有用到，自己的编写的脚本属于针对自己项目的定制化，之后有空也可以整理出来~

普通三方库

Qt 本身也是一个三方库，只是 cmake 对它做了很多额外的支持，其他普通的三方库，我们使用就一个思路，设置查找头文件位置，设置链接库名称和库的查找地址，所以也就以下三个方法

# 设置头文件的查找地址
target_include_directories()

# 设置三方库的查找地址
target_link_directories()

# 设置三方库名称
target_link_libraries()

这三个方法需要在 add_executable() 和 add_library() 后面设置，那么肯定有人会问，为什么特别强调，因为还有一些语法通常在他们前面设置

# 设置头文件的查找地址
include_directories()

# 设置三方库的查找地址
link_directories()

# 设置三方库名称
link_libraries()

相比之下，target_include_directories(), target_link_directories(), 和 target_link_libraries() 是针对具体的目标设定，所以它们必须在创建目标（add_executable() 或 add_library()）后调用。

以下是两组的主要差别：

include_directories(), link_directories(), link_libraries() 这一类的命令影响所有后续的目标，更全局。
target_include_directories(), target_link_directories(), target_link_libraries() 这一类的命令只影响特定的目标，更局部。

建议尽可能采用后一类命令（即以 target_ 开头的命令），因为它们使得依赖关系更加明确，更容易跟踪，减少意外问题的可能性。