[米联客-安路飞龙DR1-FPSOC] FPGA基础篇连载-06 PWM呼吸灯实验

软件版本：Anlogic -TD5.9.1-DR1_ES1.1

操作系统：WIN10 64bit

硬件平台：适用安路(Anlogic)FPGA

实验平台：米联客-MLK-L1-CZ06-DR1M90G开发板

板卡获取平台：https://milianke.tmall.com/

登录“米联客”FPGA社区 http://www.uisrc.com 视频课程、答疑解惑！

目录

1概述

1.1 呼吸灯简介

1.2 硬件电路分析

2 PWM呼吸灯程序设计

2.1 系统框图

2.2 程序源码

3 FPGA工程

4 Modelsim仿真

4.1 准备工作

4.2 启动modelsim仿真

5 下载演示

5.1 硬件连接

5.2 运行结果

---

1概述

小小呼吸灯在很多设备上我们可以看到，我们可以在FPGA的控制主板上也可以加入呼吸灯，指示我们的FPGA主板正在运行。一般呼吸灯的亮灭周期是2S，呼吸灯的亮度可以通过PWM来调节。本文实现一个实用的小程序，读者完全可以自己编写代码，并且通过仿真测试代码的正确性，然后下载到开发板看实际运行效果。

在完成本实验前，请确保已经完成前面的实验，包括已经掌握以下能力：

1:完成了TD软件安装

2:完成了modelsim安装以及TD库的编译

3:掌握了TD仿真环境的设置

4:掌握了modesim通过do文件启动仿真

1.1 呼吸灯简介

呼吸灯，就是指灯光设备的亮度随着时间由暗到亮逐渐增强，再由亮到暗逐渐衰减。呼吸灯最早是被苹果公司开发出来的，一经面世，立刻吸引众多科技公司效仿并广泛应用于各类电子产品上。本章课程将通过PWM的方式实现呼吸灯效果。

脉冲宽度调制(PWM)，是英文“Pulse Width Modulation”的缩写，简称脉宽调制，是利用微处理器的数字输出来对模拟电路进行控制的一种非常有效的技术，广泛应用在从测量、通信到功率控制与变换的许多领域。

PWM的频率f是指1秒钟内信号从高电平到低电平再回到高电平的次数(一个周期)，单位为Hz；

PWM的周期是指频率的倒数，T = 1/f，如果频率为50Hz，即一个周期是20ms，那么1s中有1s/20ms=50次PWM周期；

占空比是指高电平在一个周期之内所占的时间比率。若信号的周期为T，每周期高电平时间为t1,低电平时间为t2,T=t1+t2,则占空比D=t1/T

呼吸灯采用 PWM 的方式，在固定的频率下，通过调整占空比的方式来控制 LED 灯亮度的变化。一般人眼睛对于80Hz以上刷新频率则完全没有闪烁感。频率太小的话，LED灯看起来就会闪烁，当频率大于50Hz的时候，人眼就会产生视觉暂留效果，基本就看不到闪烁了，就是一个常亮的LED灯。如果高电平点亮LED灯，低电平熄灭LED灯，占空比为100%，LED 灯最亮，占空比为0%，LED 灯最暗。所以，在频率一定下，可以用不同占空比改变LED灯的亮度。

1.2 硬件电路分析

参照“流水灯”硬件电路分析部分

2 PWM呼吸灯程序设计

2.1 系统框图

本次实验目的为1个LED实现呼吸灯的效果，LED变换间隔时间需要基于系统时钟来计数，实现间隔时间的计时，除此之外，添加系统复位使程序恢复至默认状态，输出结果由1个LED灯显示。命名模块名为pwm_light，此模块需要两个输入的端口，分别为系统时钟和系统复位，输出为1位的 LED 端口。

呼吸灯是由两个部分组成，一个是由亮到暗的过程，一个是由暗到亮的过程，再由简介可知我们是在固定的频率下通过调整高电平的占空比来调控 led 灯的亮度。第一个过程由亮到暗的过程为t=2s，如果高电平点亮LED灯，低电平熄灭LED灯，不同的占空比显示不同的亮度，占空比就要在2s之间逐渐由100%减小至0%，如果我们把2s划分成100份，那么每一个占空比就要保持t1=2s/100=20ms。由于占空比100%减小到0%一共变化了100次，占空比=高电平周期/整个周期t1，所以需要将一个占空比周期t1划分成100份，从而达到高电平周期每减小一个周期t2，占空比就减少1%，t2=20ms/100=200us。

PWM呼吸灯程序设计中包含了3个定时计数器：

20us定时器，作为本系统的基本定时器，产生时间基准。

20ms定时器，通过20us定时器，计数100次完成20ms定时计数

2s定时器，通过20ms定时器，计数100次完成2S定时计数

PWM每间隔2ms更新一次，共计更新100次即2S后切换PWM的占空比调整方向。因此PWM占空比的调整是和2ms定时计数器和2S定时计数器相关。系统框图如下:

2.2 程序源码

