aardio - 动态视频桌面

用aardio做动态视频桌面，全网首发，就问你：炫不炫！！

如果您运行了各种桌面管理软件，请先关闭，不然看不到效果。

复制以下代码，运行后，看看桌面，炫不炫！

import fonts.fontAwesome;
import win.ui;
/*DSG{{*/
var winform = win.form(text="动态视频桌面";right=859;bottom=459;bgcolor=16515070;parent=...)
winform.add(
video={cls="custom";left=10;top=10;right=850;bottom=451;bgcolor=0;db=1;dl=1;dr=1;dt=1;z=1}
)
/*}}*/

import mpvPlayer;
var mplayer = mpvPlayer(winform.video);
mplayer.setOption("osd-msg1","动态视频桌面 光庆编写 chengxu.online");
mplayer.loadFile("http://download.aardio.com/demo/video.aardio"); 
mplayer.play();   
setWallPaperWindow =  function(winhwnd,x,y,w,h){
	if !win import win;
	if x===null x,y,w,h=0,0,..win.getScreen();
	var windowHandle = ..win.find("Progman")
	if !windowHandle return ; 
	::SendMessageTimeout(windowHandle, 1324, ..topointer(0), ..topointer(0), 0, 1000, 0);
	var workerwin;
	..win.enum(
		function(hwnd){
			var defview = ..win.findEx(hwnd, 0, "SHELLDLL_DefView", null);
			if(defview)	workerwin = ..win.findEx(0, hwnd, "WorkerW", null);
			return true; 
		}
	)
	if workerwin ..win.show(workerwin,false);
	..win.setParent(winhwnd,windowHandle);
	..win.setPos(winhwnd,x,y,w,h,0,0);
}
setWallPaperWindow(winform.video.hwnd);
win.loopMessage();