数组排序系列（7）

ArrayList排序法

'System.Collections.ArrayList’提供了Sort方法，可以实现数组排序。

Sub ArrayList()
    Dim aintData(1 To 10) As Variant
    Dim i As Integer
    Dim intLB As Integer
    Dim intUB As Integer
    Dim avntData(1 To 10) As Variant
    Dim objArrayList As Object
    intLB = LBound(aintData)
    intUB = UBound(aintData)
    For i = intLB To intUB
        aintData(i) = Application.WorksheetFunction.RandBetween(1, 100)
    Next i
    Debug.Print "Original Data: " & Join(aintData, ",")
    Set objArrayList = CreateObject("System.Collections.ArrayList")
    For i = intLB To intUB
        objArrayList.Add aintData(i)
    Next i
    objArrayList.Sort
    For i = intLB To intUB
        avntData(i) = objArrayList(i - 1)
    Next i
    Debug.Print "After Sort: " & Join(avntData, ",")
End Sub

运行代码结果如下。

Original Data: 72,8,53,2,38,51,39,63,77,33
After Sort: 2,8,33,38,39,51,53,63,72,77

代码解析：
第14行代码创建’System.Collections.ArrayList’对象实例。
第15行到第17行代码将数组元素添加的ArrayList。
第18行代码实现排序。

---

此示例代码实现的是升序排序，如需使用降序，那么只需要修改第20行代码如下。

avntData(i) = objArrayList(intUB - i)

---

相关文章链接：

数组排序系列（1）-- 冒泡法
数组排序系列（2）-- 极值法
数组排序系列（3）-- 工作表排序法
数组排序系列（4）-- JavaScript排序法（数字升序）
数组排序系列（5）-- JavaScript排序法（数字降序）
数组排序系列（6）-- JavaScript排序法（字符排序）
数组排序系列（7）-- ArrayList排序法
数组排序系列（8）-- Sortedlist排序法