Windows系统调用学习笔记（三）—— 保存现场

最新推荐文章于 2024-08-09 19:45:54 发布
最新推荐文章于 2024-08-09 19:45:54 发布
阅读量2.2k 收藏 11
点赞数 2
分类专栏： x86内核 文章标签： Windows 系统调用 保存现场
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_41988448/article/details/102886413
版权

Windows系统调用学习笔记（三）—— 保存现场

要点回顾

API进入0环后调用的函数：

  1. 中断门 – KiSystemService
  2. 快速调用 – KiFastCallEntry

上一篇留了几个练习：

  1. 进0环后，原来的寄存器存在哪里？
  2. 如何根据系统服务号(eax中存储)找到要执行的内核函数？
  3. 调用时参数是存储到3环的堆栈，如何传递给内核函数？
  4. 2种调用方式是如何返回到3环的？

本篇将对第一个练习进行说明

基本概念

Trap Frame 结构

描述：

  1. 无论是通过中断门进入0环，还是通过快速调用进入0环，进入0环前（3环）的所有寄存器都会存到这个结构体中
  2. 这个结构体本身处于0环，由windows操作系统进行维护
  3. 当程序通过中断门从3环进入0环时，ESP指向TrapFrame+0x64的位置
  4. 当程序通过快速调用从3环进入0环时，ESP指向TrapFrame+0x78的位置

结构体：
Trap_Frame
在WinDbg中查看：

kd> dt _Ktrap_frame

注意：
5. 在保护模式下，最后四个成员（0x7C~0x88）并没有被使用，因此无需考虑；只有在虚拟8086模式下，才会用到
6. 当中断门执行时，3环的SS、ESP、EFLAGS、CS、EIP会被存储到结构体的0x68~0x78中，而执行快速调用时不会

线程相关的结构体

ETHREAD

结构体：
ETHREAD

KTHREAD

结构体：

kd> dt _KTHREAD

CPU相关的结构体

KPCR

描述：

  1. 全称为CPU控制区（Processor Control Region）
  2. 每一个CPU都有一个CPU控制区，一核一个KPCR

结构体：
KPCR
查看CPU数量：

kd>dd KeNumBerProcessors

查看KPCR：

kd>dd KiProcessorBlock L2
ffdff120 00000000
若第二个成员有值，说明当前CPU有两个核

_NT_TIB

描述：
_NT_TIB是KPCR结构体的成员之一

结构体：
_NT_TIB

KPRCB

描述：
KPRCB是KPCR结构体的成员之一

结构体：

kd> dt _KPRCB

实验一：分析 KiSystemService

注意：当进入KiSystemService时，3环的SS、ESP、EFLAGS、CS、EIP就已经被存储到 Trap Frame 结构体中

IDA反汇编：

.text:004067D1                 push    0			; nt!_KTRAP_FRAME
													;    +0x064 ErrCode          : Uint4B
													; 中断门产生权限切换时一般往堆栈中压入5个值，但有些情况会压入6个值，第六个值为Error Code
													; 具体细节可以参考Intel白皮书第三卷，章节名：Input and Exception Handling
													; 其中有一小节叫做 Error Code
													;
													; 当通过 INT 2E 进入0环时，并没有压入Error Code
													; 操作系统为了对齐，自己补了个0
.text:004067D3                 push    ebp			; nt!_KTRAP_FRAME
													;    +0x060 Ebp              : Uint4B
.text:004067D4                 push    ebx			;    +0x05c Ebx              : Uint4B
.text:004067D5                 push    esi			; 	 +0x058 Esi              : Uint4B
.text:004067D6                 push    edi			; 	 +0x054 Edi              : Uint4B
.text:004067D7                 push    fs			; 	 +0x050 SegFs            : Uint4B
.text:004067D9                 mov     ebx, 30h		; 为FS寄存器赋值，指向KPCR结构体
.text:004067DE                 mov     fs, ebx		; 加载下标为6的段描述符到fs

