【bat脚本】将VS Code添加到右键菜单中

之前发过一个添加Sublime Text的，其实方法一样

1.打开VS Code安装目录，新建txt文件，将后缀.txt改为.bat

2.输入以下代码

@ECHO OFF
PUSHD %~DP0
TITLE
 
>NUL 2>&1 REG.exe query "HKU\S-1-5-19" || (
    ECHO SET UAC = CreateObject^("Shell.Application"^) > "%TEMP%\Getadmin.vbs"
    ECHO UAC.ShellExecute "%~f0", "%1", "", "runas", 1 >> "%TEMP%\Getadmin.vbs"
    "%TEMP%\Getadmin.vbs"
    DEL /f /q "%TEMP%\Getadmin.vbs" 2>NUL
    Exit /b
)
 
ECHO input 'a' to add a right-click menu, input 'd' to delete the right-click menu:
REM 用户输入 'a' 或 'd'
SET /P ST=
if /I "%ST%"=="a" goto Add
if /I "%ST%"=="d" goto Delete
 
:Add
REM 添加文件右键菜单项
reg add "HKEY_CLASSES_ROOT\*\shell\VS Code" /t REG_SZ /v "" /d "Open with VS Code" /f
reg add "HKEY_CLASSES_ROOT\*\shell\VS Code" /t REG_EXPAND_SZ /v "Icon" /d "%~dp0Code.exe" /f
reg add "HKEY_CLASSES_ROOT\*\shell\VS Code\command" /t REG_SZ /v "" /d "%~dp0Code.exe \"%%1\"" /f
 
REM 添加文件夹右键菜单项
reg add "HKEY_CLASSES_ROOT\directory\shell\VS Code" /t REG_SZ /v "" /d "Open with VS Code" /f
reg add "HKEY_CLASSES_ROOT\directory\shell\VS Code" /t REG_EXPAND_SZ /v "Icon" /d "%~dp0Code.exe" /f
reg add "HKEY_CLASSES_ROOT\directory\shell\VS Code\command" /t REG_SZ /v "" /d "%~dp0Code.exe \"%%1\"" /f
 
exit
 
:Delete
REM 删除文件右键菜单项
reg delete "HKEY_CLASSES_ROOT\*\shell\VS Code" /f
 
REM 删除文件夹右键菜单项
reg delete "HKEY_CLASSES_ROOT\directory\shell\VS Code" /f
 
exit

拓展到任意软件：

1.Open With XXX 替换 Open with VS Code

2.%~dp0XXX.exe替换%~dp0Code.exe，XXX代表exe的名字，%~dp0的含义是获取批处理文件的目录，注意XXX.exe一定要和安装目录下的exe名称保持一致，如VS Code安装目录下为Code.exe