[操作系统真相还原]第二章编写 MBBRR 主引导记录，实验部分以及可能遇到的一些小问题。

mbr.S文件

; 主引导程序
; -------------------------------------------------------------
SECTION MBR vstart=0x7c00 
mov ax,cs 
mov ds,ax 
mov es,ax 
mov ss,ax 
mov fs,ax 
mov sp,0x7c00 

; 清屏利用 0x06 号功能,上卷全部行,则可清屏｡
; ----------------------------------------------------------- 
; INT 0x10 功能号:0x06 功能描述:上卷窗口
; ------------------------------------------------------ 
; 输入: 
; AH 功能号= 0x06 
; AL = 上卷的行数(如果为 0,表示全部) 
; BH = 上卷行属性
; (CL,CH) = 窗口左上角的(X,Y)位置
; (DL,DH) = 窗口右下角的(X,Y)位置
; 无返回值: 
mov ax, 0x600 
mov bx, 0x700 
mov cx, 0 ; 左上角: (0, 0) 
mov dx, 0x184f ; 右下角: (80,25), 
; VGA 文本模式中,一行只能容纳 80 个字符,共 25 行｡
; 下标从 0 开始,所以 0x18=24,0x4f=79 
int 0x10 ; int 0x10 

;;;;;;;;; 下面这三行代码获取光标位置 ;;;;;;;;; 
;.get_cursor 获取当前光标位置,在光标位置处打印字符｡
mov ah, 3 ; 输入: 3 号子功能是获取光标位置,需要存入 ah 寄存器
mov bh, 0 ; bh 寄存器存储的是待获取光标的页号

int 0x10 ; 输出: ch=光标开始行,cl=光标结束行
; dh=光标所在行号,dl=光标所在列号

;;;;;;;;; 获取光标位置结束 ;;;;;;;;;;;;;;;; 

;;;;;;;;; 打印字符串 ;;;;;;;;;;; 
;还是用 10h 中断,不过这次调用 13 号子功能打印字符串
mov ax, message 
mov bp, ax ; es:bp 为串首地址,es 此时同 cs 一致, 
; 开头时已经为 sreg 初始化

; 光标位置要用到 dx 寄存器中内容,cx 中的光标位置可忽略
mov cx, 12 ; cx 为串长度,不包括结束符 0 的字符个数
mov ax, 0x1301 ;子功能号 13 显示字符及属性,要存入 ah 寄存器, 
; al 设置写字符方式 ah=01: 显示字符串,光标跟随移动
mov bx, 0x2 ; bh 存储要显示的页号,此处是第 0 页, 
; bl 中是字符属性,属性黑底绿字(bl = 02h) 
int 0x10 ; 执行 BIOS 0x10 号中断
;;;;;;;;; 打字字符串结束 ;;;;;;;;;;;;;;;

jmp $ ; 使程序悬停在此

message db "hhhyh get it" 
times 510-($-$$) db 0 
db 0x55,0xaa

安装编译器nasm编译二进制代码

sudo apt-get install nasm
nasm -o mbr.bin mbr.S

编译完成后可以执行,可以看到结果大小是512字节的（符合mbr引导的大小标准）

ls -lb mbr.bin

将编译出的二进制代码写入我们img的第一个块，大小为512，这样就可以负责启动我们的bios了

sudo dd if=/your_path/mbr.bin of=/your_path/bochs/hd60M.img bs=512 count=1 conv=notrunc

这是我的路径自用复制粘贴

sudo dd if=/home/h123/bochs/mbr.bin of=/home/h123/bochs/hd60M.img bs=512 count=1 conv=notrunc

启动我们的bochs

sudo bin/bochs -f bochsrc.disk

小问题

这个时候应该是一片黑屏，也别着急，在终端中输入continue，继续操作，你就会发现屏幕有输出了。（不能就我一开始没发现continue吧）
温馨提示：如果你的输出不全，请修改这个cx的长度，长度为message的长度（也就是你要打印的东西的长度）

mov cx, 12 ; cx 为串长度,不包括结束符 0 的字符个数

结果如下

第二章其实还是偏环境和概念，那么第二章实验就此结束了，第三章节就是完善我们的mbr了。