在WinDbg中查看GDT表中下标为6的段描述符：
fs
段描述符：ffc093df`f0000001
fs.Base：0xffdff000（KPCR）

.text:004067E0                 push    large dword ptr fs:0			; 保存老的ExceptionList（异常列表）
																	; nt!_KPCR
																	;    +0x000 NtTib            : _NT_TIB
																	; nt!_NT_TIB
																	;    +0x000 ExceptionList    : Ptr32 _EXCEPTION_REGISTRATION_RECORD
																	;
																	; nt!_KTRAP_FRAME
																	;    +0x04c ExceptionList    : Ptr32 _EXCEPTION_REGISTRATION_RECORD
.text:004067E7                 mov     large dword ptr fs:0, 0FFFFFFFFh		; 新的ExceptionList为空白
.text:004067F2                 mov     esi, large fs:124h			; 得到当前正在执行的线程信息
																	; nt!_KPCR
																	;    +0x120 +0x4 CurrentThread    : Ptr32 _KTHREAD
																	; 存储了当前正在跑的线程的信息，为 KTHREAD 结构体

在WinDbg中查看 KPCR + 0x120 + 0x4：
KPCR
KPRCB

.text:004067F9                 push    dword ptr [esi+140h]			; 保存老的"先前模式"到堆栈
																	; nt!_KTHREAD
																	;    +0x140 PreviousMode     : Char
.text:004067FF                 sub     esp, 48h					; 执行前，ESP位于_KTRAP_FRAME + 0x48 = PreviousPreviousMode
																; 执行后，ESP 等于 _KTRAP_FRAME 结构指针
.text:00406802                 mov     ebx, [esp+68h+arg_0]		; arg_0 = 4
																; 取出三环压入的参数CS（_KTRAP_FRAME + 0x6C）
.text:00406806                 and     ebx, 1					; 权限检查：0环最低位为0，3环最低位为1
.text:00406809                 mov     [esi+140h], bl			; 新的"先前模式"
																; 将权限检查的结果存储到 PreviousMode 中
																; 目的是检测调用该代码前，程序处于几环
.text:0040680F                 mov     ebp, esp					; ebp = esp = _KTRAP_FRAME 结构指针
.text:00406811                 mov     ebx, [esi+134h]			; _KTHREAD 的成员 TrapFrame
.text:00406817                 mov     [ebp+3Ch], ebx			; 将 _KTHREAD 中的 TrapFrame 暂时存放在这个位置
																; 之后会将这个值重新取出来，赋值给 _KTHREAD 的 TrapFrame
.text:0040681A                 mov     [esi+134h], ebp			; 将堆栈中形成的 _KTRAP_FRAME 结构指针赋值给 _KTHREAD 的 TrapFrame
.text:00406820                 cld
.text:00406821                 mov     ebx, [ebp+60h]			; 将原来3环的ebp赋值给ebx
.text:00406824                 mov     edi, [ebp+68h]			; 将原来3环的eip赋值给edi

.text:00406827                 mov     [ebp+0Ch], edx			; edx存储的是3环参数的指针：
																;
																; _KiFasSystemCall函数：
																; 		mov edx, esp
																;		sysenter
																;
.text:0040682A                 mov     dword ptr [ebp+8], 0BADB0D00h		; 给操作系统用的标志
.text:00406831                 mov     [ebp+0], ebx				; 原来3环的ebp存储到 _KTRAP_FRAME
																; + 0x000 DbgEbp 的位置
.text:00406834                 mov     [ebp+4], edi				; 原来3环的eip存储到 _KTRAP_FRAME
																; + 0x004 DbgEbp 的位置
.text:00406837                 test    byte ptr [esi+2Ch], 0FFh	; 判断 _KTHREAD + 0x02c DebugActive 是否为 -1
																; 若为 -1， 即当前线程 未 处于调试状态
.text:0040683B                 jnz     Dr_kss_a					; 若处于调试状态，则跳转
																; 功能是对TrapFrame的Dr0~Dr7进行赋值
																; 也就是TrapFrame+0x18 ~ TrapFrame+0x2c的位置进行赋值
																; 若未处于调试状态，则继续向下执行（loc_406841）

在WinDbg中查看KTHREAD + 0x02c：
KTHREAD

.text:00406841                 sti								; 关闭中断
.text:00406842                 jmp     loc_406932				; KiSystemService 与 KiFastCallEntry 函数的共同代码片段
																; 下篇学习系统服务表时再进行分析

实验二：分析 KiFastCallEntry

IDA反汇编：

.text:0040689F                 mov     ecx, 23h						; ECX = 0x23
.text:004068A4                 push    30h							; 通过堆栈的入栈和出栈加载fs
.text:004068A6                 pop     fs							; 加载fs段寄存器：GDT表下标为6的段描述符

在WinDbg中查看GDT表下标为6的段描述符：
fs
段描述符：ffc093df`f0000001
fs.Base：0xffdff000（KPCR）

