LocalConnection - AS2与AS3通信说明

LocalConnection - AS2与AS3通信说明

由于当AS3加载AS2时,AS2会在AMV1中运行,
AS3文件跟AS2文件互相都不可以进行操作(跟两个swf独立运行无区别)..
我们常用的解决方法是使用LocalConnection作为他们之前的桥梁..
实现通信进行操作..

下面的例子..
先给AS3进行LocalConnection的运行,,让他处理连接状态(就像一个服务端)
然后AS2使用LocalConnection中的send,调用AS3中的方法

AS3的文档类

代码

package
{
     import  flash.display. * ;
     import  flash.net. * ;
     import  flash.text. * ;

     public   class  AS3Class  extends  Sprite
    {
         private  var server:LocalConnection
         public  function AS3Class()
        {
            init()
        }
         private  function init(): void
        {
             // 初始化
            server  =   new  LocalConnection()
             // 建立一个本地连接,名字随意,取一个不会取与人重复的名字就ok了
            server.connect( " _AS3_L4cd_2008_08_02 " )
             // 指定this为LocalConnection的client,这样才可以调用this中的方法(重要)
            server.client  =   this
        }
         // 随便定义一个方法,不带参数的,需要设置为public(重要)
         public  function m1(): void
        {
            txt.appendText( " \rAS3:m1 " )
        }
         // 随便定义一个方法,带一个参数,需要设置为public(重要)
         public  function m2(_name:String): void
        {
            txt.appendText( " \rAS3:m2,caller name: "   +  _name)
        }
    }
}

AS2中的代码

代码

var caller:LocalConnection
// 初始化对象,由于这里只需要调用别的LocalConnection的方法,所以这里不需要connect
caller  =   new  LocalConnection()
// 调用_AS3_L4cd_2008_08_02(AS3中connect的名字)中的m1
caller.send( " _AS3_L4cd_2008_08_02 " , " m1 " )
// 调用_AS3_L4cd_2008_08_02(AS3中connect的名字)中的m2,前把"L4cd.Net"传到m2的第一个参数
caller.send( " _AS3_L4cd_2008_08_02 " , " m2 " , " L4cd.Net " )

接下来，我们只需要先运行AS3，再运行AS2，AS3中的方法便已经被AS2执行了。

 

转自：http://www.cnblogs.com/sevenyuan/archive/2009/11/30/1613914.html 

 

 

转载于:https://www.cnblogs.com/fxair/archive/2010/01/08/1642259.html