C0014.分享一个带注解的CMakeLists.txt代码，很全值得收藏

#指定构建项目所需的最小 CMake 版本
cmake_minimum_required(VERSION 3.16)

# 设置项目名称和版本
project(NaMi VERSION 0.1 LANGUAGES CXX)

#启用自动处理 Qt 的 UIC（User Interface Compiler） 文件
set(CMAKE_AUTOUIC ON)
#启用自动处理 Qt 的 MOC（Meta-Object Compiler） 文件
set(CMAKE_AUTOMOC ON)
#启用自动处理 Qt 的 RCC（Resource Compiler） 文件
set(CMAKE_AUTORCC ON)

#设置 C++ 编译标准为 C++17
set(CMAKE_CXX_STANDARD 17)
#强制要求使用 C++17 或更高版本的编译器
set(CMAKE_CXX_STANDARD_REQUIRED ON)

# 解决ui文件移动到别的文件夹后报错的问题，即指定ui文件路径，这里Ui即为目录
set(CMAKE_AUTOUIC_SEARCH_PATHS "Ui")

# 设置OpenCV的安装路径
set(OpenCV_DIR D:/OpenCv_Win/opencv/build)

# 查找OpenCV包
find_package(OpenCV REQUIRED)

# 解决.h头文件移动到别的文件夹后报错的问题，即指定.h头文件路径，这里include即为目录，结尾的是opencv头文件的路径
include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include ${OpenCV_INCLUDE_DIRS})

# 用于查找 Qt5包，并确保找到Widgets、SerialPort模块
find_package(QT NAMES Qt5 REQUIRED COMPONENTS Widgets SerialPort)
find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Widgets SerialPort)

set(PROJECT_SOURCES
        main.cpp
        src/nami.cpp
        src/link.cpp
        src/link_info.cpp
        src/deepVision.cpp
        src/utility.cpp
        include/nami.h
        include/link.h
        include/link_info.h
        include/deepVision.h
        include/utility.h
        Ui/nami.ui
        Ui/link.ui
        Ui/link_info.ui
        Ui/deepVision.ui
        my_qrc.qrc
)

# 如下代码只在使用VS编译器时需要，使用mingw32编译器时需要注释掉
# 编码设置(用于解决warning C4819:警告),必须位于 add_executable（……） 之前
add_compile_options("$<$<C_COMPILER_ID:MSVC>:/utf-8>")
add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/utf-8>")

# 解决（warning C4828:）问题
# 添加以下行来指定字符集为多字节字符集或 Unicode
add_compile_options("/DUNICODE")
add_compile_options("/D_UNICODE")


if(${QT_VERSION_MAJOR} GREATER_EQUAL 6)
    qt_add_executable(NaMi
        MANUAL_FINALIZATION
        ${PROJECT_SOURCES}
    )
# Define target properties for Android with Qt 6 as:
#    set_property(TARGET NaMi APPEND PROPERTY QT_ANDROID_PACKAGE_SOURCE_DIR
#                 ${CMAKE_CURRENT_SOURCE_DIR}/android)
# For more information, see https://doc.qt.io/qt-6/qt-add-executable.html#target-creation
else()
    if(ANDROID)
        add_library(NaMi SHARED
            ${PROJECT_SOURCES}
        )
# Define properties for Android with Qt 5 after find_package() calls as:
#    set(ANDROID_PACKAGE_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/android")
    else()
        # 创建可执行文件
        add_executable(NaMi
            ${PROJECT_SOURCES}
        )
    endif()
endif()

# 链接Qt库，这里是链接了Qt下面的Widgets库和SerialPort库，OpenCV库
target_link_libraries(NaMi PRIVATE Qt${QT_VERSION_MAJOR}::Widgets Qt${QT_VERSION_MAJOR}::SerialPort ${OpenCV_LIBS})

# Qt for iOS sets MACOSX_BUNDLE_GUI_IDENTIFIER automatically since Qt 6.1.
# If you are developing for iOS or macOS you should consider setting an
# explicit, fixed bundle identifier manually though.
if(${QT_VERSION} VERSION_LESS 6.1.0)
  set(BUNDLE_ID_OPTION MACOSX_BUNDLE_GUI_IDENTIFIER com.example.NaMi)
endif()

set_target_properties(NaMi PROPERTIES
    ${BUNDLE_ID_OPTION}
    MACOSX_BUNDLE_BUNDLE_VERSION ${PROJECT_VERSION}
    MACOSX_BUNDLE_SHORT_VERSION_STRING ${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}
    MACOSX_BUNDLE TRUE
    WIN32_EXECUTABLE TRUE
)

include(GNUInstallDirs)
install(TARGETS NaMi
    BUNDLE DESTINATION .
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

if(QT_VERSION_MAJOR EQUAL 6)
    qt_finalize_executable(NaMi)
endif()