大数据-Hive高级-调优（MR模式）

第 1 章 Explain 查看执行计划（重点）

1.1 创建测试用表

1）建大表、小表和 JOIN 后表的语句

hive (test1)> use test1;
OK
Time taken: 0.027 seconds
// 创建大表
hive (test1)> create table bigtable(id bigint, t bigint, uid string, keyword string, url_rank int, click_num int, click_url string) row format delimited fields terminated by '\t';
// 创建小表
hive (test1)> create table smalltable(id bigint, t bigint, uid string, keyword string, url_rank int, click_num int, click_url string) row format delimited fields terminated by '\t';
// 创建JOIN后表
hive (test1)> create table jointable(id bigint, t bigint, uid string, keyword string, url_rank int, click_num int, click_url string) row format delimited fields terminated by '\t';

2） 分别向大表和小表中导入数据

hive (test1)> load data local inpath '/opt/module/data/bigtable' into table bigtable;
hive (test1)> load data local inpath '/opt/module/data/smalltable' into table smalltable;

1.2 基本语法

EXPLAIN [EXTENDED | DEPENDENCY | AUTHORIZATION] query-sql 

explain 查询sql语句

1.3 案例实操

1） 查看下面这条语句的执行计划

hive (test1)> explain select * from bigtable;
OK
Explain
STAGE DEPENDENCIES:
  Stage-0 is a root stage

STAGE PLANS:
  Stage: Stage-0
    Fetch Operator
      limit: -1
      Processor Tree:
        TableScan
          alias: bigtable
          Statistics: Num rows: 1 Data size: 1291573248 Basic stats: COMPLETE Column stats: NONE
          Select Operator
            expressions: id (type: bigint), t (type: bigint), uid (type: string), keyword (type: string), url_rank (type: int), click_num (type: int), click_url (type: string)
            outputColumnNames: _col0, _col1, _col2, _col3, _col4, _col5, _col6
            Statistics: Num rows: 1 Data size: 1291573248 Basic stats: COMPLETE Column stats: NONE
            ListSink

Time taken: 1.351 seconds, Fetched: 17 row(s)

可以看出 hive语句被划分了 stage，其实普通全表查询—不需要走MR，所以不会被拆分stage
例如：select * from 表名 ，这是通过对文件进行filter过滤就可以实现查询
count、sum、avg、group、max、min等聚合函数—是一定会走MR的
【注意：配置简单查询不走MR的方式】
在hive-site.xml里面有个配置参数：hive.fetch.task.conversion
将这个参数设置为more，简单查询就不走map/reduce了，设置为minimal，就任何简单select都会走map/reduce

不走MR（不会拆分stage）的各种情况：
1、等值判断

select * from table_name where name = “Tom”;

2、不等值判断

select * from table_name where age<>18;

3、模糊查询

select * from table_name where name like “%和%”;

4、空、非空值判断

select * from table_name where name is null;

5、大于、小于

select * from table_name where id>5;

hive (test1)> explain select click_url, count(*) ct from bigtable group by click_url;
OK
Explain
STAGE DEPENDENCIES:
  Stage-1 is a root stage
  Stage-0 depends on stages: Stage-1

STAGE PLANS:
  Stage: Stage-1
    Map Reduce
      Map Operator Tree:
          TableScan
            alias: bigtable
            Statistics: Num rows: 1 Data size: 1291573248 Basic stats: COMPLETE Column stats: NONE
            Select Operator
              expressions: click_url (type: string)
              outputColumnNames: click_url
              Statistics: Num rows: 1 Data size: 1291573248 Basic stats: COMPLETE Column stats: NONE
              Group By Operator
                aggregations: count()
                keys: click_url (type: string)
                mode: hash
                outputColumnNames: _col0, _col1
                Statistics: Num rows: 1 Data size: 1291573248 Basic stats: COMPLETE Column stats: NONE
                Reduce Output Operator
                  key expressions: _col0 (type: string)
                  sort order: +
                  Map-reduce partition columns: _col0 (type: string)
                  Statistics: Num rows: 1 Data size: 1291573248 Basic stats: COMPLETE Column stats: NONE
                  value expressions: _col1 (type: bigint)
      Execution mode: vectorized
      Reduce Operator Tree:
        Group By Operator
          aggregations: count(VALUE._col0)
          keys: KEY._col0 (type: string)
          mode: mergepartial
          outputColumnNames: _col0, _col1
          Statistics: Num rows: 1 Data size: 1291573248 Basic stats: COMPLETE Column stats: NONE
          File Output Operator
            compressed: false
            Statistics: Num rows: 1 Data size: 1291573248 Basic stats: COMPLETE Column stats: NONE
            table:
                input format: org.apache.hadoop.mapred.SequenceFileInputFormat
                output format: org.apache.hadoop.hive.ql.io.HiveSequenceFileOutputFormat
                serde: org.apache.hadoop.hive.serde2.lazy.LazySimpleSerDe

  Stage: Stage-0
    Fetch Operator
      limit: -1
      Processor Tree:
        ListSink

