linux 管道符 md5,获取keystore的MD5值

新浪微博里注册应用需要填写app的签名。虽然他们提供了一个工具，但是每次都要先打包安装，输入包名，还得发送结果到电脑。过程太麻烦了。我就想着要简化下。

这里填写的签名实际上是keystore的md5，用命令行

`keytool -v -list -keystore ***.keystore`

即可输出md5的信息，但是新浪要求的是32位的小写不带冒号的字符串。

由于我对js比较熟悉，所以我一开始的处理方法是用chrome的console处理下。var a = 'E9:AB:F3:DF:84:82:E9:ED:AB:AB:F3:A9:C1:AE:17:AB';

a = a.toLocaleLowerCase();

a.replace(/\:/g,'');

如此就得到了想要的字符串了。

但是还是有些麻烦，还想再简化下，人至懒则无敌了。

后来查了批处理处理字符串的方法，用如下方法将字符串aa中的:替换为空字符。set "aa=%aa::=%"

设置变量的方法是set a=var

现在我们先想办法把MD5值单独输出来。一步一步往前走啊，往前走。

通过keytool -list -help来查看帮助信息。

我们可以得知-storepass参数可以将store密码直接跟在后面不用等待输入密码了。

我喜欢行云流水，一起哈成的感觉。

下一个重要人物就是管道符`|`了。

大概的意思就是前面的输出可以当做后面的输入。

//todo要详细了解下管道符，我相信我之前的明白的，就是后来年纪大了。。。

findStr命令用来查找字符串。

好了，思路清晰，结果明确。

经过一通乱凑，终于把findStr的结果赋值给变量了。期间过程不想多说什么，error&trail

for /f "tokens=3 delims= " %%i in ('keytool -v -list -keystore release.keystore -storepass password^|findStr MD5') do set result=%%i

就这么一句就把结果拿到了，将md5赋值在result变量中。然后再跟上一句set "result=%result::=%"

result里边就是单纯的0-F了。我还喜欢这种纯纯的感觉。

用语句`set result`查看变量，妥妥的了，已经在碗里了。

最后一步就是要把大写的字符转换为小写。

脑阔疼。。。

一阵搜刮之后，得到了大小写装换的代码。拿来用了。@echo off&setlocal enabledelayedexpansion

set /p "string=请输入字符串:"

set "code=a b c d e f g h i j k l m n o p q r s t u v w x y z A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"

set string=!string: =#!

:loop

set "str_nul=!str_nul!!string:~,1! "&set string=!string:~1!

if defined string goto loop

for %%i in (!str_nul!) do (

set flag=1

for %%j in (!code!) do (

if /i "%%i"=="%%j" if not "%%i"=="%%j" set str=!str!%%j&set flag=0

)

if !flag! equ 1 set str=!str!%%i

)

set "str=!str:#= !"

echo.&echo转换后:!str!

pause>nul

这个功能是大小写互换。其他字符不变。

好了。整合下完整的获取md5的代码如下所示：@echo off&setlocal enabledelayedexpansion

set store_pwd=dlj2016

set store_name=release.keystore

for /f "tokens=3 delims= " %%i in ('keytool -v -list -keystore %store_name% -storepass %store_pwd%^|findStr MD5') do set md5=%%i

set "code=a b c d e f g h i j k l m n o p q r s t u v w x y z A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"

set "md5=%md5::=%"

set string=!md5: =#!

:loop

set "str_nul=!str_nul!!string:~,1! "&set string=!string:~1!

if defined string goto loop

for %%i in (!str_nul!) do (

set flag=1

for %%j in (!code!) do (

if /i "%%i"=="%%j" if not "%%i"=="%%j" set str=!str!%%j&set flag=0

)

if !flag! equ 1 set str=!str!%%i

)

set "str=!str:#= !"

echo.&echo md5:!str!

pause>nul

将store_pwd变量的值修改为keystore的密码，store_name修改为keystore的名称，双击下就好了。

好吧，就这么用一次的东西还搞了这么长时间。

只能当做是程序猿的自我修炼了。说不定某天会有大用场呢。