【ANSYS命令流】加载与求解技术（四）：面载荷（节点）的施加 [重点]

面载荷的施加

ANSYS结构分析中的面载荷为压力，其标识符为PRES，相关命令如下表所示

线分布载荷和面分布荷载都成为压力，但是不同单元类型，其荷载单位不尽相同。

• 2D面单元
  无论面载荷施加在单元边还是边界线，其荷载单位都是力/面积
• 梁单元
  分布荷载单位为力/长度，单元端部荷载单位为力
• 3D实体单元
  面荷载单位为力/面积

节点面载荷

对节点群施加面载荷

可解决大面积局部加载问题，只需在划分网格时加以控制

SF,Nlist,Lab,VALUE,VALUE2

Nlist——节点群，可取ALL或元件名，也可为P（进入GUI方式拾取节点）
Lab——面载荷标识符，结构分析时为PRES
VALUE——面荷载或表格型面荷载的表格名称
VALUE2——复数输入时面荷载的第二个值

对单个节点不能使用该命令

由Nlist节点群能够确定多少个单元面就施加多少单元面（与几何面无关）
如3D体单元面的所有节点在Nlist表示的节点群中时才能施加该载荷，否则不予施加。
面载荷方向与单元面法向相同

对于2D单元，在单元外部边界上加载时，可仅选择外部边界上的节点群即可加载；
当节点群不在单元外部边界时，需单独选择包含这些节点的单元。
该特点对于单元周边施加相同面载荷是简单，但施加单元任意一边面载荷麻烦点

举个栗子

3D单元SF加载示例

finish
/clear
/prep7
et,1,95
blc4,,,10,10,20        ! 创建长方体
esize,,4				! 定义单元网格数目
vmesh,all      			! 划分网格
asel,s,loc,y,10			! 选择Y=10的几何面
nsla,s 					! 选择与面相关的节点，但不包含面边界节点
sf,all,pres,1000  		! 施加节点群压力载荷，仅4个单元面
asel,s,loc,z,20 		! 选择z=20的面
nsla,s,1 				! 选择与面相关所有节点
sf,all,pres,1000 		! 施加节点群压力荷载，显示所有单元面

再举个栗子

2d单元sf加载示例

finish
/clear
/prep7
! 定义单元，创建带孔面
et,1,82
blc4,,,100,200
blc4,30,60,40,80
asba,1,2
! 切分面，便于划分网格
wprota,,-90
wpoff,,,60
asbw,all
wpoff,,,80
asbw,all
wprota,,,90
wpoff,,,30
asbw,all
wpoff,,,40
asbw,all
wpcsys,-1
esize,5
amesh,all
/psf,pres,norm,2

sf,all,pres,100			! 对所由单元施加面载荷
sfdele,all,pres			! 删除上述面载荷
nsel,s,loc,x,0			! 选择x=0的节点群
sf,all,pres,100			! 对上述节点群施加面载荷
nsel,s,loc,x,15,20		! 选择X=15-20的节点
esln,s,1 				! 选择上述节点能确定的全部单元
nsel,r,loc,x,15 
sf,all,pres,110			! 对上述单元施加面荷载（内部单元的一边上）
nsel,s,loc,x,40,60		! 选择X=40-60的节点群
nsel,r,loc,y,10,30		! 从中选择y=10-30的节点
esln,s,1                ! 选择上述节点能确定的全部单元
sf,all,pres,100  		! 对上述单元施加面荷载（内部单元的一边上）
       
lsel,s,loc,x,100		! 选择X=100的线
nsll,s,1				! 选择与线相关的全部节点
esln,s					! 选择与节点相关的全部单元
nsel,s,loc,x,95			! 重新选择节点群（在上述单元范围内）
sf,all,pres,-100		! 对上述单元施加面荷载（内部单元的一边上）
allsel
eplot

定义节点号和面荷载的函数关系

SFFUN,Lab,Par,Par2

Lab——面荷载标识符，结构分析时为PRES
Par——储存面荷载值的参数名（数组参数）
Par2——用于复数输入时的第二个值

数组中的值的位置（数组下标）表示节点号，数组值表示面荷载的大小。

该命令所定义的函数关系，可用于SF和SFE命令。

举个栗子

finish
/clear
/prep7
et,1,45
blc4,,,10,10,20  		! 创建长方体
esize,5
vmesh,all
*dim,mypres,,100		! 定义数组MYPRES

*do,i,1,100
mypres(i)=i*10.0 		! 为数组赋值
*enddo

sffun,pres,mypres(i) 	! 定于节点号与面荷载函数关系
nsel,s,loc,y,10			! 选择节点群
sf,all,pres,10
sflist					! 面荷载列表（该面荷载节点上的值为10+I*10）
*do,i,1,100
mypres(i)=i*50.0
*enddo
nsel,s,loc,z,20
sf,all,pres,0
allsel
sflist

定义面荷载梯度

SFGRAD,Lab,SLKCN,Sldir,SLZER,SLOPE

定义的梯度仅在当前被激活，即如果定义了多个梯度，后面定义的将替代前面已定义的

特别注意：一但设定了荷载梯度，则对随后的荷载施加命令都有效。
无参数的SFGRAD命令，则取消此命令所有设置

命令SFGRAD,STAT可显示当前的状态。