.text:004068A8                 mov     ds, ecx						; RPL=3；TI=0；INDEX=4
																	; 加载GDT表下标为4的段描述符给ds
.text:004068AA                 mov     es, ecx						; 加载GDT表下标为4的段描述符给es

在WinDbg中查看GDT表下标为4的段描述符：
ds

.text:004068AC                 mov     ecx, large fs:40h			; ECX = TSS指针
																	; nt!_KPCR
																	;    +0x040 TSS              : Ptr32 _KTSS
.text:004068B3                 mov     esp, [ecx+4]					; nt!_KTSS
																	;    +0x004 Esp0             : Uint4B
.text:004068B6                 push    23h							; nt!_KTRAP_FRAME
																	;    +0x078 HardwareSegSs    : Uint4B
.text:004068B8                 push    edx							; edx保存的是3环参数的指针
																	; nt!_KTRAP_FRAME
																	;    +0x074 HardwareEsp      : Uint4B
.text:004068B9                 pushf								; 旧的标志寄存器入栈
.text:004068BA
.text:004068BA loc_4068BA:                             ; CODE XREF: _KiFastCallEntry2+23↑j
.text:004068BA                 push    2							; 新的标志寄存器的值入栈
.text:004068BC                 add     edx, 8
.text:004068BF                 popf									; 新的标志寄存器的值出栈

																	; EFlags =  2，即第二位置1，其它位清零
.text:004068C0                 or      [esp+0Ch+var_B], 2
.text:004068C5                 push    1Bh							; nt!_KTRAP_FRAME
																	;    +0x06c SegCs            : Uint4B
.text:004068C7                 push    dword ptr ds:0FFDF0304h		;    +0x068 Eip              : Uint4B
.text:004068CD                 push    0							;    +0x064 ErrCode          : Uint4B
.text:004068CF                 push    ebp							;    +0x060 Ebp              : Uint4B
.text:004068D0                 push    ebx							;    +0x05c Ebx              : Uint4B
.text:004068D1                 push    esi							;    +0x058 Esi              : Uint4B
.text:004068D2                 push    edi							;    +0x054 Edi              : Uint4B
.text:004068D3                 mov     ebx, large fs:1Ch			; nt!_KPCR
																	;    +0x01c SelfPcr          : Ptr32 _KPCR
																	; 指向当前 KPCR 结构体本身，目的是方便查找
.text:004068DA                 push    3Bh							; nt!_KTRAP_FRAME
																	;    +0x050 SegFs            : Uint4B
.text:004068DC                 mov     esi, [ebx+124h]				; nt!_KPCR
																	;    +0x120 +0x4 CurrentThread    : Ptr32 _KTHREAD
																	; 存储了当前正在跑的线程的信息，为 KTHREAD 结构体

.text:004068E2                 push    dword ptr [ebx]				; ebx 保存的是KPCR结构体的地址
																	; KPCR 第一个成员为结构体 NT_TIB 的指针
																	; NT_TIB 的第一个值为 ExceptionList（异常列表）
																	; 这句话的目的是将异常列表保存到TrapFrame结构体中
																	; nt!_KPCR
																	;    +0x000 NtTib            : _NT_TIB
																	; nt!_NT_TIB
																	;    +0x000 ExceptionList    : Ptr32 _EXCEPTION_REGISTRATION_RECORD
																	;
																	; nt!_KTRAP_FRAME
																	;    +0x04c ExceptionList    : Ptr32 _EXCEPTION_REGISTRATION_RECORD
.text:004068E4                 mov     dword ptr [ebx], 0FFFFFFFFh	; 将 ExceptionList（异常列表）置为 -1
.text:004068EA                 mov     ebp, [esi+18h]				; nt!_KTHREAD
																	;    +0x018 InitialStack     : Ptr32 Void
.text:004068ED                 push    1							; nt!_KTRAP_FRAME
																	;    +0x048 PreviousPreviousMode : Uint4B
																	; 往栈中压入老的先前模式，1表示先前模式为3环