Time taken: 1.42 seconds, Fetched: 49 row(s)

因为 group by 有 shuffle 操作会被拆成两个stage

2） 查看详细执行计划（一般不用）

hive (test1)> explain extended select * from bigtable;
hive (test1)> explain extended select click_url, count(*) ct from bigtable group by click_url;

第 2 章 Hive 建表优化

2.1 分区表

分区表实际上就是对应一个 HDFS 文件系统上的独立的文件夹，该文件夹下是该分区所有的数据文件。
Hive 中的分区就是分目录，把一个大的数据集根据业务需要分割成小的数据集。
在查询时通过 WHERE 子句中的表达式选择查询所需要的指定的分区，这样的查询效率会提高很多，所以我们需要把常常用在 WHERE 语句中的字段指定为表的分区字段。

2.1.1 分区表基本操作

1） 引入分区表（需要根据日期对日志进行管理, 通过部门信息模拟）
dept_20200401.log
dept_20200402.log
dept_20200403.log

2） 创建分区表语法

hive (test1)> create table dept_partition( deptno int, dname string, loc string
)
partitioned by (day string)
row format delimited fields terminated by '\t';

注意：分区字段不能是表中已经存在的数据，可以将分区字段看作表的伪列。
3） 加载数据到分区表中

（1） 数据准备

dept_20200401.log

10 ACCOUNTING 1700
20 RESEARCH	1800

dept_20200402.log

30 SALES	1900
40 OPERATIONS 1700

dept_20200403.log

60 DEV 1900

（2） 加载数据

hive (test1)> load data local inpath '/opt/module/data/dept_20200401.log' into table dept_partition 
partition(day='20200401');

hive (test1)> load data local inpath '/opt/module/data/dept_20200402.log' into table dept_partition 
partition(day='20200402');

hive (test1)> load data local inpath '/opt/module/data/dept_20200403.log' into table dept_partition 
partition(day='20200403');

4）查询分区表中数据
单分区查询

hive (test1)> select * from dept_partition where day='20200401';

多分区联合查询

hive (test1)> select * from dept_partition where day='20200401' union
select * from dept_partition where day='20200402' union
select * from dept_partition where day='20200403';

走mr，任务被拆分多个stage

hive (test1)> select * from dept_partition where day='20200401' or day='20200402' or day='20200403';

不走mr
5）增加分区
增加单个分区

hive (test1)> alter table dept_partition add partition(day='20200404');

同时增加多个分区

hive (test1)> alter table dept_partition add partition(day='20200405') partition(day='20200406');

6）删除分区
删除单个分区

hive (test1)> alter table dept_partition drop partition (day='20200406');

同时删除多个分区

hive (test1)> alter table dept_partition drop partition (day='20200404'), partition(day='20200405');

7）查看分区表有多少分区

hive (test1)> show partitions dept_partition;
OK
partition
day=20200401
day=20200402
day=20200405
day=20200406
Time taken: 0.062 seconds, Fetched: 4 row(s)

8）查看分区表结构

hive (test1)> desc formatted dept_partition;

思考: 如果一天的日志数据量也很大，如何再将数据拆分?

2.1.2 二级分区

1）创建二级分区表

hive (test1)> create table dept_partition2(deptno int, dname string, loc string) partitioned by (day string, hour string) row format delimited fields terminated by '\t';

