【qt】pro/pri文件添加cuda相关环境onnxruntime、opencv490、cudnn

单独opencv490

# 定义基础路径
OPENCV490_PATH = F:/sdk/sdk_cuda12.3/opencv490_cpu/
#OPENCV490_PATH = $$PWD/sdk/opencv490/
# include路径
INCLUDEPATH += $$OPENCV490_PATH/include
OPENCV490_BIN_PATH = $$OPENCV490_PATH/bin/

CONFIG(release, debug|release) {
    LIBS += -L$$OPENCV490_PATH/lib/ -lopencv_world490
    opencv490.files += $$OPENCV490_BIN_PATH/opencv_world490.dll
    opencv490.path += $$OUT_PWD/Release
}else {
    LIBS += -L$$OPENCV490_PATH/lib/ -lopencv_world490d
    opencv490.files += $$OPENCV490_BIN_PATH/opencv_world490d.dll
    opencv490.path += $$OUT_PWD/Debug
}

COPIES += opencv490

单独onnxruntime

# 定义基础路径
ONNXRUNTIME_PATH = F:/sdk/sdk_cuda12.3/onnxruntime-x64-cuda-1.17.0/
#ONNXRUNTIME_PATH = $$PWD/sdk/onnxruntime-x64-cuda-1.17.0/
# include路径
INCLUDEPATH += $$ONNXRUNTIME_PATH/include
# bin路径,onnxruntime的dll也可能在lib文件夹里
ONNXRUNTIME_BIN_PATH = $$ONNXRUNTIME_PATH/bin/

LIBS += -L$$ONNXRUNTIME_PATH/lib/ -lonnxruntime \
        -L$$ONNXRUNTIME_PATH/lib/ -lonnxruntime_providers_cuda \
        -L$$ONNXRUNTIME_PATH/lib/ -lonnxruntime_providers_shared

onnxruntime.files += \
    $$ONNXRUNTIME_BIN_PATH/onnxruntime.dll \
    $$ONNXRUNTIME_BIN_PATH/onnxruntime_providers_cuda.dll \
    $$ONNXRUNTIME_BIN_PATH/onnxruntime_providers_shared.dll

CONFIG(release, debug|release) {
    onnxruntime.path += $$OUT_PWD/Release
}else {
    onnxruntime.path += $$OUT_PWD/Debug
}

COPIES += onnxruntime

常用版本——模型、opencv、onnxruntime、cuda

models.files += $$PWD/weights
CONFIG(release, debug|release) {
    models.path += $$OUT_PWD/Release
}else {
    models.path += $$OUT_PWD/Debug
}
COPIES += models

# 定义基础路径
ONNXRUNTIME_PATH = F:/sdk/sdk_cuda12.3/onnxruntime-x64-cuda-1.17.0/
OPENCV490_PATH = F:/sdk/sdk_cuda12.3/opencv490/

#ONNXRUNTIME_PATH = $$PWD/sdk/onnxruntime-x64-cuda-1.17.0/
#OPENCV490_PATH = $$PWD/sdk/opencv490/
# include路径
INCLUDEPATH += $$ONNXRUNTIME_PATH/include
INCLUDEPATH += $$OPENCV490_PATH/include
# bin路径,onnxruntime的dll也可能在lib文件夹里
ONNXRUNTIME_BIN_PATH = $$ONNXRUNTIME_PATH/bin/
OPENCV490_BIN_PATH = $$OPENCV490_PATH/bin/

CONFIG(release, debug|release) {
    LIBS += -L$$OPENCV490_PATH/lib/ -lopencv_world490
}else {
    LIBS += -L$$OPENCV490_PATH/lib/ -lopencv_world490d
}
LIBS += -L$$ONNXRUNTIME_PATH/lib/ -lonnxruntime \
        -L$$ONNXRUNTIME_PATH/lib/ -lonnxruntime_providers_cuda \
        -L$$ONNXRUNTIME_PATH/lib/ -lonnxruntime_providers_shared

# 添加文件到 files 变量
CONFIG(release, debug|release) {
    opencv490.files += $$OPENCV490_BIN_PATH/opencv_world490.dll
}else {
    opencv490.files += $$OPENCV490_BIN_PATH/opencv_world490d.dll
}
onnxruntime.files += \
    $$ONNXRUNTIME_BIN_PATH/onnxruntime.dll \
    $$ONNXRUNTIME_BIN_PATH/onnxruntime_providers_cuda.dll \
    $$ONNXRUNTIME_BIN_PATH/onnxruntime_providers_shared.dll

CONFIG(release, debug|release) {
    opencv490.path += $$OUT_PWD/Release
    onnxruntime.path += $$OUT_PWD/Release
}else {
    opencv490.path += $$OUT_PWD/Debug
    onnxruntime.path += $$OUT_PWD/Debug
}

COPIES += opencv490
COPIES += onnxruntime


CUDNN_BIN_PATH = $$PWD/sdk/cuda12_3_cudnn/bin
CONFIG(release, debug|release) {
    cudnn.files += $$CUDNN_BIN_PATH/cublas64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/cublasLt64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/cudart64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/cudnn64_8.dll
    cudnn.files += $$CUDNN_BIN_PATH/cudnn_adv_infer64_8.dll
    cudnn.files += $$CUDNN_BIN_PATH/cudnn_adv_train64_8.dll
    cudnn.files += $$CUDNN_BIN_PATH/cudnn_cnn_infer64_8.dll
    cudnn.files += $$CUDNN_BIN_PATH/cudnn_cnn_train64_8.dll
    cudnn.files += $$CUDNN_BIN_PATH/cudnn_ops_infer64_8.dll
    cudnn.files += $$CUDNN_BIN_PATH/cudnn_ops_train64_8.dll
    cudnn.files += $$CUDNN_BIN_PATH/cufft64_11.dll
    cudnn.files += $$CUDNN_BIN_PATH/cufftw64_11.dll
    cudnn.files += $$CUDNN_BIN_PATH/cuinj64_123.dll
    cudnn.files += $$CUDNN_BIN_PATH/curand64_10.dll
    cudnn.files += $$CUDNN_BIN_PATH/cusolver64_11.dll
    cudnn.files += $$CUDNN_BIN_PATH/cusolverMg64_11.dll
    cudnn.files += $$CUDNN_BIN_PATH/cusparse64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nppc64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nppial64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nppicc64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nppidei64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nppif64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nppig64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nppim64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nppist64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nppisu64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nppitc64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/npps64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nvblas64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nvJitLink_120_0.dll
    cudnn.files += $$CUDNN_BIN_PATH/nvjpeg64_12.dll
    cudnn.files += $$CUDNN_BIN_PATH/nvrtc-builtins64_123.dll
    cudnn.files += $$CUDNN_BIN_PATH/nvrtc64_120_0.dll
    cudnn.files += $$CUDNN_BIN_PATH/zlibwapi.dll
}else {

}
CONFIG(release, debug|release) {
    cudnn.path += $$OUT_PWD/Release
}else {
}
COPIES += cudnn

OPENCV_PATH = $$PWD/OpenCV_4.6.0/x64/mingw
LIBS += $$OPENCV_PATH/lib/libopencv_*.a

opencv460.files += $$OPENCV_PATH/bin/libopencv_*.dll
model.files += $$PWD/yaming_model.onnx

CONFIG(release, debug|release) {
    opencv460.path += $$OUT_PWD/Release
    model.path += $$OUT_PWD/Release/
}else {
    opencv460.path += $$OUT_PWD/Debug
    model.path += $$OUT_PWD/Debug
}
COPIES += opencv460
COPIES += model