提示:文章写完后,目录可以自动生成,如何生成可参考右边的帮助文档
目录
提示:以下是本篇文章正文内容,下面案例可供参考
一、nginx安装
1、下载
(1)下载地址
(2)系统选择
1)中“1”为Linux资源,
2)“2”为window资源
(3)版本选择
1)Mainline version 主流版
2)Stable version 稳定版
3)Legacy versions 历史版本
2、安装部署
(1)解压
1)将下载的压缩包解压到指定文件夹
2)文件说明
文件夹 | 说明 |
conf | nginx所有的配置文件的目录 |
contrib | 存放开源爱好者共享的代码 |
docs | 存放文档资料 |
html | 默认站点目录,存放了Nginx的错误页面和欢迎页面 |
logs | 默认存放访问日志、错误日志和Nginx主进程pid文件 |
temp | 临时目录,用于存放Nginx运行时产生的临时文件 |
nginx.exe | 可执行程序,常用于Nginx服务的启动、停止等管理工作 |
(2)配置文件修改
1)在conf目录下找到nginx.conf文件,打开
2)找到server这个节点,视需要修改端口号或默认主页
3)检查修改是否正确
nginx -t -xxxxxx/nginx.conf // xxxx为nginx.conf所在的绝对路径
4)重启
如果nginx没有启动,则执行启动操作,如果已经启动,执行重启命令
nginx -s reload // 重启
(3)启动
1)双击nginx.exe(不推荐)
因为直接双击nginx.exe,会导致修改配置后重启、停止nginx无效,需要手动关闭任务管理器内的所有nginx进程。
2)cmd命令启动(推荐)
① 运行cmd打开终端
② 切换磁盘
输入“D:”回车
③ 进入上面解压的文件夹
cd xxxxx // 目标文件夹路径
或者直接在解压文件夹中右键 => 在终端中打开,直接进入此路径
④ 启动——执行命令后会有窗口一闪而过
start nginx
⑤ 检查是否启动成功
通过命令确认:
tasklist /fi "imagename eq nginx.exe"
通过任务管理器确认:
通过命令启动nginx时,其进程在详细信息中展现,通过双击nginx.exe启动的进程才在进程栏中展现。
⑥ 访问端口
打开浏览器,访问http://localhost:80或127.0.0.1:80,页面出现以下内容
(4)nginx脚本创建
上面已经阐述了为什么要使用cmd命令来管理nginx,但如果需要经常使用的话就比较麻烦了,所以就需要一个脚本来提升我们的管理效率。
1)创建txt文档;
2)脚本代码
@echo off
rem 提供Windows下nginx的启动,重启,关闭功能
echo ==================begin========================
cls
::ngxin 所在的盘符
set NGINX_PATH=E:
::nginx 所在目录
set NGINX_DIR=E:\develop\nginx-1.10.1\
color 0a
TITLE Nginx 管理程序增强版
CLS
echo.
echo. ** Nginx 管理程序 ***
echo. *** create 2017-09-22 ***
echo.
:MENU
echo. ***** nginx 进程list ******
::tasklist|findstr /i "nginx.exe"
tasklist /fi "imagename eq nginx.exe"
echo.
if ERRORLEVEL 1 (
echo nginx.exe不存在
) else (
echo nginx.exe存在
)
echo.
::*************************************************************************************************************
echo.
echo. [1] 启动Nginx
echo. [2] 关闭Nginx
echo. [3] 重启Nginx
echo. [4] 刷新控制台
echo. [5] 重新加载Nginx配置文件
echo. [6] 检查测试nginx配置文件
echo. [7] 查看nginx version
echo. [0] 退 出
echo.
echo.请输入选择的序号:
set /p ID=
IF "%id%"=="1" GOTO start
IF "%id%"=="2" GOTO stop
IF "%id%"=="3" GOTO restart
IF "%id%"=="4" GOTO MENU
IF "%id%"=="5" GOTO reloadConf
IF "%id%"=="6" GOTO checkConf
IF "%id%"=="7" GOTO showVersion
IF "%id%"=="0" EXIT
PAUSE
::*************************************************************************************************************
::启动
:start
call :startNginx
GOTO MENU
::停止
:stop
call :shutdownNginx
GOTO MENU
::重启
:restart
call :shutdownNginx
call :startNginx
GOTO MENU
::检查测试配置文件
:checkConf
call :checkConfNginx
GOTO MENU
::重新加载Nginx配置文件
:reloadConf
call :checkConfNginx
call :reloadConfNginx
GOTO MENU
::显示nginx版本
:showVersion
call :showVersionNginx
GOTO MENU
::*************************************************************************************
::底层
::*************************************************************************************
:shutdownNginx
echo.
echo.关闭Nginx......
taskkill /F /IM nginx.exe > nul
echo.OK,关闭所有nginx 进程
goto :eof
:startNginx
echo.
echo.启动Nginx......
IF NOT EXIST "%NGINX_DIR%nginx.exe" (
echo "%NGINX_DIR%nginx.exe"不存在
goto :eof
)
%NGINX_PATH%
cd "%NGINX_DIR%"
IF EXIST "%NGINX_DIR%nginx.exe" (
echo "start '' nginx.exe"
start "" nginx.exe
)
echo.OK
goto :eof
:checkConfNginx
echo.
echo.检查测试 nginx 配置文件......
IF NOT EXIST "%NGINX_DIR%nginx.exe" (
echo "%NGINX_DIR%nginx.exe"不存在
goto :eof
)
%NGINX_PATH%
cd "%NGINX_DIR%"
nginx -t -c conf/nginx.conf
goto :eof
::重新加载 nginx 配置文件
:reloadConfNginx
echo.
echo.重新加载 nginx 配置文件......
IF NOT EXIST "%NGINX_DIR%nginx.exe" (
echo "%NGINX_DIR%nginx.exe"不存在
goto :eof
)
%NGINX_PATH%
cd "%NGINX_DIR%"
nginx -s reload
goto :eof
::显示nginx版本
:showVersionNginx
echo.
%NGINX_PATH%
cd "%NGINX_DIR%"
nginx -V
goto :eof
注意
① 文件名保存为.bat类型
② 编码格式建议选择ANSI,防止中文乱码
③ 另存地址与nginx.exe同级
4)双击执行
① 1处为双击后打开窗口的显示内容
② 2处为需要执行的命令的序号,如需要启动,就输入1然后回车
5)快捷方式
因为脚本文件时保存在nginx文件夹下,每次需要使用的时候都需要先进入nginx文件夹,比较麻烦,所以直接创建快捷方式放在桌面。
① 右键脚本选择“创建快捷方式”
② 将快捷方式剪切到桌面上。如果觉得这个快捷方式难看,就继续往下看
③ 右键快捷方式选择属性
④ 点击更改图标,可以使用系统内置的图标,也可以使用自定义图标
⑤ 自定义图标
图标格式要求为.icon、.dll、.icl格式,准备好图标之后选择应用即可,可以先用png等格式的图片进行转换
二、使用
1、其他命令
// 结束进程
nginx -s stop // 快速结束
nginx -s quit // 完整有序的结束
// 重新加载
nginx -s reload