VBA之正则表达式（32）-- 提取指定规格

实例需求：按照指定规则从示例数据提取相应的规格，示例数据如下所示。

A75432222新粉色M/160 – 提取规格为：M
B43243333畅销黑色44 – 提取规格为：44
C93119125 – 无规格

方法1：
Sub Demo1()
    Dim regExp As Object, regExpMHs As Object
    Set regExp = CreateObject("vbscript.regExp")
    regExp.Global = True
    regExp.Pattern = "[一-龟]+(.+?)(?=($|/))"
    arr = Array("D132981111粉色M/160", "D931191211品牌黑44", "C93119125")
    For i = 0 To UBound(arr)
        Set regExpMHs = regExp.Execute(arr(i))
        If regExpMHs.Count > 0 Then
            Debug.Print regExpMHs(j).submatches(0)
        End If
    Next
    Set regExpMHs = Nothing
    Set regExp = Nothing
End Sub

代码解析：
第3行代码创建正则表达式对象。
第4行代码设置全局匹配。
第5行代码设置匹配规则。

正则表达式	说明
[一-龟]+	匹配一个或者多个中文字符
(.+?)	非贪婪匹配任意字符，为第一个提取组
(?=($|/))	顺序肯定环视，用于判断字符之后的字符组合符合指定模式,匹配行尾标识或者/，为第二个提取组

第6行代码将数据保存在数组中。
第7~12行代码使用For语句循环处理数据。
第8行代码执行正则匹配。
第9行代码判断是否匹配成功，如果匹配成功，那么Count属性返回为匹配结果的数量。
第10行代码输出第一个提取组的结果。
第13~14行代码清空对象变量，释放系统资源。

匹配结果如下图所示。

---

方法2：

Sub Demo2()
    Dim regExp As Object, regExpMHs As Object
    Set regExp = CreateObject("vbscript.regExp")
    regExp.Global = True
    regExp.Pattern = "[一-龟]+(\w+)|."
    arr = Array("D132981111粉色M/160", "D931191211品牌黑44", "C93119125")
    For i = 0 To UBound(arr)
        Debug.Print regExp.Replace(arr(i), "$1")
    Next
    Set regExp = Nothing
End Sub

代码解析：
第5行代码设置匹配规则。

正则表达式	说明
[一-龟]+	匹配一个或者多个中文字符
(\w+)	匹配一个或者多个英文字符或者数字，为第一个提取组
|.	匹配任意字符

第8行代码执行正则替换。

匹配结果如下图所示，注意第3个数据不符合匹配规则，正则替换后的结果为空。