《汇编语言》第8章——实验7

1.实验内容
实验内容为将 data 段中的数据按照表格的形式写入到 table 段中，并计算 21 年中的人均收入

assume cs:codesg,es:table,ss:stack
data segment 
	db '1975','1976','1977','1978','1979','1980','1981','1983','1983'
	db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
	db '1993','1994','1995'
	dd 16,22,382,1356,2390,8000,16000,24486,50064,97479,140417,197514
	dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
	dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
	dw 11542,14430,15257,17800
data ends
table segment 
	db 21 dup ('year summ ne ?? ')
table ends
stack segment
	db 8 dup (0)	
stack ends
codesg segment
start:
	mov ax,data
	mov ds,ax
	mov ax,table
	mov es,ax
	mov ax,stack
	mov ss,ax
	mov sp,16

	mov dx,0
	mov bx,0
	mov si,0
	mov di,0

	mov cx,21
s:	
	push cx
	;复制年份
	mov ax,ds:[di]
	mov es:[bx],ax
	mov ax,ds:[di+2]
	mov es:[bx+2],ax
	
	;复制雇员数
	mov ax,ds:[si+168]
	mov es:[bx+10],ax

	;复制收入
	mov ax,ds:[di+84]
	mov es:[bx+5],ax
	mov dx,ds:[di+86] ;存储高字节数据
	mov es:[bx+7],dx
	;计算平均收入
	;div word ptr es:[bx+10]
	mov cx,es:[bx+10]
	call divdw
	mov es:[bx+13],ax

	add si,2 	;控制雇员数
	add di,4 	;控制收入、年份
	add bx,16 	;控制结构体数组成员
	pop cx
	loop s

	mov ax,4c00h
	int 21h

;使用div时 做被除数 ax 低位 dx 高位,做结果时,ax 商 dx 余数 
;int(H/N)*65536 + [rem(H/N)*65536+L]/N
;参数：(ax)=dword型数据的低16位 (dx)=dword型数据的高16位 (cx)=除数
;返回：(dx)=结果的高16位 (ax)=结果的低16位 (cx)=余数
divdw:
	push bx
	push ax		;保存被除数低位 L
	mov ax,dx 	;把被除数高位H赋给ax  相当于先计算H/N
	mov dx,0	;dx 清零
	div cx		;H/N,结果 ax 商 ,dx 余数 
	mov bx,ax 	;保存商 bx = ax int(H/N)
	pop ax		;取出L 余数做高位rem(H/N)*65536存放在dx中，而上一步中的dx就是余数 低位ax=L
	div cx		;[rem(H/N)*65536+L]/N
	mov cx,dx	;保存余数结果
	mov dx,bx 	;结果高位商 ，ax低位商
	pop bx
	ret

codesg ends
end start