SPARQL Tutorial

最新推荐文章于 2023-08-28 12:04:11 发布
最新推荐文章于 2023-08-28 12:04:11 发布
阅读量607 收藏
点赞数 1
分类专栏： 图数据库 文章标签： sparql
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_27668313/article/details/113770605
版权

目录

前言

  本文是SPARQL官方入门教程，通过示例介绍SPARQL的主要功能。SPARQL是一种查询语言，用于查询RDF结构的数据。虽然RDF数据具备推理性，但是SPARQL本身没有推理查询功能，它是面向数据的，只能查询数据中包含的信息。
官方文档：sparql tutorial

1 JENA安装

  本教程演示在windows 10系统下安装JENA。JENA官方下载地址：https://jena.apache.org/download/index.cgi#， 选择.zip文件，下载后解压即可。安装JENA的前提是安装了Java运行环境。解压后设置JENA环境变量。
  在系统的环境变量中新建变量JENA_HOME，如下图所示，变量值填写你的JENA解压地址。
在这里插入图片描述
  然后在系统环境变量的“PATH”变量中添加值“;%JENA_HOME%\bat”。最后测试安装是否成功，在cmd终端中输入命令：sparql --version，将出现版本号信息：
在这里插入图片描述

2 Data Format

  首先我们要清楚待查询数据的结构。SPARQL是在RDF图上查询，一个RDF图就是一组三元组。在Jena数据库中将RDF图称为模型（models），将三元组称为陈述（statements）。有很多种协议用于描述RDF三元组，描述三元组的方式称为序列化（serialization）。用何种序列化方式并不重要，我们关心的是三元组本身内容。RDF\XML是一种序列化方式，但这种方式不适合人类阅读。我们采用另一种序列化方式：Turtle。本文使用的数据如下图所示，数据下载地址：vc-db-1.rdf，格式是RDF/XML。
在这里插入图片描述

  使用Turtle方式描述上述图，得到如下文件内容：

@prefix vCard:   <http://www.w3.org/2001/vcard-rdf/3.0#> .
@prefix rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#> .

<http://somewhere/MattJones/>  vCard:FN   "Matt Jones" .
<http://somewhere/MattJones/>  vCard:N    _:b0 .
_:b0  vCard:Family "Jones" .
_:b0  vCard:Given  "Matthew" .

<http://somewhere/RebeccaSmith/> vCard:FN    "Becky Smith" .
<http://somewhere/RebeccaSmith/> vCard:N     _:b1 .
_:b1 vCard:Family "Smith" .
_:b1 vCard:Given  "Rebecca" .

<http://somewhere/JohnSmith/>    vCard:FN    "John Smith" .
<http://somewhere/JohnSmith/>    vCard:N     _:b2 .
_:b2 vCard:Family "Smith" .
_:b2 vCard:Given  "John"  .

<http://somewhere/SarahJones/>   vCard:FN    "Sarah Jones" .
<http://somewhere/SarahJones/>   vCard:N     _:b3 .
_:b3 vCard:Family  "Jones" .
_:b3 vCard:Given   "Sarah" .

  上述内容中行的顺序可以打乱，机器在读取数据时并不关心数据的位置，这样写只是为了方便人类阅读。下载上面的数据，保存到本地电脑中。
  本文在JENA安装目录下新建doc\Tutorial文件夹，将vc-db-1.rdf文件保存到该文件夹中。

3 A First SPARQL Query

  本小节介绍一个简单的查询例子，并展示Jena数据库是如何执行查询过程的。
  查询的数据就是7.2节展示的数据，查询语句如下：