2）正常的加载数据
（1）加载数据到二级分区表中

hive (test1)> load data local inpath '/opt/module/data/dept_20200401.log' into table dept_partition2 partition(day='20200401', hour='12');

（2）查询分区数据

hive (test1)> select * from dept_partition2 where day='20200401' and hour='12';

2.1.3 动态分区

关系型数据库中，对分区表 Insert 数据时候，数据库自动会根据分区字段的值，将数据插入到相应的分区中，Hive 中也提供了类似的机制，即动态分区(Dynamic Partition)，只不过，使用 Hive 的动态分区，需要进行相应的配置。
1）开启动态分区参数设置
（1）开启动态分区功能（默认 true，开启）

set hive.exec.dynamic.partition=true;

（2）设置为非严格模式（动态分区的模式，默认 strict，表示必须指定至少一个分区为静态分区，nonstrict 模式表示允许所有的分区字段都可以使用动态分区。）

set hive.exec.dynamic.partition.mode=nonstrict;

（3）在所有执行 MR 的节点上，最大一共可以创建多少个动态分区。默认 1000

set hive.exec.max.dynamic.partitions=1000;

（4）在每个执行 MR 的节点上，最大可以创建多少个动态分区。
该参数需要根据实际的数据来设定。比如：源数据中包含了一年的数据，即 day 字段有365 个值，那么该参数就需要设置成大于 365，如果使用默认值 100，则会报错。

set hive.exec.max.dynamic.partitions.pernode=100

（5）整个 MR Job 中，最大可以创建多少个 HDFS 文件。默认 100000

set hive.exec.max.created.files=100000

（6）当有空分区生成时，是否抛出异常。一般不需要设置。默认 false

set hive.error.on.empty.partition=false

2）案例实操
需求：将 dept 表中的数据按照地区（loc 字段），插入到目标表 dept_partition 的相应分区中。
（1）创建目标分区表

hive (test1)> create table dept_partition_dy(id int, name string) partitioned by (loc int) row format delimited fields terminated by '\t';

（2）设置动态分区

hive (test1)> set hive.exec.dynamic.partition.mode = nonstrict;
hive (test1)> insert into table dept_partition_dy partition(loc) select deptno, dname, loc from dept;

（3）查看目标分区表的分区情况

2.2 分桶表

分区提供一个隔离数据和优化查询的便利方式。不过，并非所有的数据集都可形成合理的分区。对于一张表或者分区，Hive 可以进一步组织成桶，也就是更为细粒度的数据范围划分。
分桶是将数据集分解成更容易管理的若干部分的另一个技术。分区针对的是数据的存储路径，分桶针对的是数据文件。
2.2.1 创建分桶表
（1）数据准备
1001 ss1
1002 ss2
1003 ss3
1004 ss4
1005 ss5
1006 ss6
1007 ss7
1008 ss8
1009 ss9
1010 ss10
1011 ss11
1012 ss12
1013 ss13
1014 ss14
1015 ss15
1016 ss16
（2） 创建分桶表

hive (test1)> create table stu_buck(id int, name string) clustered by(id) into 4 buckets row format delimited fields terminated by '\t';

（3）查看表结构

hive (test1)> desc formatted stu_buck;
Num Buckets: 4

（4）导入数据到分桶表中，load 的方式

hive (test1)> load data inpath '/student.txt' into table stu_buck;

（5）查看创建的分桶表中是否分成 4 个桶

（6）查询分桶的数据

hive(test1)> select * from stu_buck;

（7）分桶规则：
根据结果可知：Hive 的分桶采用对分桶字段的值进行哈希，然后除以桶的个数求余的方式决定该条记录存放在哪个桶当中
1）分桶表操作需要注意的事项:
（1）reduce 的个数设置为-1，让 Job 自行决定需要用多少个 reduce 或者将 reduce 的个数设置为大于等于分桶表的桶数
（2）从 hdfs 中 load 数据到分桶表中，避免本地文件找不到问题
（3）不要使用本地模式
2）insert 方式将数据导入分桶表

hive(test1)>insert into table stu_buck select * from student_insert;

