cmake(14)：利用set_property命令设置全局属性

目录

说明

简单示例

main.c 

property.c 

根目录下的 CMakeLists.txt

子目录下的 CMakeLists.txt 

set_property() 命令

get_property() 命令

参考资料

---

说明

在开发过程碰到需要在上级目录中构建，而源代码又分别写在下级目录的情况，同时又要根据不同的情况选择性地添加不同的源代码进行编译，所以考虑将需要编译的源代码放到一个 cmake 列表中。但是 set() 对应生成的变量都是局部变量（即不同的目录下不共用），于是使用 set_property() 命令。

简单示例

为了简化，我这里假设在 main() 函数下调用一个 show_system() 函数用于显示当前系统的名称。程序整体结构如下：

$ tree
├── CMakeLists.txt              
├── linux
│   ├── CMakeLists.txt
│   ├── property.c
│   └── property.h
├── main.c
└── win
    ├── CMakeLists.txt
    ├── property.c
    └── property.h

main.c 

程序很简单，就调用子目录下定义的函数。

#include <stdio.h>

#include <property.h>

int main()
{
    show_system();

    return 0;
}

property.c 

在 linux 和 win 的实现都一样。

#include <stdio.h>

#include "property.h"

void show_system()
{
    printf("This is linux\n");    // in linux
    printf("This is windows\n");  // in win
}

 

根目录下的 CMakeLists.txt

cmake_minimum_required (VERSION 3.13.0)

project (property_test VERSION 0.0.4)

# 设置全局属性 SOURCE_LIST
set_property( GLOBAL APPEND PROPERTY SOURCE_LIST)

# 如果是 Linux 系统，选择编译 linux 目录
IF (CMAKE_SYSTEM_NAME MATCHES "Linux")
    include_directories (linux)
    add_subdirectory (linux)

# Window 系统下选择编译 win 目录
ELSEIF (CMAKE_SYSTEM_NAME MATCHES "Windows")
    include_directories (win)
    add_subdirectory (win)
ENDIF (CMAKE_SYSTEM_NAME MATCHES "Linux")

# 将 SOURCE_LIST 的内容保存到 SRC_LIST 中
get_property(SRC_LIST GLOBAL PROPERTY SOURCE_LIST )

message("src list:" ${SRC_LIST})

# build exec
SET(exename "property")
add_executable (${exename} ${SRC_LIST} main.c)

子目录下的 CMakeLists.txt 

两个子目录下的 CMakeLists.txt 的内容完全一样

file(GLOB_RECURSE SRC_LIST "*.cpp" "*.c")    # 查找当前目录下所有 .cpp 和 .c 文件
set_property( GLOBAL APPEND PROPERTY SOURCE_LIST ${SRC_LIST})   # 将这些文件路径附加到 SOURCE_LIST 后面

因为 aux_source_directory 命令生成的是源文件的相对路径，传递到上一层之后无法正常使用，所以这里选择 file() 命令来查找源文件，它会生成文件的绝对路径。注意 file() 是递归查找的，也就是说子目录下的源代码也会被找到。

这里 SRC_LIST 是局部变量，只在本目录生效，所以每个 CMakeLists.txt 都可以正常使用，而 SOURCE_LIST 则是全局变量。

 

set_property() 命令

在给定范围内设置一个对象的属性。

命令格式：

set_property(<GLOBAL                      |
              DIRECTORY [<dir>]           |
              TARGET    [<target1> ...]   |
              SOURCE    [<src1> ...]
                        [DIRECTORY <dirs> ...]
                        [TARGET_DIRECTORY <targets> ...] |
              INSTALL   [<file1> ...]     |
              TEST      [<test1> ...]     |
              CACHE     [<entry1> ...]    >
             [APPEND] [APPEND_STRING]
             PROPERTY <name> [<value1> ...])

 # 其基本格式为：
 set_property(<Scope> [APPEND] [APPEND_STRING] PROPERTY <name> [value...])

第一个参数必须是属性的范围(Scope)，后面 [APPEND | APPEND_STRING] 可选，表示属性是可扩展的列表。PROPERTY 是标识，后面接属性名称<name>，其值可选。

Scope 有多种选择可以是：

Scope	Description	相似命令
GLOBAL	属性在全局范围内有效，属性名称需唯一
DIRECTORY	在指定目录内有效，可以是相对路径也可以是绝对路径	set_directory_properties
TARGET	设置指定 TARGET 的属性	set_target_properties
SOURCE	属性对应零个或多个源文件。默认情况下，源文件属性仅对添加在同一目录 (CMakeLists.txt) 中的目标可见。	set_source_files_properties
INSTALL	属性对应零个或多个已安装的文件路径。这些可供 CPack 使用以影响部署。
TEST	属性对应零个或多个现有测试。	set_tests_properties
CACHE	属性对应零个或多个缓存现有条目。

在3.18 版本之后，SOURCE 可以通过设置选项 DIRECTORY/TARGET_DIRECTORY 来时属性在其他目录中可见。

• DIRECTORY ：源文件属性将在每个 <dirs> 目录的范围内有效，CMake 必须已经知道这些目录中的每一个，或者通过调用 add_subdirectory() 添加它们，或者它是顶级源目录。相对路径被视为相对于当前源目录。3.19 版本之后可以引用二进制目录。

• TARGET_DIRECTORY ：源文件属性将在创建任何指定 <targets> 的每个目录范围中有效， <targets> 必须已经存在。

PROPERTY 是必需的参数，后面接属性的名称，其余的参数对应的是属性的值，以分号分隔。

APPEND 和 APPEND_STRING 是可选参数，如果设置了，那么后面的 <value1>... 将以列表的形式附加到指定属性的后面。APPEND_STRING 表示后面的 <value1> 将以字符串的形式添加到属性的后面。

get_property() 命令

获取属性的值。

get_property(<variable>
             <GLOBAL             |
              DIRECTORY [<dir>]  |
              TARGET    <target> |
              SOURCE    <source>
                        [DIRECTORY <dir> | TARGET_DIRECTORY <target>] |
              INSTALL   <file>   |
              TEST      <test>   |
              CACHE     <entry>  |
              VARIABLE           >
             PROPERTY <name>
             [SET | DEFINED | BRIEF_DOCS | FULL_DOCS])

<variable> : 保存属性值的变量

GLOBAL/DIRECTORY ... /VARIABLE : 表示属性对应的范围，与 set_property() 相同，额外的 VARIABLE 表示范围是唯一的，不接受名称。

PROPERTY <name> : 属性名，同 set_property()

SET | DEFINED | BRIEF_DOCS | FULL_DOCS : 可选参数

• SET : 将变量设置为布尔值，指示是否已设置属性；
• DEFINED : 将变量设置为布尔值，指示属性是否已被定义
• BRIEF_DOCS | FULL_DOCS : 如果给定了 Brief_DOCS 或 FULL_DOCS，则将变量设置为包含所请求属性的文档的字符串。

参考资料

set_property — CMake 3.24.0-rc5 Documentation

get_property — CMake 3.24.0-rc5 Documentation