高光反射-逐顶点光照

Shader "Custom/testShader" {
properties
{
   _Diffuse("my diffuse",Color) = (1,1,1,1)
   _Specular("my specular", Color) = (1,1,1,1)        //高光颜色
   _Gloss("my gloss", Range(8.0, 256)) = 20         //控制高光区域大小
} 
subshader
{
  Tags{"LightMode"="ForwardBase"}
  pass
  {
     CGPROGRAM
     #pragma vertex vert
     #pragma fragment frag
     #include "Lighting.cginc"
 
     fixed4 _Diffuse;
     fixed4 _Specular;
     float _Gloss;
 
     struct a2v
     {
         float4 vertex : POSITION;
         float3 normal : NORMAL;
     };
     struct v2f
     {
         float4 pos : SV_POSITION;
         float3 color : COLOR;
     }; 

     v2f vert(a2v v)
     {
         v2f o;
         o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
         fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
         fixed3 worldNormal = normalize(mul(v.normal, (float3x3)_World2Object));
         fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
         fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb *saturate(dot(worldNormal,worldLightDir));
 
 fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));        //反射方向 = 单位化反射光照计算函数
 fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(_Object2World, v.vertex).xyz);    
 fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss);
 
      o.color = ambient + diffuse + specular;
         return o;
     }
     fixed4 frag(v2f i) : SV_Target
     {
        return fixed4(i.color, 1.0);
     }
     ENDCG
    }
}
}   

【说明】

1.  首先计算了入射光线方向关于法线的反射方向reflectDir，由于reflect函数的入射方向要求是由光源指向交点处       的，因此，需要对worldLightDir取反后再传给reflect函数。

2. 通过_WorldSpaceCameraPos得到世界空间中的摄像机位置，再把顶点位置从模型位置变换到世界空间下，再通     过和_WorldSpaceCameraPos相减即可得到世界空间下的视角方向。 视角方向 = 单位化（相机方向-顶点位置）世界坐标系下