.text:004068EF                 sub     esp, 48h						; 执行前，ESP位于_KTRAP_FRAME + 0x48 = PreviousPreviousMode
																	; 执行后，ESP 等于 _KTRAP_FRAME 结构指针
.text:004068F2                 sub     ebp, 29Ch
.text:004068F8                 mov     byte ptr [esi+140h], 1		; 新的先前模式
																	; nt!_KTHREAD
																	;     +0x140 PreviousMode     : Char
.text:004068FF                 cmp     ebp, esp						; 检查 ebp 是否等于 esp，也就是 _KTRAP_FRAME 结构指针
.text:00406901                 jnz     loc_40686C					; 若不等于，则跳转，进行异常处理
.text:00406907                 and     dword ptr [ebp+2Ch], 0		; 修改 TrapFrame 结构体中 Dr7 的值
																	; nt!_KTRAP_FRAME
																	;    +0x02c Dr7              : Uint4B
.text:0040690B                 test    byte ptr [esi+2Ch], 0FFh		; 检测当前进程是否处于调试状态
																	; nt!_KTHREAD
																	;    +0x02c DebugActive      : UChar
																	; 若不处于调试状态，则 DebugActive 的值为FF
.text:0040690F                 mov     [esi+134h], ebp				; 将 TrapFrame 结构指针写入当前线程信息中
																	; nt!_KTHREAD
																	;    +0x134 TrapFrame        : Ptr32 _KTRAP_FRAME
.text:00406915                 jnz     Dr_FastCallDrSave			; 若当前进程处于被调试状态，则跳转，为 Dr0 ~ Dr7 进行赋值
																	; 若当前进程不处于被调试状态，则继续向下执行

.text:0040691B
.text:0040691B loc_40691B:                             ; CODE XREF: Dr_FastCallDrSave+10↑j
.text:0040691B                                         ; Dr_FastCallDrSave+7C↑j
.text:0040691B                 mov     ebx, [ebp+60h]				; 从 TrapFrame 结构体中取出 Ebp 到 ebx 寄存器
.text:0040691E                 mov     edi, [ebp+68h]				; 从 TrapFrame 结构体中取出 Eip 到 edi 寄存器
.text:00406921                 mov     [ebp+0Ch], edx				; nt!_KTRAP_FRAME
																	;    +0x000 DbgEbp           : Uint4B
.text:00406924                 mov     dword ptr [ebp+8], 0BADB0D00h;    +0x008 DbgArgMark       : Uint4B
.text:0040692B                 mov     [ebp+0], ebx					;    +0x000 DbgEbp           : Uint4B
.text:0040692E                 mov     [ebp+4], edi					;    +0x004 DbgEip           : Uint4B
.text:00406931                 sti									; 关闭中断
.text:00406932
.text:00406932 loc_406932:                             ; CODE XREF: _KiBBTUnexpectedRange+18↑j
.text:00406932                                         ; _KiSystemService+71↑j
																	; KiSystemService 与 KiFastCallEntry 函数的共同代码部分
																	; 下篇学习系统服务表时再进行分析

总结

  1. 当程序通过中断门从3环进入0环时，ESP指向TrapFrame+0x64的位置
  2. 当程序通过快速调用从3环进入0环时，ESP指向TrapFrame+0x78的位置
  3. 若通过中断门进入0环，在KiSystemService函数开始执行时，3环的SS、ESP、EFLAGS、CS、EIP就已经被存储到 TrapFrame 结构体中了
  4. TrapFrame 结构体的其它成员通过 KiSystemService 和 KiFastCallEntry 进行赋值
  5. 不管是 KiSystemService 还是 KiFastCallEntry，最终都要执行一部分相同的代码，分为两个函数是因为进入0环时，堆栈里的值不一样，走同一条函数会出问题
