Excel工作表事件（4）- 单元格修订记录跟踪

Change事件看起来并不复杂，但是在很多应用场景，都会用到Change事件，并且可以给大家带来很多工作上的便利性。
例如很多用户都希望能够保存单元格内容的修订记录，但是靠人工记录下来这个修改过程，确实有些繁琐，合理使用Change事件，就可以实现这个功能，修订记录保存在单元格批注中。
当前数据表内容如下所示。

现在做如下修改：

Math_05 => CS_01
Tom => Jerry

修改后工作表如下图所示，修订记录自动添加到批注中。

示例代码如下。

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim strCmt As String
    Application.EnableEvents = False
    With Target
        If .Count = 1 Then
            Application.DisplayAlerts = False
            On Error Resume Next
            strCmt = .Comment.Text
            If Err.Number > 0 Then
                strCmt = Date & "-" & .Value
                .AddComment strCmt
            Else
                strCmt = strCmt & Chr(10) & Date & "-" & .Value
                .Comment.Text strCmt
            End If
            On Error GoTo 0
            Application.DisplayAlerts = True
        End If
    End With
    Application.EnableEvents = True
End Sub

【代码解析】
第3行代码禁用系统事件激活。
第5行代码判断是否只是修改了单个单元格。
第6行代码禁止显示告警。
第7行代码忽略错误继续执行。
第8行读取单元格的注释，如果单元格中没有注释，那么第9行代码进行错误捕获。
第10行代码为生成批注内容。
第11行代码为单元格添加批注。
如果单元格已经存在批注，那么第13和14行代码将在批注中追加单元格的最新值。
第16行恢复系统的错误处理机制。
第17行恢复系统错误显示。
第20行代码启用系统事件激活。