`timescale 1ns / 1ns

module pwm_light#
(
parameter REF_CLK      = 32'd100000000
)
(
input       I_sysclk,
input       I_rstn,
output      O_pwm
);

localparam T20US_SET     = REF_CLK/20000 - 1;  //set 200us
localparam T20MS_SET     = 100 - 1;           //set 20ms
localparam PWM_SET       = 100 - 1;           //Set PWM duty cycle adjustment times

reg [23:0] t20us_cnt;
reg [9 :0] t20ms_cnt;
reg [9 :0] pwm_cnt;
reg PWM_S;

wire t20us_done;
wire t20ms_done;

//设置20us计数，当计数条件达成时拉高
assign t20us_done = (t20us_cnt == T20US_SET);
///设置20ms计数，当计数条件达成时拉高
assign t20ms_done = t20us_done & (t20ms_cnt == T20MS_SET) ;

//1us base timer
always @(posedge I_sysclk or negedge I_rstn)begin
    if(I_rstn == 1'b0)
        t20us_cnt <= 0;    
    else if(t20us_cnt < T20US_SET)                                  //t20us_cnt寄存器用来计数，目标值是T20US_SET
        t20us_cnt <= t20us_cnt + 1'b1;                              //未达到目标值+1
    else 
        t20us_cnt <= 24'd0;                                          //达到目标值清零
end

//1ms pwm compare timer,based on 1us base timer
always @(posedge I_sysclk or negedge I_rstn)begin                  //系统时钟的上升沿以及复位的下降沿触发
    if(I_rstn == 1'b0)                                                //复位清零
         t20ms_cnt <= 0;    
    else if(t20us_done)                                                  //t20us_done计数完成作为后续判断的大前提
         t20ms_cnt <= (t20ms_cnt < T20MS_SET) ? (t20ms_cnt + 1'b1) : 10'd0;   //判断语句，当t20ms_cnt < T20MS_SET满足时
    else                                                                            //t20ms_cnt计数器+1，否则就清零
         t20ms_cnt <= t20ms_cnt;
end

//PWM counter for generating duty cycle parameters as well as PWM adjustment count
always @(posedge I_sysclk or negedge I_rstn)begin                              //系统时钟的上升沿以及复位的下降沿触发
    if(I_rstn == 1'b0)                                                             //复位清零
        pwm_cnt <= 0;
    else if(t20ms_done)                                                           //t20ms_done计数完成作为后续判断的大前提
        pwm_cnt <= (pwm_cnt < PWM_SET) ? (pwm_cnt + 1'b1) : 10'd0;           //判断语句，当pwm_cnt < PWM_SET满足时
    else                                                                          //pwm_cntt计数器+1，否则就清零
        pwm_cnt <= pwm_cnt;                                                        
end

//switch breathing state
always @(posedge I_sysclk or negedge I_rstn)begin                          //系统时钟的上升沿以及复位的下降沿触发
    if(I_rstn == 1'b0)
        PWM_S <= 0;                                                            //复位清零
    else if(t20ms_done && (pwm_cnt == PWM_SET))                             //pwm_cnt == PWM_SET达成时，对PWM_S的状态进行翻转
        PWM_S <= ~PWM_S;                                                       //反应到LED灯上是LED灯的亮灭变换转换
    else
        PWM_S <= PWM_S;
end

//PWM wave generating
assign  O_pwm = PWM_S ? (pwm_cnt >= t20ms_cnt) : (pwm_cnt < t20ms_cnt);         //判断语句，通过PWM_S的变换，使O_pwm输出的

endmodule  

3 FPGA工程

fpga工程的创建过程不再重复，如有不清楚的请看前面实验。

米联客的代码管理规范,在对应的FPGA工程路径下创建uisrc路径，并且创建以下文件夹

01_rtl:放用户编写的rtl代码

02_sim:仿真文件或者工程

03_ip:放使用到的ip文件

04_pin:放fpga的pin脚约束文件或者时序约束文件

05_boot:放编译好的bit或者bin文件(一般为空)

06_doc:放本一些相关文档(一般为空)

4 Modelsim仿真

4.1 准备工作

Modelsim仿真的创建过程不再重复，如有不清楚的请看前面实验

仿真测试文件源码如下，对于led这种低速仿真，仿真精度可以设置为1ns，另外仿真阶段可以把间隔时间设置小一些，这样仿真速度就快了：

`timescale 1ns / 1ns

module sim_top_tb();

reg I_sysclk,I_rstn;
wire  O_pwm;

pwm_light#
(
.REF_CLK(100_000)
)
pwm_light_inst
(
.I_sysclk(I_sysclk),
.I_rstn(I_rstn),
.O_pwm(O_pwm)
);

initial begin
   I_sysclk  <= 1'b0;
   I_rstn    <= 1'b0;
   #100;
   I_rstn    <= 1'b1;  
end

always #20 I_sysclk=~I_sysclk;

endmodule

4.2 启动modelsim仿真

启动后，右击需要观察的信号，添加到波形窗口

设置restart

设置运行100ms(如果运行时间太长可以修改小一些)

从仿真结果可以看到PWM占空比的调整

5 下载演示

下载程序前，先确保FPGA工程已经编译。

5.1 硬件连接

（该教程为通用型教程，教程中仅展示一款示例开发板的连接方式，具体连接方式以所购买的开发板型号以及结合配套代码管脚约束为准。）

请确保下载器和开发板已经正确连接，并且开发板已经上电(注意JTAG端子不支持热插拔，而USB接口支持，所以在不通电的情况下接通好JTAG后，再插入USB到电脑，之后再上电，以免造成JTAG IO损坏)

5.2 运行结果

（该教程为通用型教程，教程中仅展示一款示例开发板的上板现象，具体现象以所购买的开发板型号以及配套代码上板现象为准。）