【bat脚本】将Sublime Text添加到右键菜单中

1.打开Sublime Text安装目录，新建txt文件，将后缀.txt改为.bat

2.输入以下代码

@ECHO OFF
PUSHD %~DP0
TITLE

>NUL 2>&1 REG.exe query "HKU\S-1-5-19" || (
    ECHO SET UAC = CreateObject^("Shell.Application"^) > "%TEMP%\Getadmin.vbs"
    ECHO UAC.ShellExecute "%~f0", "%1", "", "runas", 1 >> "%TEMP%\Getadmin.vbs"
    "%TEMP%\Getadmin.vbs"
    DEL /f /q "%TEMP%\Getadmin.vbs" 2>NUL
    Exit /b
)

ECHO input 'a' to add a right-click menu, input 'd' to delete the right-click menu:
REM 用户输入 'a' 或 'd'
SET /P ST=
if /I "%ST%"=="a" goto Add
if /I "%ST%"=="d" goto Delete

:Add
REM 添加文件右键菜单项
reg add "HKEY_CLASSES_ROOT\*\shell\Sublime Text" /t REG_SZ /v "" /d "Open with Sublime Text" /f
reg add "HKEY_CLASSES_ROOT\*\shell\Sublime Text" /t REG_EXPAND_SZ /v "Icon" /d "%~dp0sublime_text.exe" /f
reg add "HKEY_CLASSES_ROOT\*\shell\Sublime Text\command" /t REG_SZ /v "" /d "%~dp0sublime_text.exe \"%%1\"" /f

REM 添加文件夹右键菜单项
reg add "HKEY_CLASSES_ROOT\directory\shell\Sublime Text" /t REG_SZ /v "" /d "Open with Sublime Text" /f
reg add "HKEY_CLASSES_ROOT\directory\shell\Sublime Text" /t REG_EXPAND_SZ /v "Icon" /d "%~dp0sublime_text.exe" /f
reg add "HKEY_CLASSES_ROOT\directory\shell\Sublime Text\command" /t REG_SZ /v "" /d "%~dp0sublime_text.exe \"%%1\"" /f

exit

:Delete
REM 删除文件右键菜单项
reg delete "HKEY_CLASSES_ROOT\*\shell\Sublime Text" /f

REM 删除文件夹右键菜单项
reg delete "HKEY_CLASSES_ROOT\directory\shell\Sublime Text" /f

exit