TestLplC.nc

/**
 * Simple test code for low-power-listening. Sends a sequence of packets,
 * changing the low-power-listening settings every ~32s. See README.txt
 * for more details.
 */

#include "Timer.h"

module TestLplC {
  uses {
    interface Leds;
    interface Boot;
    interface Receive;
    interface AMSend;
    interface Timer<TMilli> as MilliTimer;
    interface SplitControl;
    interface LowPowerListening;
  }
}
implementation {
  message_t packet;
  bool locked;
  uint8_t counter = 0, sendSkip;
  int16_t sendInterval;

  event void Boot.booted() {
    call SplitControl.start();
  }

  void nextLplState() {
    switch (counter >> 5) {
    case 0:
      sendSkip = 0;
      sendInterval = 0;
      call LowPowerListening.setLocalWakeupInterval(0);
      break;
    case 1:
      sendInterval = 100; /* Send to sleepy listener */
      break;
    case 2:
      sendInterval = -1; /* Send to listener like us */
      call LowPowerListening.setLocalWakeupInterval(250);
      break;
    case 3:
      sendInterval = 0; /* Send to awake listener */
      break;
    case 4:
      sendInterval = -1; /* Send to listener like us */
      call LowPowerListening.setLocalWakeupInterval(10);
      break;
    case 5:
      sendSkip = 7; /* Send every 7s */
      call LowPowerListening.setLocalWakeupInterval(2000);
    }
  }

  event void MilliTimer.fired() {
    counter++;
    if ((counter & 0x1F) == 0)
      nextLplState();

    if (!locked && ((counter & sendSkip) == sendSkip)) {
      if (sendInterval >= 0)
        call LowPowerListening.setRemoteWakeupInterval(&packet, sendInterval);
      if (call AMSend.send(AM_BROADCAST_ADDR, &packet, 0) == SUCCESS) {
        call Leds.led0On();
        locked = TRUE;
      }
    }
  }

  event message_t * Receive.receive(message_t * bufPtr, void * payload, uint8_t len) {
    call Leds.led1Toggle();
    return bufPtr;
  }

  event void AMSend.sendDone(message_t* bufPtr, error_t error) {
    if (&packet == bufPtr) {
      locked = FALSE;
      call Leds.led0Off();
    }
  }

  event void SplitControl.startDone(error_t err) {
    call MilliTimer.startPeriodic(1000);
  }

  event void SplitControl.stopDone(error_t err) { }
}