SELECT ?x
WHERE { ?x  <http://www.w3.org/2001/vcard-rdf/3.0#FN>  "John Smith" }

  这个语句来自q1.rq。“?”表示这是个变量，“x”是变量名。“<>”中的是一个URI，描述了一个资源地址。双引号中的内容表示字面量（literal）。Where从句中描述了一个RDF三元组，其中主体是要查询的变量，谓语和客体已经给出具体的值。JENA按照谓语和客体区数据库中查找对应的三元组，然后返回找到的三元组的主体。
  将这个查询语句保存为文件q1.rq，并保存到本地的doc/Tutorial文件夹下，也就是和7.2节的数据文件vc-db-1.rdf放一起。如下所示：
在这里插入图片描述
  打开cmd终端，进入doc/Tutorial目录下，执行命令：

sparql --data=vc-db-1.rdf --query=q1.rq

  出现如下内容：
在这里插入图片描述
  图中的“x”对应查询语句中的“x”，下方的值就是返回的结果。Where从句中也可以只指定一个值，其他两个值都是变量，如下查询语句：

SELECT ?x ?fname
WHERE {?x  <http://www.w3.org/2001/vcard-rdf/3.0#FN>  ?fname}

  将上述语句保存为文件q-bp1.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=vc-db-1.rdf --query=q-bp1.rq

  返回查询结果如下图。
在这里插入图片描述

4 Basic Patterns

  一个基本的pattern就是一组三元组pattern，即在where从句中可以有多个三元组。多个三元组中变量名相同的变量需要匹配同一个实体。如下的查询语句中，两个三元组中的变量y表示的是同一个实体。

SELECT ?givenName
WHERE
  { ?y  <http://www.w3.org/2001/vcard-rdf/3.0#Family>  "Smith" .
    ?y  <http://www.w3.org/2001/vcard-rdf/3.0#Given>  ?givenName .
  }

  将上述查询语句保存为文件q-bq2.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=vc-db-1.rdf --query=q-bp2.rq

  返回查询结果如下图。
在这里插入图片描述
  SPARQL支持URI简写，可将上面的查询语句改为如下形式：

PREFIX vcard:      <http://www.w3.org/2001/vcard-rdf/3.0#>

SELECT ?givenName
WHERE
 { ?y vcard:Family "Smith" .
   ?y vcard:Given  ?givenName .
 }

  第一行表示用vcard代替http://www.w3.org/2001/vcard-rdf/3.0#。将上述查询语句保存为文件q-bq3.rq，放到doc/Tutorial目录下。在终端执行命令：sparql --data=vc-db-1.rdf --query=q-bp3.rq。
  同样也可以返回查询的中间节点，上述查询中的节点‘y’就是中间节点，只要在select从句中加上该变量名即可，如下所示：

PREFIX vcard:      <http://www.w3.org/2001/vcard-rdf/3.0#>

SELECT ?y ?givenName
WHERE
 { ?y vcard:Family "Smith" .
   ?y vcard:Given  ?givenName .
 }

  将上述查询语句保存为文件q-bq4.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=vc-db-1.rdf --query=q-bp4.rq

  返回查询结果如下图。
在这里插入图片描述
  返回的结果中‘y’具有不同的值，这是因为这个变量在数据中是个空白节点，针对空白节点，系统自动安排变量值。即使是同一个空白节点，系统打印的变量值也是不同的。

5 Filters

  本文讲解如何给返回结果加上限制条件。第一种是使用正则表达式对返回结果中的字符串作出限制。语法如下：

FILTER regex(?x, "pattern" [, "flags"])

  Pattern表示给出的正则表达式，flag是可选项。给出如下查询语句：

PREFIX vcard: <http://www.w3.org/2001/vcard-rdf/3.0#>

SELECT ?g
WHERE
{ ?y vcard:Given ?g .
  FILTER regex(?g, "r", "i") }

  “r”表示返回的字符串中需要包含字母“r”，“i”是一个flag，表示不区分字符串中的大小写。将上述查询语句保存为文件q-f1.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=vc-db-1.rdf --query=q-f1.rq

  返回查询结果如下图。
在这里插入图片描述
  第二种是按条件返回结果。我们使用新的数据集，在其中加入人物的年龄信息，部分内容如下所示：

<rdf:RDF
  xmlns:rdf='http://www.w3.org/1999/02/22-rdf-syntax-ns#'
  xmlns:vCard='http://www.w3.org/2001/vcard-rdf/3.0#'
  xmlns:info='http://somewhere/peopleInfo#'
   >

  <rdf:Description rdf:about="http://somewhere/JohnSmith">
    <vCard:FN>John Smith</vCard:FN>
    <info:age rdf:datatype='http://www.w3.org/2001/XMLSchema#integer'>25</info:age>
    <vCard:N rdf:parseType="Resource">
	<vCard:Family>Smith</vCard:Family>
	<vCard:Given>John</vCard:Given>
    </vCard:N>
  </rdf:Description>

  <rdf:Description rdf:about="http://somewhere/RebeccaSmith">
    <vCard:FN>Becky Smith</vCard:FN>
    <info:age rdf:datatype='http://www.w3.org/2001/XMLSchema#integer'>23</info:age>
    <vCard:N rdf:parseType="Resource">
	<vCard:Family>Smith</vCard:Family>
	<vCard:Given>Rebecca</vCard:Given>
    </vCard:N>
  </rdf:Description>

  <rdf:Description rdf:about="http://somewhere/SarahJones">
    <vCard:FN>Sarah Jones</vCard:FN>
    <vCard:N rdf:parseType="Resource">
	<vCard:Family>Jones</vCard:Family>
	<vCard:Given>Sarah</vCard:Given>
    </vCard:N>
  </rdf:Description>

  <rdf:Description rdf:about="http://somewhere/MattJones">
    <vCard:FN>Matt Jones</vCard:FN>
    <vCard:N
	vCard:Family="Jones"
	vCard:Given="Matthew"/>
  </rdf:Description>

</rdf:RDF>

  我们查询所有年龄大于24岁的人，查询语句如下所示：

PREFIX info: <http://somewhere/peopleInfo#>

SELECT ?resource
WHERE
  {
    ?resource info:age ?age .
    FILTER (?age >= 24)
  }

  将上述查询语句保存为文件q-f2.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=vc-db-1.rdf --query=q-f2.rq

  返回查询结果如下图。
在这里插入图片描述

6 Optional Information

  RDF 是半结构化数据，RDF中不同的实体可能具有不同的属性。SPARQL可以查询RDF中存在的信息，但是在查询不存在的信息时并不会显示查询失败，也不会返回任何结果。可以使用Optional关键字，表示该查询是可选的，也就是当实体存在该属性时，就返回结果，不存在时就返回空。
  例如下面的查询语句：

PREFIX info:    <http://somewhere/peopleInfo#>
PREFIX vcard:   <http://www.w3.org/2001/vcard-rdf/3.0#>

SELECT ?name ?age
WHERE
{
    ?person vcard:FN  ?name .
    OPTIONAL { ?person info:age ?age }
}

  Optional后的三元组表示实体存在age属性时就返回该属性结果，不存在就返回空。将上述查询语句保存为文件q-opt1.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=vc-db-2.rdf --query=q-opt1.rq

  返回查询结果如下图。
在这里插入图片描述
  如果没有optional关键字，上述查询语句就不会返回没有age属性的实体。如下所示，删除optional后的查询语句：

PREFIX info:   <http://somewhere/peopleInfo#>
PREFIX vcard:  <http://www.w3.org/2001/vcard-rdf/3.0#>

SELECT ?name ?age
WHERE
{
    ?person vcard:FN  ?name .
    ?person info:age ?age .
}

  将上述查询语句保存为文件q-opt2.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=vc-db-2.rdf --query=q-opt2.rq

  返回查询结果如下图。
在这里插入图片描述
  Filter关键词也可以在optional中使用，如下所示：

PREFIX info:        <http://somewhere/peopleInfo#>
PREFIX vcard:      <http://www.w3.org/2001/vcard-rdf/3.0#>

SELECT ?name ?age
WHERE
{
    ?person vcard:FN  ?name .
    OPTIONAL { ?person info:age ?age . FILTER ( ?age > 24 ) }
}

  上述查询将filter关键词放在optional的三元组中，因此filter只对该三元组的结果有效。将上述查询语句保存为文件q-opt3.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=vc-db-2.rdf --query=q-opt3.rq

  返回查询结果如下图。
在这里插入图片描述
  如果将filter放到外面，filter将对所有返回结果都有效，例如：

PREFIX info:        <http://somewhere/peopleInfo#>
PREFIX vcard:      <http://www.w3.org/2001/vcard-rdf/3.0#>

SELECT ?name ?age
WHERE
{
    ?person vcard:FN  ?name .
    OPTIONAL { ?person info:age ?age . }
    FILTER ( !bound(?age) || ?age > 24 )
}

  Filter中的条件表示若实体存在age属性，则必须大于24，否则不返回。对于不存在age属性的实体，仍可以返回。这是因为!bound表示未绑定的意思，!bound(?age)意思是实体可以没有age属性。因此这个filter语句的含义是：保留age大于24的实体或者没有age属性的实体。将上述查询语句保存为文件q-opt4.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=vc-db-2.rdf --query=q-opt4.rq

  返回查询结果如下图。
在这里插入图片描述
  如果filter中没有!bound(?age)，则只会返回一个结果，如下：
在这里插入图片描述

7 Alternatives in a Pattern

  有时我们需要联合多种条件进行查询，UNION关键词可以实现此目的。UNION用于联合多个查询三元组，只要实体满足其中一个三元组即可返回。本节使用的数据内容如下：

@prefix foaf: <http://xmlns.com/foaf/0.1/> .
@prefix vcard: <http://www.w3.org/2001/vcard-rdf/3.0#> .

_:a foaf:name   "Matt Jones" .
_:b foaf:name   "Sarah Jones" .
_:c vcard:FN    "Becky Smith" .
_:d vcard:FN    "John Smith" .

  将上述内容保存为文件vc-db-3.ttl，放到doc/Tutorial目录下。查询语句如下：

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX vCard: <http://www.w3.org/2001/vcard-rdf/3.0#>

SELECT ?name
WHERE
{
   { [] foaf:name ?name } UNION { [] vCard:FN ?name }
}

  将上述查询语句保存为文件q-union1.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=vc-db-3.ttl --query=q-union1.rq

  返回查询结果如下图。
在这里插入图片描述
  也可以使用filter关键词实现同样的功能，查询语言如下：

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX vCard: <http://www.w3.org/2001/vcard-rdf/3.0#>

SELECT ?name
WHERE
{
  [] ?p ?name
  FILTER ( ?p = foaf:name || ?p = vCard:FN )
}

  这种方式效率可能没有前一种快，这里是先查询出所有的实体，然后在进行过滤。将上述查询语句保存为文件q-union-1alt.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=vc-db-3.ttl --query=q-union-1alt.rq

  返回查询结果和上一个相同。

8 Datasets

  有时候一个graph中含有多个graph，例如下面的default graph中含有ds-ng-1.ttl和ds-ng-2.ttl。

@prefix dc: <http://purl.org/dc/elements/1.1/> .
@prefix xsd: <http://www.w3.org/2001/XMLSchema#> .

<ds-ng-1.ttl> dc:date "2005-07-14T03:18:56+0100"^^xsd:dateTime .
<ds-ng-2.ttl> dc:date "2005-09-22T05:53:05+0100"^^xsd:dateTime .

  ds-ng-1.ttl是一个named graph，其内容如下：

@prefix dc: <http://purl.org/dc/elements/1.1/> .

[] dc:title "Harry Potter and the Philospher's Stone" .
[] dc:title "Harry Potter and the Chamber of Secrets" .

  ds-ng-2.ttl是一个named graph，其内容如下：

@prefix dc: <http://purl.org/dc/elements/1.1/> .

[] dc:title "Harry Potter and the Sorcerer's Stone" .
[] dc:title "Harry Potter and the Chamber of Secrets" .

  返回default graph中的所有三元组，尽管default graph中引用了其他的named graph，这些named graph中的三元组是不会返回的。查询语句如下：

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX : <.>

SELECT *
{ ?s ?p ?o }

  其中的“PREFIX : <.>” 仅是为了简化输出格式。将上述查询语句保存为文件q-ds-1.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=ds-dft.ttl --query=q-ds-1.rq

  返回查询结果如下。
在这里插入图片描述
  下面的查询语句将返回引用的named graph内容。查询语句如下所示：

PREFIX  xsd:    <http://www.w3.org/2001/XMLSchema#>
PREFIX  dc:     <http://purl.org/dc/elements/1.1/>
PREFIX  :       <.>

SELECT *
{
    { ?s ?p ?o } UNION { GRAPH ?g { ?s ?p ?o } }
}

  GRPHA关键词表示变量g是一个named graph。将上述查询语句保存为文件q-ds-2.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=ds-dft.ttl --query=q-ds-2.rq --graph ds-dft.ttl --namedgraph ds-ng-1.ttl --namedgraph ds-ng-2.ttl

  返回查询结果如下。
在这里插入图片描述
  也可以指定查询某个named graph，如下查询语句指定查询ds-ng-2.ttl。

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX : <.>

SELECT ?title
{
  GRAPH :ds-ng-2.ttl
    { ?b dc:title ?title }
}

  将上述查询语句保存为文件q-ds-3.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=ds-dft.ttl --query=q-ds-3.rq --graph ds-dft.ttl --namedgraph ds-ng-1.ttl --namedgraph ds-ng-2.ttl

  返回查询结果如下。
在这里插入图片描述
  Named graph也可以作为一个变量，使用条件查询来选择named graph。查询语句如下：

PREFIX  xsd:    <http://www.w3.org/2001/XMLSchema#>
PREFIX  dc:     <http://purl.org/dc/elements/1.1/>
PREFIX  :       <.>

SELECT ?date ?title
{
  ?g dc:date ?date . FILTER (?date > "2005-08-01T00:00:00Z"^^xsd:dateTime )
  GRAPH ?g
      { ?b dc:title ?title }
}

  Filter关键词筛选变量g，然后将g作为named graph。将上述查询语句保存为文件q-ds-4.rq，放到doc/Tutorial目录下。在终端执行命令：

sparql --data=ds-dft.ttl --query=q-ds-4.rq --graph ds-dft.ttl --namedgraph ds-ng-1.ttl --namedgraph ds-ng-2.ttl

  返回查询结果如下。
在这里插入图片描述

纽约的自行车
关注
专栏目录
SPARQL教程
Oeljeklaus的博客
03-23 2万+
介绍 在SPARQL 101中，我们介绍了SPARQL是什么，它如何与其他查询语言相关，并且通过了基本的SPARQL语法。 这个课程建立在这个基础上，主要是以示例为基础。我们使用许多现实世界的SPARQL查询来说明查询语言的功能，作为提高效率的最快方法。 这是一个技术性的课程。 先决条件 SPARQL 101 今天课 在本教程中，我们将使用DB
SPARQL 入门教程
weixin_34227447的博客
11-21 267
1.准备工作 1.1 下载ZIP 1.2 配置环境变量 1.3 查询文件 vc-db-1.rdf 2. 查询操作 2.1 普通查询 /** * 查询family为“Smith”的 GivenName */ // 前缀声明 PREFIX vcard: <http://www.w3.org/2001/vcard-rdf/3.0#> SELECT ?givenName WHE...
sparql入门-中文教程
热门推荐
minosisterry的博客
11-05 1万+
粗糙翻译，供自己学习记录用，有时间再精细化。不明朗之处请对照英文原文理解 简化版：https://blog.csdn.net/minosisterry/article/details/102963985 官网教程链接：http://jena.apache.org/tutorials/sparql_data.html 先给个定义： SPARQL是W3C RDF数据访问工作组设计的用于访问RD...
SPARQL 教程八
最新发布
weixin_43742726的博客
08-28 286
SELECT 形式直接返回解决方案表作为结果集，而 DESCRIBE 和 CONSTRUCT 则使用匹配结果来构建 RDF 图。
SPARQL查询语言
皂雨霏霏的博客
12-28 1186
SPARQL的查询是基于结构化知识的，变无序数据为有序知识，让计算机理解Web信息，即语义Web。现如今，语义网适用于各个领域，包括语义出版、语义知识库等。SPARQL是针对以RDF框架进行存储的知识库进行检索的SQL语句，因此有一定SQL基础的话，学习会很容易。 1.概述 2.匹配模式 3.组织结果集 4.查询方式 5.使用方式 什么是语义网？ 语义网是一种使用可以被计算机理解的方式描...
【其他】RDF与SPARQL
Linoy
02-21 536
RDF(Resource Description Framework) RDF在线验证器 RDF(资源描述框架)是描述网络资源的 W3C 标准 <?xml version="1.0"?> <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" xmlns:si="http://www.runoob.co...
jena 查询 java_Jena搭建SPARQL查询RDF数据
weixin_36372452的博客
02-26 676
1Jena搭建SPARQL查询RDF数据1.1Jena概要·SPARQL是W3C的RDF数据工作组设计的一种查询语言和协议，用于RDF数据的查询。经过类似于JDK安装时候的配置，可以在命令行运行SPARQL查询，也可以在安装了JenaAPI之后，在Java程序用使用SPARQL查询。1.2Jena环境搭建·可以从http://jena.sourceforge.net免费获得Jena的最...
JENA的安装和配置+Myeclipse的破解及安装+sparql查询的例子
weixin_37197708的博客
11-07 1418
jena的配置和安装，附带测试教程
知识表示
Scarlett
03-02 1470
本文参考：http://notes.duyichao.site/早期知识表示 1、 一阶谓词逻辑（First-Order Logic） Horn逻辑：一阶谓词逻辑的子集 p(t1,t2....,tn) p：谓词，n:目（项），ti:变量或常量 eg: has_child(Helen,Jack) 描述逻辑：一阶谓词逻辑...
理解_SPARQL_-_SPARQL中文详解
02-20
本教程介绍了 SPARQL 以及基础数据格式。还涵盖了 RDF、RDF Schema、OWL 以及 Turtle 知识表示语言。通过这些语言可以建立本体 或者域模型。本教程的例子建立了用于日志和预约系统的本体和查询，可以生成带语义标签的类似 twitter 的微型博客。通过查询博客记录可以发现公司中具备您的项目所需技能并且可以组成团队的人员。 
Sparql学习
baidu_15113429的博客
08-31 510
PREFIX rdf: &lt;http://www.w3.org/1999/02/22-rdf-syntax-ns#&gt; PREFIX owl: &lt;http://www.w3.org/2002/07/owl#&gt; PREFIX rdfs: &lt;http://www.w3.org/2000/01/rdf-schema#&gt; PREFIX xsd: &lt;http://ww...
SPARQL基础入门练习
Zjhao666的博客
06-24 871
知识图谱：Freebase，服务器：virtuosoSPARQL基本语法表一个SPARQL样例 大致意思是在virtuoso服务器执行后，设置格式为html，结果如下。此外，值得注意的是，对于 而言，若写为 则返回满足后续（where子句里的）约束条件的(x1, x2, x3)组合。最简单的形式 这表示，不加任何限制地，查询图谱内所有的三元组。返回结果自然就有很多：可以看到返回结果的顶上，还写上了查询语句里我们自己命名的e1，r，e2。加上一个三元组的约束 即要求变量e1和r，满足三元组
知识图谱：SPARQL的基本语法示例
Puzzle的博客
04-30 8269
前言 SPARQL的英文全称为SPARQL Protocol and RDF Query Language，是为RDF开发的一种查询语言和数据获取协议，它是为W3C所开发的RDF数据模型所定义，但是可以用于任何可以用RDF来表示的信息资源。 从SPARQL的全称我们可以知道，其由两个部分组成：协议和查询语言。 1、查询语言很好理解，就像SQL用于查询关系数据库中的数据，XQuery用于查询XML数据，SPARQL用于查询RDF数据。 2、协议是指我们可...
如何运行SPARQL
mnshenyanping的专栏
04-07 941
1、创建***.rdf数据源文件 2、创建###.rq查询语句文件       如： SELECT ?x WHERE { ?x    "John Smith" } 3、执行：      sparql --data=***.rdf --query=###.rq命令！      注：在执行上面的查询时，要保证数据文件和查询文件在当前目录下，否则命令中应
Jena安装使用以及sparql查询
Minor0218的博客
08-12 975
Jena的下载使用以及简单查询
知识图谱构建5——Jena 和 Fuseki安装与SPARQL查询
野有蔓兮的博客
03-18 1万+
Jena 和 Fuseki安装与SPARQL查询 简介 Apache Jena是一个开源的Java语义网框架（open source Semantic Web Framework for Java），用于构建语义网和链接数据应用。 架构图如下： TDB：用于存储RDF的组件 Jena提供了RDFS、OWL和通用规则推理机 Fuseki：Jena提供的SPARQL服务器，也就是SPARQL end...
SPARQL初学 JDK和jena的配置
yumi_huang的博客
04-08 1706
1.配置JDK环境变量(win10) 打开控制面板——系统与安全——系统——高级系统设置 ①新建一个名为“JAVA_HOME”的环境变量，变量值为Java的安装路径。如E:\JDK-8u152 ②Path路径中添加如下信息：%JAVA_HOME%\bin;%JAVA_HOME%\jre\bin ③新建一个名为“classpath”的环境变量，变量值为.;%JAVA_HOME%\lib\dt...
SPARQL查询语言指南
"SPARQL查询语言是用于RDF数据的一种标准查询语言，由W3C推荐，并在2008年1月15日发布。它允许用户从不同的数据源，无论是原生的RDF格式还是通过中间件视图为RDF的数据中提取信息。该语言具有丰富的查询功能，包括...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值