Codeforces 575H Bots 组合恒等式+逆元法求组合数取模

题意简述
每次取$0$或$1$，总共取$2*N$次，$0$和$1$都限取$N$次，求操作过程中可能产生的状态总数（对$10^9+7$取模）。$(1 ≤ N ≤ 10^6)$

如下图，$N=2$时有$19$种状态，红边表示选$1$，蓝边表示选$0$（可互换）

---

分析
题目可以转化为在网格图中求从$(0,0)$走到$(N,N)$可能产生的所有状态总数，即求$\sum_{i=0}^{n}\sum_{j=0}^{n}f[i][j]$，$f[i][j]$表示从原点走到$(i,j)$的走法数。
由组合数知识可知$f[i][j]=C_{i+j}^{i}$
对横坐标为$i$的纵列求和
$\sum_{j=0}^{n}C_{i+j}^{i}=C_{i}^{i}+C_{i+1}^{i}+C_{i+2}^{i}+…+C_{i+n}^{i}$
$=(C_{i+1}^{i+1}+C_{i+1}^{i})+C_{i+2}^{i}+…+C_{i+n}^{i}$
$=C_{i+2}^{i+1}+C_{i+2}^{i}+…+C_{i+n}^{i}$
$=C_{i+n+1}^{i+1}$
再对这些纵列和求和
$\sum_{i=0}^{n}C_{i+n+1}^{i+1}=C_{n+1}^{1}+C_{n+2}^{2}+C_{n+3}^{3}+…+C_{n+n+1}^{n+1}$
$=C_{n+1}^{n}+C_{n+2}^{n}+C_{n+3}^{n}+…+C_{n+n+1}^{n}$
$=-C_{n+1}^{n+1}+(C_{n+1}^{n+1}+C_{n+1}^{n})+C_{n+2}^{n}+C_{n+3}^{n}+…+C_{n+n+1}^{n}$
$=-1+C_{n+2}^{n+1}+C_{n+2}^{n}+C_{n+3}^{n}+…+C_{n+n+1}^{n}$
$=C_{2n+2}^{n+1}-1$
以上分析都使用了组合恒等式$C_{n}^{k}=C_{n-1}^{k}+C_{n-1}^{k-1}$

接下来求$C_{2n+2}^{n+1}-1$对$mo=10^9+7$取模的结果
求逆元即可（三种做法如下）

---

一、扩展欧几里得算法
$a*ni(a)\equiv 1(mod \;mo)$
$a*ni(a)+mo*y=1$

const
mo=1000000007;
var
ans,p,x,y:int64;
i,n:longint;
fact:array[0..2000020] of int64;

function extgcd(a,b:int64;var x,y:int64):int64;
var x1,y1:int64;
begin
  if b=0 then
  begin
    x:=1;y:=0;
    exit(a);
  end
  else
  begin
    extgcd:=extgcd(b,a mod b,x1,y1);
    x:=y1;
    y:=x1-(a div b)*y1;
  end;
end;

function ni(a,m:int64):int64;
var tmp:int64;
begin
  tmp:=extgcd(a,m,x,y);
  exit((m+x mod m) mod m);
end;

function cmod(n,k:longint):longint;
var m:longint;
begin
    m:=mo;
    exit(fact[n]*ni(fact[k]*fact[n-k] mod mo,m)mod mo);
end;

begin
  readln(n);
  fact[1]:=1;
  for i:=2 to 2*n+2 do fact[i]:=fact[i-1]*i mod mo;
  ans:=cmod(2*n+2,n+1)-1;
  if ans=-1 then ans:=mo-1;
  writeln(ans);
end.

二、费马小定理
$a^{mo-1} \equiv 1(mod \;mo)$
$gcd(a,mo)=1$
$ni(a)=a^{mo-2}$

const
mo=1000000007;
var
ans,p,x,y,tmp:int64;
i,n:longint;
fact:array[0..2000020] of longint;

function pow(a,b:int64):longint;
var ans:longint;
begin
    ans:=1;
    while b<>0 do
    begin
        if b and 1=1 then ans:=ans*a mod mo;
        a:=a*a mod mo;
        b:=b>>1;
    end;
    exit(ans);
end;

function ni(a:int64):int64;
var m:longint;
begin
    m:=mo-2;
    exit(pow(a,m));
end;//求逆元：mo为素数使用费马小定理

function cmod(n,k:longint):longint;
var m:longint;
begin
    m:=mo;
    exit(fact[n]*ni(tmp*fact[k]*fact[n-k] mod mo)mod mo);
end;

begin
  readln(n);
  fact[1]:=1;tmp:=1;
  for i:=2 to 2*n+2 do fact[i]:=tmp*fact[i-1]*i mod mo;
  ans:=cmod(2*n+2,n+1)-1;
  if ans=-1 then ans:=mo-1;
  writeln(ans);
end.

三、神奇方法

const
mo=1000000007;
var
ans,p,x,y,tmp:int64;
i,n:longint;
fact:array[0..2000020] of longint;

function ni(t:int64):int64;
var k:int64;
begin
    if t=1 then exit(1);
    k:=mo div t+1;
    exit(k*ni(k*t-mo)mod mo);
end;//求逆元：神奇O(log n)做法
{
  t=n!
  mo=k*t-r  //k=mo div t+1
  t*k≡r(mod mo)
  t*(k*ni[r])≡r*ni[r]≡1(mod mo)
  ni[t]=k*ni[r]
  //显然这个做法还可以用于递推做1~n的逆元预处理
}
function cmod(n,k:longint):longint;
var m:longint;
begin
    m:=mo;
    exit(fact[n]*ni(tmp*fact[k]*fact[n-k] mod mo)mod mo);
end;
begin
  readln(n);
  fact[1]:=1;tmp:=1;
  for i:=2 to 2*n+2 do fact[i]:=tmp*fact[i-1]*i mod mo;
  ans:=cmod(2*n+2,n+1)-1;
  if ans=-1 then ans:=mo-1;
  writeln(ans);
end.

虽然三种求逆元的方法都是$O(log\;n)$的效率，但extgcd的常数比较小，注意费马小定理+快速幂的求法要求mo为素数。