[USACO 5.1.3]Musical Themes(后缀数组)

【题目描述】：

 

我们用N(1 <= N <=5000)个音符的序列来表示一首乐曲，每个音符都是1..88范围内的整数，每个数表示钢琴上的一个键。很不幸这种表示旋律的方法忽略了音符的时值，但这项编程任务是关于音高的，与时值无关。

许多作曲家围绕一个重复出现的“主题”来构建乐曲。在我们的乐曲表示法中，“主题”是整个音符序列的一个子串，它需要满足如下条件：

⒈长度至少为5个音符

⒉在乐曲中重复出现(可能经过转调，见下)

⒊重复出现的同一主题不能有公共部分。

“转调”的意思是主题序列中每个音符都被加上或减去了同一个整数值。 给定一段乐曲，计算其中最长主题的长度(即音符数)。

【题目分析】：

这个题我当时在做的时候用的是枚举+优化。

这回做的时候因为刚刚学会了suffix array，所以练习一下，的确非常的快：

枚举+优化：

 Compiling...
Compile: OK

Executing...
   Test 1: TEST OK [0.000 secs, 220 KB]
   Test 2: TEST OK [0.000 secs, 220 KB]
   Test 3: TEST OK [0.000 secs, 220 KB]
   Test 4: TEST OK [0.000 secs, 220 KB]
   Test 5: TEST OK [0.000 secs, 220 KB]
   Test 6: TEST OK [0.000 secs, 220 KB]
   Test 7: TEST OK [0.000 secs, 220 KB]
   Test 8: TEST OK [0.011 secs, 220 KB]
   Test 9: TEST OK [0.022 secs, 220 KB]
   Test 10: TEST OK [0.000 secs, 220 KB]
   Test 11: TEST OK [0.227 secs, 220 KB]
   Test 12: TEST OK [0.216 secs, 220 KB]
   Test 13: TEST OK [0.173 secs, 220 KB]
   Test 14: TEST OK [0.238 secs, 220 KB]
   Test 15: TEST OK [0.216 secs, 220 KB]

All tests OK.

后缀数组：

Compiling...
Compile: OK

Executing...
   Test 1: TEST OK [0.011 secs, 364 KB]
   Test 2: TEST OK [0.000 secs, 364 KB]
   Test 3: TEST OK [0.000 secs, 364 KB]
   Test 4: TEST OK [0.000 secs, 364 KB]
   Test 5: TEST OK [0.000 secs, 364 KB]
   Test 6: TEST OK [0.000 secs, 364 KB]
   Test 7: TEST OK [0.000 secs, 364 KB]
   Test 8: TEST OK [0.000 secs, 364 KB]
   Test 9: TEST OK [0.011 secs, 364 KB]
   Test 10: TEST OK [0.000 secs, 364 KB]
   Test 11: TEST OK [0.011 secs, 364 KB]
   Test 12: TEST OK [0.000 secs, 364 KB]
   Test 13: TEST OK [0.011 secs, 364 KB]
   Test 14: TEST OK [0.011 secs, 364 KB]
   Test 15: TEST OK [0.011 secs, 364 KB]

All tests OK.
可以说差距是相当的明显……
一会找时间写下后缀数组的总结~这个题就是用后缀数组搞出来SA,RANK和HEIGHT之后二分答案，然后分段。
连续的HEIGHT值大于x的算作一段，如果一段最大的SA 和最小的SA之差大于K，那么代表没有重叠，说明有解。
好长时间不做了，忘了很多东西，最开始忘了可以转调这回事了，汗……
后来的问题，例如有负数~基数排序的时候上界开小了之类的各种白痴错误。其实最白痴的就是二分的地方。
我终于明白为什么我有时候会死在二分里面了…………
情况是这样的，如果有解s:=mid，无解t:=mid-1是没问题的。但是mid不可以用(left+right) div 2的。
原因是如果说Mid是有解的，如果想向右靠那就要用(left+right+1) div 2。
但是如果是向左靠的就没什么问题了。
唉……没什么好说的了，自己看代码吧：
【代码】：
{
TASK:theme
LANG:PASCAL
}
program theme;
var
  sum,rank,trank,tmp,sa,s,height,a:array[0..5000] of longint;
  n,i,min:longint;
procedure suffix_init;
var
  i,j,m,p:longint;
begin
  fillchar(sum,sizeof(sum),0);
  for i:=1 to n do begin rank[i]:=s[i]; inc(sum[rank[i]]) end;
  for i:=1 to 1000 do inc(sum[i],sum[i-1]);
  for i:=n downto 1 do
    begin
      sa[sum[rank[i]]]:=i;
      dec(sum[rank[i]]);
    end;
  m:=0;
  for i:=1 to n do
    begin
      if rank[sa[i]]<>rank[sa[i-1]] then inc(m);
      trank[sa[i]]:=m;
    end;
  rank:=trank;
  j:=1;
  while m<n do
    begin
      fillchar(sum,sizeof(sum),0);
      p:=0;
      for i:=n-j+1 to n do
        begin
          inc(p);
          tmp[p]:=i;
        end;
      for i:=1 to n do
        if sa[i]>j then
          begin
            inc(p);
            tmp[p]:=sa[i]-j;
          end;
      for i:=1 to n do begin trank[i]:=rank[tmp[i]]; inc(sum[trank[i]]); end;
      for i:=1 to m do inc(sum[i],sum[i-1]);
      for i:=n downto 1 do
        begin
          sa[sum[trank[i]]]:=tmp[i];
          dec(sum[trank[i]]);
        end;
      m:=0;
      for i:=1 to n do
        begin
          if (rank[sa[i]]<>rank[sa[i-1]]) or (rank[sa[i]+j]<>rank[sa[i-1]+j]) then inc(m);
          trank[sa[i]]:=m;
        end;
      rank:=trank;
      j:=j shl 1;
    end;
end;
procedure calc_height;
var
  i,j,k:longint;
begin
  j:=1;
  for i:=1 to n do
    begin
      if rank[i]=1 then continue;
      k:=sa[rank[i]-1];
      while s[i+j]=s[k+j] do inc(j);
      height[rank[i]]:=j;
      if j>0 then dec(j);
    end;
end;
function check(x:longint):boolean;
var
  max,min,i:longint;
begin
  check:=false; max:=-maxlongint; min:=maxlongint;
  for i:=1 to n do
    if height[i]<x then
      begin
        min:=sa[i];
        max:=sa[i];
      end
    else
      begin
        if sa[i]>max then max:=sa[i];
        if sa[i]<min then min:=sa[i];
        if max-min>x then exit(true);
      end;
end;
procedure main;
var
  left,right,mid:longint;
begin
  left:=1; right:=n;
  while left<right do
    begin
      mid:=(left+right+1) div 2;
      if check(mid) then left:=mid
                    else right:=mid-1;
    end;
  if left+1>=5 then writeln(left+1) else writeln(0);
end;
begin
  assign(input,'theme.in');
  assign(output,'theme.out');
  reset(input); rewrite(output);
  readln(n);
  for i:=1 to n do read(a[i]);
  n:=n-1;
  min:=maxlongint;
  for i:=1 to n do
    begin
      s[i]:=a[i+1]-a[i];
      if s[i]<min then min:=s[i];
    end;
  for i:=1 to n do
    s[i]:=s[i]-min+1;
  suffix_init;
  calc_height;
  main;
  close(input); close(output);
end.