《汇编语言》第3版 （王爽）第15章

第15章

---

检测点15.1
（1）.仔细分析一下上面的int9中断例程，看看是否可以精简一下？
其实在我们的int9中断例程中，模拟int指令调用原int9中断例程的程序段是可以精简的，因为在进入中断例程后，IF和TF都已经置0，没有必要再进行设置了。对于程序段：
pushf
pushf
pop ax
and ah，11111100b
push ax
popf
call dword ptr ds:[0]
可以精简为：
pushf
call dword ptr ds:[0]
两条指令。
（2）.仔细分析上面程序中的主程序，看看有什么潜在的问题？
在主程序中，如果在执行设置int9中断例程的段地址和偏移地址的指令之间发生了键盘中断，则CPU将转去一个错误的地址执行，将发生错误。
找出这样的程序段，改写它们，排除潜在的问题。
提示，注意sti和cli的用法。

cli ;将TI设置为0，禁止可屏蔽中断
mov word ptr es:[9*4],offset int9
mov es:[9*4+2],cs
sti ;将TI设置为1，开启可屏蔽中断

cli ;将TI设置为0，禁止可屏蔽中断	
push ds:[0]
pop es:[9*4]
push ds:[2]
pop es:[9*4+2]
sti ;将TI设置为1，开启可屏蔽中断

实验15 安装新的int9中断例程
安装一个新的int9中断例程，功能：在DOS下，按下”A”键后，除非不再松开，如果松开，就显示满屏幕的”A”，其他的键照常处理。
提示，按下一个键时产生的扫描码称为通码，松开一个键产生的扫描码称为断码。断码=通码+80h。

assume cs:code

stack segment
	db 128 dup(0)
stack ends

code segment
start:mov ax,stack
      mov ss,ax ;设置栈段
      mov sp,128 ;设置栈顶

      push cs ;cs入栈
      pop ds  ;出栈到ds

      mov ax,0
      mov es,ax ;es指向0

      ;安装中断处理程序
      mov si,offset int9  ;设置di:si指向源地址
      mov di,204h   ;设置es:di指向目的地址
      mov cx,offset int9end-offset int9  ;设置cx为传输长度
      cld  ;设置传输方向为正
      rep movsb

      push es:[9*4]
      pop es:[200h] ;将原来的中断处理程序入口地址保存到200h
      push es:[9*4+2] 
      pop es:[202h]

      cli
      mov word ptr es:[9*4],204h ;将新的中断处理程序入口地址放入中断向量表
      mov word ptr es:[9*4+2],0
      sti

      mov ax,4c00h
      int 21h

  int9:push ax  ;寄存器内容入栈
       push bx
       push cx
       push es

   wat:in al,60h 
       
       pushf  ;标志寄存器入栈
       call dword ptr cs:[200h]

       cmp al,03bh  ;通码
       je wat

       cmp al,0bbh  ;断码
       jne int9ret
   
       mov ax,0b800h
       mov es,ax  ;es指向显存空间
       mov bx,0
       mov cx,2000 ;一页屏幕2000字符
     s:mov byte ptr es:[bx],'A' ;将’A’写入显存空间
       add bx,2 ;bx+2指向下一个显存空间
       loop s

   int9ret:pop es
           pop cx
	   pop bx
	   pop ax
	   iret
   int9end:nop

code ends
end start

在DOS中运行该程序，按下F1松开后效果如下：