颜色置灰，控制灰化程度

Shader "DanDan/Sprite/Gray"
{
    Properties
    {
        [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
        _Color ("Tint", Color) = (1,1,1,1)
        [MaterialToggle] PixelSnap ("Pixel snap", Float) = 0
        
        // 声明属性，值的范围 0 到 1，默认值为 1
        // 控制灰化程度
        _GrayFactor("GrayFactor",Range(0,1)) = 1
    }

    SubShader
    {
        Tags
        { 
            "Queue"="Transparent" 
            "IgnoreProjector"="True" 
            "RenderType"="Transparent" 
            "PreviewType"="Plane"
            "CanUseSpriteAtlas"="True"
        }

        Cull Off
        Lighting Off
        ZWrite Off
        Blend One OneMinusSrcAlpha

        Pass
        {
        CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile _ PIXELSNAP_ON
            #include "UnityCG.cginc"

            struct appdata_t
            {
                float4 vertex   : POSITION;
                float4 color    : COLOR;
                float2 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex   : SV_POSITION;
                fixed4 color    : COLOR;
                float2 texcoord  : TEXCOORD0;
            };

            fixed4 _Color;

            v2f vert(appdata_t IN)
            {
                v2f OUT;
                OUT.vertex = UnityObjectToClipPos(IN.vertex);
                OUT.texcoord = IN.texcoord;
                OUT.color = IN.color * _Color;
                #ifdef PIXELSNAP_ON
                OUT.vertex = UnityPixelSnap (OUT.vertex);
                #endif

                return OUT;
            }

            sampler2D _MainTex;
            sampler2D _AlphaTex;
            float _AlphaSplitEnabled;

            // 声明与 Properties 同名变量（自动接收 Proeprty 值）
            float _GrayFactor;

            fixed4 SampleSpriteTexture (float2 uv)
            {
                // 贴图色
                fixed4 color = tex2D (_MainTex, uv);

                // 取灰
                float grayValue = color.r * 0.299 + color.g * 0.587 + color.b * 0.114;
                
                //创建灰色
                float4 grayColor = float4(grayValue,grayValue,grayValue,1.0);
                
                // 控制灰化程度
                color = lerp(color,grayColor, _GrayFactor);

#if UNITY_TEXTURE_ALPHASPLIT_ALLOWED
                if (_AlphaSplitEnabled)
                    color.a = tex2D (_AlphaTex, uv).r;
#endif //UNITY_TEXTURE_ALPHASPLIT_ALLOWED

                return color;
            }

            fixed4 frag(v2f IN) : SV_Target
            {
                fixed4 c = SampleSpriteTexture (IN.texcoord) * IN.color;
                c.rgb *= c.a;
                return c;
            }
        ENDCG
        }
    }
}

前：

后：

对差值 Lerp 的理解方式

// 区间理解方式
float lerp(float a, float b, float w) 
{
  return a + w*(b-a);
}

// 权重理解方式
float lerp(float a, float b, float w) {
  return a(1-w) + b * w;
}