lzyddf
关注
专栏目录
任务调度管理-保存现场和恢复现场
wangfengjuan0102的博客
04-07 2566
在FreeRTOS移植到ARM Cortex-A9,关于任务调度的模块，前面的文章中讲到了任务调度的原理，这里讲一下如何保存现场和恢复现场； 保存现场 保存上文信息汇编实现的函数为portSAVE_CONTEXT。在Arm Cortext-A9平台保护现场都通过system模式进行访问，因为system mode和usr mode看到的是一份寄存器内容，能反应usr模式下的运行状态，又不会影响其他特权模式；针对每个任务，在其创建的时候都会在栈内开辟一段固定大小的空间用来保存任务的上下文（包括CPU状态，运
Windows系统调用中的现场保存
songfei_dream的专栏
10-20 1350
Windows内核分析索引目录：https://www.cnblogs.com/onetrainee/p/11675224.html Windows系统调用中的现场保存 　　我们之前介绍过三环进零环的步骤，通过中断或者快速调用来实现。 　　但是我们是否考虑过CPU从三环进入零环时，其三环的寄存器该如何保存。 　　这一篇文件就来介绍其系统调用中的(三环)现场保存的问题。 一、几个重要的...
_KiSystemServiceRepeat函数在_KiSystemService 函数里面
最新发布
linux-0.11调试教程
08-09 841
_KiSystemServiceRepeat: _KiServiceExit2 是两个非常重要的符号。
（三）ARM 常用汇编指令(2)之ARM堆栈保护/恢复现场分析
songze_lee
04-10 5717
3.3 APCS(ARM Procedure Call standard)规则 a.寄存器的使用规则 r0-r3  用于函数的传参，使用之前不用保存他的值，别名a1-a4 r4-r11 用于保存函数内部的局部变量 别名 v1 -v8 使用之前保存他的值，使用之后恢复他的值， r11    特别的别名fp  r12    别名ip  r13    别名sp栈指针寄存器，不能用于其
FreeRTOS学习笔记——（1）ARM架构调用标准AAPCS、现场的保存与恢复
嵌入式小白之进阶之路的博客
05-04 1312
文章目录前言一、ARM架构调用标准AAPCS1、寄存器介绍2、寄存器使用规则二、现场的保存与恢复 一、ARM架构调用标准AAPCS 1、寄存器介绍 CPU中共有 17 个寄存器： 寄存器 备注 R0 - - -R3 4个寄存器用来传参 R4 - - -R11 8个寄存器保存局部变量 R12 内部调用暂时寄存器；别名： IP
线程
qq_43496435的博客
02-22 87
上图中一条实线就是一个线程 多线程的过程：当main()执行到say()或wait()，main启动一下say()或wait()就不管它们了，自己继续执行，接下来say()、wait()会和main()并发执行 引入线程的目的：进程切换时，要保存现场。如果保存整个进程信息很浪费时间，所以把一个进程拆分成多个线程，每次调度时只保存线程（又叫“轻量级进程“），速度变快。 ...
Linux学习笔记04——输入输出与文件系统
m0_52248951的博客
05-07 961
概述 本章学习目标： 了解文件系统层次结构和文件I/O库之间关系、应用场合、性能比较。 掌握使用系统级I/O函数进行文件I/O、文件元数据读取的基本编程方法，能根据应用需求进行I/O库选择。 掌握内核文件I/O数据结构的用途与文件打开过程，理解文件描述符含义、文件共享原理，以及I/O重定向原理。 掌握文件组织和文件物理结构，能进行优劣对比分析，理解提高文件搜索效率的基本方法。 4.1 文件系统层次结构 4.1.1 文件系统层次结构简介 文件管理系统的引入 一般来说，处理的数据信息和结果存
Linux学习笔记——CentOS
热门推荐
MCC
04-20 3万+
Linux1 介绍2 安装3 Linux 的目录结构4 远程操作工具5 1 介绍 Linux 是一个开源、免费的操作系统，具有很强的稳定性、安全性、以及处理多并发的能力，目前大多数企业级应用甚至是集群项目都部署运行在 Linux 操作系统上，很多软件公司考虑到开发成本都首选Linux，Linux 在中国软件公司得到了广泛的使用。 Linux 的主要发行版本有以下几种： Ubuntu（乌班图）、RedHat（红帽）、CentOS、Debain（蝶变）、Fedora、SuSE、OpenSUSE、红旗Li
WIndows内核学习笔记：分页机制——PAE分页模式
weixin_38526180的博客
07-21 3310
Chapter 4 Paging 4.1 分页模式和控制位 分页控制有关的寄存器 CR0 标志位：WP（bit 16）、PG（bit 31） CR4 标志位：PSE（bit 4）、PAE（bit 5）、PGE（bit 7）、PCIDE（bit 17）、SMEP（bit 20）、SMAP（bit 21）、PKE（bit 22）、CET（bit 23）、PKS（bit 24） IA32_EFER MSR 标志位：LEM（bit 8）、NXE（bit 11) EFLAGS 标志位：AC（
操作系统原理学习笔记（第一章——第七章）
weixin_44570415的博客
03-23 3436
目录第一章 操作系统概述1.1 操作系统概述为什么要有操作系统什么是操作系统计算机系统部件操作系统的目标操作系统的其他定义小结1.2 操作系统发展发展动力（需求推动发展）OS的发展和计算机硬件计数、体系结构的发展相关发展过程一、手工操作二、单道批处理系统1.3 多道批处理系统多道批程序对OS特点的要求60年代通道和中断技术的出现1.4 分时系统一、概念二、实现方式二、过程三、特点四、发展第一次作业...
操作系统学习笔记——第二章 进程管理 和 第三章 死锁
Alliswell_WP
04-18 382
在学习操作系统时总结了笔记，并分享出来，特别是蓝色和红色字体。有问题请及时联系博主：Alliswell_WP，转载请注明出处。 参考书：《操作系统》谌卫军等，清华大学出版社，2012年5月参考视频：清航全套计算机专业课视频 目录 第二章 进程管理 1.进程(Process) 2.线程(Thread) 3.进程间通信 4.经典的IPC问题 5.进程调度 第三章 死锁 第二章 进程管理(进程...
_KiFastCallEntry静态分析
qq_41490873的博客
06-13 203
.text:0040689F _KiFastCallEntry proc near ; DATA XREF: _KiTrap01+71o .text:0040689F ; KiLoadFastSyscallMachineSpecificRegisters(x)+24o .text:0040...
Trap Frame
weixin_33860737的博客
06-29 2540
Trap Frame是指中断、自陷、异常进入内核后，在堆栈上形成的一种数据结构。对于Windows操作系统，是 kd> dt nt!_KTRAP_FRAME +0x000 DbgEbp : Uint4B +0x004 DbgEip : Uint4B +0x008 DbgArgMark : Uint4B ...
中断和异常
u012138730的专栏
05-10 3152
最近在看内存方面的知识，打算写一系列的博客分享记录一下。 本文介绍任务管理器里各个内存项的含义以及用一个例子也解释独占性。 目录 内存项含义 1.工作集Working Set(内存)=内存（专用工作集）+ 内存（共享工作集） 2.提交大小 Comitted Memory 内存的独占性 内存项含义 打开任务管理--详细信息---右键选择列，选择下面这4个。 1....
系统调用
SUNE__学无止境
11-07 343
00
《重要》从用户模式切换到内核模式的完整过程分析
多媒体编程、网络编程、系统编程、网络安全编程、驱动编程
10-29 2415
Home > 《重要》从用户模式切换到内核模式的完整过程分析 《重要》从用户模式切换到内核模式的完整过程分析 AloneMonkey 2014年7月20日 0 Windows定义了两种访问模式：用户模式和内核模式。应用程序代码运行在用户模式下，操作系统代码运行在内核模式下。 内核模式对应处理器的最高权限级别。在内核模式下执行的代码可以访问所有资源并可以执行所有特权指令。
_KiSystemService
qq_40912408的博客
03-28 313
#分析 KiSystemService _KiSystemService proc near ; CODE XREF: ZwAcceptConnectPort(x,x,x,x,x,x)+Cp .text:83E54EFE ...
（转载）Gloomy对Windows内核的分析（介绍）
峥嵘岁月
01-31 5141
INTRO (写给NT研究者)=============================                                             Мы всего лишь момент во времени                                             Отблеск в глазах,                
JOS 系统调用的过程
fang92的专栏
09-14 2828
系统调用，是用户态进程转向内核态的一种安全机制，在保证了内核空间安全并且不被破坏的的前提下，让用户态程序可以实现一定的功能。 通过JOS系统，来看系统调用的具体过程。 系统调用，在语言层面来看，其实可以把系统调用看成是一种函数的调用。只是这种函数调用，不同于一般的用户态下的函数调用，用户态下，函数调用，只需要用栈来保存各种信息就可以了，因为调用前后，保存的信息的栈都是用户地址空间下的栈，所以只
评论 2
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值