rt_hw_context_switch_to 函数分析

此功能用于执行第一个线程切换

;/*
; * void rt_hw_context_switch_to(rt_uint32 to);
; * r0 --> to
; * this fucntion is used to perform the first thread switch
; */
rt_hw_context_switch_to    PROC
    EXPORT rt_hw_context_switch_to
    ; set to thread
    LDR     r1, =rt_interrupt_to_thread
    STR     r0, [r1]

    IF      {FPU} != "SoftVFP"
    ; CLEAR CONTROL.FPCA
    MRS     r2, CONTROL             ; read
    BIC     r2, #0x04               ; modify
    MSR     CONTROL, r2             ; write-back
    ENDIF

    ; set from thread to 0
    LDR     r1, =rt_interrupt_from_thread
    MOV     r0, #0x0
    STR     r0, [r1]

    ; set interrupt flag to 1
    LDR     r1, =rt_thread_switch_interrupt_flag
    MOV     r0, #1
    STR     r0, [r1]

    ; set the PendSV and SysTick exception priority
    LDR     r0, =NVIC_SYSPRI2
    LDR     r1, =NVIC_PENDSV_PRI
    LDR.W   r2, [r0,#0x00]       ; read
    ORR     r1,r1,r2             ; modify
    STR     r1, [r0]             ; write-back

    ; trigger the PendSV exception (causes context switch)
    LDR     r0, =NVIC_INT_CTRL
    LDR     r1, =NVIC_PENDSVSET
    STR     r1, [r0]

    ; restore MSP
    LDR     r0, =SCB_VTOR
    LDR     r0, [r0]
    LDR     r0, [r0]
    MSR     msp, r0

    ; enable interrupts at processor level
    CPSIE   F
    CPSIE   I

    ; ensure PendSV exception taken place before subsequent operation
    DSB
    ISB

    ; never reach here!
    ENDP

	//switch to new thread
    rt_hw_context_switch_to((rt_ubase_t)&to_thread->sp);

（1）、将r0寄存器的值，传送到地址值为rt_interrupt_to_thread的内存中，也就是执行线程的堆栈指针。

    LDR     r1, =rt_interrupt_to_thread
    STR     r0, [r1]

（2）、条件判断，如果处理器支持浮点运算（FPU不是软件模拟的），则执行其中的指令块。

在这个情况下，通过指令序列清除了 CONTROL.FPCA 标志，可能用于关闭浮点运算的自动上下文保存。

    IF      {FPU} != "SoftVFP"
    ; CLEAR CONTROL.FPCA
    MRS     r2, CONTROL             ; read
    BIC     r2, #0x04               ; modify
    MSR     CONTROL, r2             ; write-back
    ENDIF

（3）将0，传送到地址值为rt_interrupt_from_thread的内存中

    ; set from thread to 0
    LDR     r1, =rt_interrupt_from_thread
    MOV     r0, #0x0
    STR     r0, [r1]

（4） 将1，传送到地址值为rt_thread_switch_interrupt_flag

    ; set interrupt flag to 1
    LDR     r1, =rt_thread_switch_interrupt_flag
    MOV     r0, #1
    STR     r0, [r1]

（5）将PendSV 和 SysTick的优先级设为256

    ; set the PendSV and SysTick exception priority
    LDR     r0, =NVIC_SYSPRI2
    LDR     r1, =NVIC_PENDSV_PRI
    LDR.W   r2, [r0,#0x00]       ; read
    ORR     r1,r1,r2             ; modify
    STR     r1, [r0]             ; write-back

NVIC_SYSPRI2    EQU     0xE000ED20               ; system priority register (2)
NVIC_PENDSV_PRI EQU     0xFFFF0000               ; PendSV and SysTick priority value (lowest)

（6）将PendSV中断置位。

    ; trigger the PendSV exception (causes context switch)
    LDR     r0, =NVIC_INT_CTRL
    LDR     r1, =NVIC_PENDSVSET
    STR     r1, [r0]

NVIC_INT_CTRL   EQU     0xE000ED04               ; interrupt control state register

NVIC_PENDSVSET  EQU     0x10000000               ; value to trigger PendSV exception

（7）在中断向量表中获取MSP的初始值并写入 MSR寄存器中

    ; restore MSP
    LDR     r0, =SCB_VTOR
    LDR     r0, [r0]
    LDR     r0, [r0]
    MSR     msp, r0

SCB_VTOR        EQU     0xE000ED08               ; Vector Table Offset Register

（8）开异常，开中断。

    ; enable interrupts at processor level
    CPSIE   F
    CPSIE   I

（9）确保后续操作之前，发生PendSV异常。

    ; ensure PendSV exception taken place before subsequent operation
    DSB
    ISB