2.2.2 抽样查询

对于非常大的数据集，有时用户需要使用的是一个具有代表性的查询结果而不是全部结果。Hive 可以通过对表进行抽样来满足这个需求。
语法: TABLESAMPLE(BUCKET x OUT OF y)
查询表 stu_buck 中的数据。

hive (test1)> select * from stu_buck tablesample(bucket 1 out of 4 on id);

注意：x 的值必须小于等于 y 的值，否则
FAILED: SemanticException [Error 10061]: Numerator should not be bigger than denominator in sample clause for table stu_buck

2.3 合适的文件格式

Hive 支持的存储数据的格式主要有：TEXTFILE 、SEQUENCEFILE、ORC、PARQUET。

2.3.1 列式存储和行式存储

如图所示左边为逻辑表，右边第一个为行式存储，第二个为列式存储。
1）行存储的特点
查询满足条件的一整行数据的时候，列存储则需要去每个聚集的字段找到对应的每个列的值，行存储只需要找到其中一个值，其余的值都在相邻地方，所以此时行存储查询的速度更快。
2）列存储的特点
因为每个字段的数据聚集存储，在查询只需要少数几个字段的时候，能大大减少读取的数据量；每个字段的数据类型一定是相同的，列式存储可以针对性的设计更好的设计压缩算法。
TEXTFILE 和 SEQUENCEFILE 的存储格式都是基于行存储的；
ORC 和 PARQUET 是基于列式存储的。

2.3.2 TextFile 格式

默认格式，数据不做压缩，磁盘开销大，数据解析开销大。可结合 Gzip、Bzip2 使用，但使用 Gzip 这种方式，hive 不会对数据进行切分，从而无法对数据进行并行操作。

2.3.3 Orc 格式

Orc (Optimized Row Columnar)是 Hive 0.11 版里引入的新的存储格式。

2.3.4 Parquet 格式

Parquet 文件是以二进制方式存储的，所以是不可以直接读取的，文件中包括该文件的数据和元数据，因此 Parquet 格式文件是自解析的。

2.4 合适的压缩格式

为了支持多种压缩/解压缩算法，Hadoop 引入了编码/解码器，如下表所示。

压缩性能的比较

第 3 章 HQL 语法优化

3.1 列裁剪与分区裁剪

列裁剪就是在查询时只读取需要的列，分区裁剪就是只读取需要的分区。当列很多或者数据量很大时，如果 select * 或者不指定分区，全列扫描和全表扫描效率都很低。
Hive 在读数据的时候，可以只读取查询中所需要用到的列，而忽略其他的列。这样做可以节省读取开销：中间表存储开销和数据整合开销。

3.2 Group By

默认情况下，Map 阶段同一 Key 数据分发给一个 Reduce，当一个 key 数据过大时就倾斜了。
并不是所有的聚合操作都需要在 Reduce 端完成，很多聚合操作都可以先在 Map 端进行部分聚合，最后在Reduce 端得出最终结果。
开启 Map 端聚合参数设置
（1） 是否在 Map 端进行聚合，默认为True

set hive.map.aggr = true;

（2）在 Map 端进行聚合操作的条目数目

set hive.groupby.mapaggr.checkinterval = 100000;

（3）有数据倾斜的时候进行负载均衡（默认是 false）

set hive.groupby.skewindata = true;

当选项设定为 true，生成的查询计划会有两个 MR Job。
第一个 MR Job 中，Map 的输出结果会随机分布到 Reduce 中，每个 Reduce 做部分聚合操作，并输出结果，这样处理的结果是相同的 Group By Key 有可能被分发到不同的 Reduce中，从而达到负载均衡的目的；
第二个 MR Job 再根据预处理的数据结果按照Group By Key 分布到 Reduce 中（这个过程可以保证相同的Group By Key 被分布到同一个Reduce 中），最后完成最终的聚合操作（虽然能解决数据倾斜，但是不能让运行速度的更快）。

3.3 Vectorization

vectorization : 矢量计算的技术，在计算类似scan, filter, aggregation 的时候，vectorization技术以设置批处理的增量大小为 1024 行单次来达到比单条记录单次获得更高的效率。